EvaPig

unit UnitFeedEdition;

interface

uses

  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,

  Dialogs, gnugettext, StdCtrls, Grids, DBGrids, Buttons, Mask, DBCtrls, DB,

  JvExStdCtrls, JvEdit, JvValidateEdit, JvExControls, JvEnterTab, JvExMask,

  JvSpin, ExtCtrls, ComCtrls, ToolWin, ActnList, ImgList, JvButton, JvCtrls;

type

  TFormFeedEdition = class(TForm)

    GroupBoxIngredients: TGroupBox;

    GroupBoxComposition: TGroupBox;

    DBGridIngredients: TDBGrid;

    SpeedButtonAppend: TSpeedButton;

    SpeedButtonDelete: TSpeedButton;

    SpeedButtonReplace: TSpeedButton;

    DBEditTotal: TDBEdit;

    SpeedButtonUp: TSpeedButton;

    SpeedButtonDown: TSpeedButton;

    SpeedButtonName: TSpeedButton;

    SpeedButtonLevel: TSpeedButton;

    DBEditRemain: TDBEdit;

    CheckBoxPhytase: TCheckBox;

    DBGridComposition: TDBGrid;

    DBEditName: TDBEdit;

    GroupBoxPhytase: TGroupBox;

    DBEditPhytaseLevel: TDBEdit;

    DBEditPhytaseConcentration: TDBEdit;

    DBEditPhytaseIncorporation: TDBEdit;

    DBLookupComboBoxPhytase: TDBLookupComboBox;

    EnterAsTab: TJvEnterAsTab;

    SpinEditBonusC: TJvSpinEdit;

    SpinEditBonusT: TJvSpinEdit;

    GroupBoxPresentation: TGroupBox;

    GroupBoxBonus: TGroupBox;

    PanelHeader: TPanel;

    PanelButtons: TPanel;

    PanelMain: TPanel;

    ImageListIcons: TImageList;

    ActionListButtons: TActionList;

    ActionRename: TAction;

    ActionComment: TAction;

    ActionHelp: TAction;

    ActionOK: TAction;

    ActionCancel: TAction;

    LabelName: TLabel;

    LabelWarning: TLabel;

    LabelCrois: TLabel;

    LabelTruie: TLabel;

    LabelTotal: TLabel;

    LabelRemain: TLabel;

    LabelType: TLabel;

    LabelConcentration: TLabel;

    LabelIncorporation: TLabel;

    LabelClass: TLabel;

    ComboBoxClass: TComboBox;

    ComboBoxPresentation: TComboBox;

    JvImgBtnCancel: TJvImgBtn;

    JvImgBtnOK: TJvImgBtn;

    JvImgBtnHelp: TJvImgBtn;

    JvImgBtnRename: TJvImgBtn;

    JvImgBtnComment: TJvImgBtn;

    procedure FormCreate(Sender: TObject);

    procedure ComboBoxClassChange(Sender: TObject);

    procedure DBGridIngredientsDrawColumnCell(Sender: TObject;

      const Rect: TRect; DataCol: Integer; Column: TColumn;

      State: TGridDrawState);

    procedure DBGridIngredientsTitleClick(Column: TColumn);

    procedure SpeedButtonAppendClick(Sender: TObject);

    procedure SpeedButtonDeleteClick(Sender: TObject);

    procedure SpeedButtonReplaceClick(Sender: TObject);

    procedure SpeedButtonUpClick(Sender: TObject);

    procedure SpeedButtonDownClick(Sender: TObject);

    procedure SpeedButtonNameClick(Sender: TObject);

    procedure SpeedButtonLevelClick(Sender: TObject);

    procedure DBGridCompositionDrawColumnCell(Sender: TObject;

      const Rect: TRect; DataCol: Integer; Column: TColumn;

      State: TGridDrawState);

    procedure DBGridCompositionKeyPress(Sender: TObject; var Key: Char);

    procedure CheckBoxPhytaseClick(Sender: TObject);

    procedure FormDestroy(Sender: TObject);

    procedure DBGridIngredientsDblClick(Sender: TObject);

    procedure DBEditPhytaseConcentrationEnter(Sender: TObject);

    procedure DBEditPhytaseConcentrationExit(Sender: TObject);

    procedure FormShow(Sender: TObject);

    procedure ActionRenameExecute(Sender: TObject);

    procedure ActionCommentExecute(Sender: TObject);

    procedure ActionHelpExecute(Sender: TObject);

    procedure ActionOKExecute(Sender: TObject);

    procedure ActionCancelExecute(Sender: TObject);

    procedure NumEditKeyDown(Sender: TObject; var Key: Word;

      Shift: TShiftState);

    procedure NumEditKeyPress(Sender: TObject; var Key: Char);

  private

    { D?clarations priv?es }

  public

    { D?clarations publiques }

  end;

var

  FormFeedEdition: TFormFeedEdition;

implementation

{$R *.dfm}

uses

  UnitDeclaration, UnitOptions, UnitRename, UnitComment;

var

  VK_Separator: boolean;

procedure TFormFeedEdition.ActionCancelExecute(Sender: TObject);

begin

  ModalResult := mrCancel;

end;

procedure TFormFeedEdition.ActionCommentExecute(Sender: TObject);

begin

  FormComment := TFormComment.Create(nil);

  try

//    FormComment.Caption := ButtonComment.Hint;

    FormComment.Name := DataModuleDeclaration.ClientDataSetFeedsName.Value;

    FormComment.OldComment := DataModuleDeclaration.ClientDataSetFeedsDescription.Value;

    if (FormComment.ShowModal = mrOk) and (FormComment.NewComment <> FormComment.OldComment)

    then // Commenter

      with DataModuleDeclaration do

      begin

        DBUser.BeginTransaction;

        try

          DBUser.ExecSQL('UPDATE Feeds '

            + Format('SET Description = %s ', [QuotedStr(FormComment.NewComment)])

            + Format('WHERE Id = %d', [ClientDataSetFeedsId.Value]));

          DBUser.Commit;

        except

          DBUser.RollBack;

          MessageDlg(Format(_('Unknown error: %s %s %s'), ['UnitFeedEdition', 'ActionCommentExecute', 'DBUser (UPDATE Feeds)']), mtError, [mbOK], 0);

          Exit;

        end;

        // Commenter dans ClientDataSetFeeds

        ClientDataSetFeeds.Edit;

        ClientDataSetFeedsDescription.Value := FormComment.NewComment;

        ClientDataSetFeeds.Post;

      end;

  finally

    FormComment.Release;

  end;

end;

procedure TFormFeedEdition.ActionHelpExecute(Sender: TObject);

begin

  Application.HelpContext(HelpContext);

end;

procedure TFormFeedEdition.ActionOKExecute(Sender: TObject);

var

  total: Double;

  USFormatSettings: TFormatSettings;

begin

  with DataModuleDeclaration do

  begin

    if CheckBoxPhytase.Checked

    then // V?rifier la saisie de la phytase

    begin

      if ClientDataSetFeedsPhytaseId.IsNull

      then

      begin

        MessageDlg(_('You must select a phytase name.'), mtError, [mbOK], 0);

        ActiveControl := DBLookupComboBoxPhytase;

        Exit;

      end;

      if ClientDataSetFeedsPhytaseConcentration.Value = 0

      then

      begin

        MessageDlg(_('You must specify a phytase concentration level.'), mtError, [mbOK], 0);

        ActiveControl := DBEditPhytaseConcentration;

        Exit;

      end;

      if ClientDataSetFeedsPhytaseIncorporation.Value = 0

      then

      begin

        MessageDlg(_('You must specify a phytase incorporation level.'), mtError, [mbOK], 0);

        ActiveControl := DBEditPhytaseIncorporation;

        Exit;

      end;

    end;

    total := 0;

    ClientDataSetComposition.DisableControls;

    try

      ClientDataSetComposition.First;

      while not ClientDataSetComposition.Eof do

      begin // V?rifier la saisie de chaques mati?res premi?res utilis?es

        if ClientDataSetCompositionMS.Value = 0

        then

        begin

          MessageDlg(_('You must specify a dry matter value for this ingredient.'), mtError, [mbOK], 0);

          ActiveControl := DBGridComposition;

          DBGridComposition.SelectedField := ClientDataSetCompositionMS;

          Exit;

        end;

        if ClientDataSetCompositionLevel.Value = 0

        then

        begin

          MessageDlg(_('You must specify an incorporation rate for this ingredient.'), mtError, [mbOK], 0);

          ActiveControl := DBGridComposition;

          DBGridComposition.SelectedField := ClientDataSetCompositionLevel;

          Exit;

        end;

        total := total + ClientDataSetCompositionLevel.Value;

        ClientDataSetComposition.Next;

      end;

    finally

      ClientDataSetComposition.EnableControls;

    end;

    if Abs(ClientDataSetFeedsRemain.Value) > 1 / 1000

    then

      if MessageDlg(_('The sum of ingredient incorporation rates is not equal to 100% of the diet composition.' + sLineBreak + 'Are you sure you want to continue?'), mtError, [mbYes, mbNo], 0) <> mrYes

      then

      begin

        Exit;

      end;

    FilterOnClass := False; // Mise ? jour le 22/02/2008

    // Modifier le r?gime

    GetLocaleFormatSettings(1033, USFormatSettings);

    DBUser.BeginTransaction;

    try

      DBUser.ExecSQL('UPDATE Feeds '

        + Format('SET Presentation = %d, ', [ComboBoxPresentation.ItemIndex])

        + Format('BonusC = %.3f, ', [SpinEditBonusC.Value / 100], USFormatSettings)

        + Format('BonusT = %.3f ', [SpinEditBonusT.Value / 100], USFormatSettings)

        + Format('WHERE Id = %d', [ClientDataSetFeedsId.Value]));

      // Phytase

      if CheckBoxPhytase.Checked

      then

        DBUser.ExecSQL('UPDATE Feeds '

          + Format('SET Phytase = %d, ', [ClientDataSetFeedsPhytaseId.Value])

          + Format('Concentration = %.0f, ', [ClientDataSetFeedsPhytaseConcentration.Value], USFormatSettings)

          + Format('Incorporation = %.0f ', [ClientDataSetFeedsPhytaseIncorporation.Value], USFormatSettings)

          + Format('WHERE Id = %d', [ClientDataSetFeedsId.Value]))

      else

        DBUser.ExecSQL('UPDATE Feeds '

          + 'SET Phytase = null, '

          + 'Concentration = null, '

          + 'Incorporation = null '

          + Format('WHERE Id = %d', [ClientDataSetFeedsId.Value]));

      DBUser.Commit;

    except

      DBUser.RollBack;

      MessageDlg(Format(_('Unknown error: %s %s %s'), ['UnitFeedEdition', 'ActionOKExecute', 'DBUser (UPDATE Feeds)']), mtError, [mbOK], 0);

      Exit;

    end;

    // Suppression de l'ancienne composition

    DBUser.BeginTransaction;

    try

      DBUser.ExecSQL('DELETE FROM Composition '

        + Format('WHERE Feed = %d', [ClientDataSetFeedsId.Value]));

      DBUser.Commit;

    except

      DBUser.RollBack;

      MessageDlg(Format(_('Unknown error: %s %s %s'), ['UnitFeedEdition', 'ActionOKExecute', 'DBUser (DELETE FROM Composition)']), mtError, [mbOK], 0);

      Exit;

    end;

    // Enregistrement de la nouvelle composition

    ClientDataSetComposition.DisableControls;

    try

      DBUser.BeginTransaction;

      try

        ClientDataSetComposition.First;

        while not ClientDataSetComposition.Eof do

        begin

          ClientDataSetCompositionUser.DisplayValues := DefaultTrueBoolStr + ';' + DefaultFalseBoolStr;

          DBUser.ExecSQL('INSERT INTO Composition (Feed, Ingredient, User, Rank, MS, Level) VALUES ('

            + Format('%d, ', [ClientDataSetFeedsId.Value])

            + Format('%d, ', [ClientDataSetCompositionIngredient.Value])

            + Format('''%s'', ', [ClientDataSetCompositionUser.AsString])

            + Format('%d, ', [ClientDataSetCompositionRank.Value])

            + Format('%.15f, ', [InputProximal(ClientDataSetCompositionMS.Value, 1, 1, FormOptions.Proximal)], USFormatSettings)

            + Format('%.15f)', [InputIncorporation(ClientDataSetCompositionLevel.Value, FormOptions.Incorporation)], USFormatSettings));

          ClientDataSetComposition.Next;

        end;

        DBUser.Commit;

      except

        DBUser.RollBack;

        MessageDlg(Format(_('Unknown error: %s %s %s'), ['UnitFeedEdition', 'ActionOKExecute', 'DBUser (INSERT INTO Composition)']), mtError, [mbOK], 0);

        Exit;

      end;

    finally

      ClientDataSetComposition.EnableControls;

    end;

    // Calculer les valeurs de ClientDataSetFeeds

    TableFeeds := DBUser.GetTable('SELECT * FROM Feeds '

      + Format('WHERE Id = %d', [ClientDataSetFeedsId.Value]));

    ClientDataSetFeeds.Edit;

    try

      ClientDataSetFeedsPresentation.Value := ComboBoxPresentation.ItemIndex;

      ClientDataSetFeedsBonusC.Value := SpinEditBonusC.Value;

      ClientDataSetFeedsBonusT.Value := SpinEditBonusT.Value;

      CalcFeed;

      ClientDataSetFeeds.Post;

    except

      ClientDataSetFeeds.Cancel;

      MessageDlg(Format(_('Unknown error: %s %s %s'), ['UnitFeedEdition', 'ActionOKExecute', 'ClientDataSetFeeds']), mtError, [mbOK], 0);

      Exit;

    end;

    TableFeeds.Free;

  end;

  ModalResult := mrOk;

end;

procedure TFormFeedEdition.ActionRenameExecute(Sender: TObject);

begin

  FormRename := TFormRename.Create(nil);

  try

//    FormRename.Caption := ButtonRename.Hint;

    FormRename.OldName := DataModuleDeclaration.ClientDataSetFeedsName.Value;

    FormRename.NameList.Assign(DataModuleDeclaration.FeedList);

    if (FormRename.ShowModal = mrOk) and (FormRename.NewName <> FormRename.OldName)

    then // Renommer

      with DataModuleDeclaration do

      begin

        DBUser.BeginTransaction;

        try

          DBUser.ExecSQL('UPDATE Feeds '

            + Format('SET Name = %s ', [QuotedStr(FormRename.NewName)])

            + Format('WHERE Id = %d', [ClientDataSetFeedsId.Value]));

          DBUser.Commit;

        except

          DBUser.RollBack;

          MessageDlg(Format(_('Unknown error: %s %s %s'), ['UnitFeedEdition', 'ActionRenameExecute', 'DBUser (UPDATE Feeds)']), mtError, [mbOK], 0);

          Exit;

        end;

        // Renommer dans ClientDataSetFeeds

        ClientDataSetFeeds.Edit;

        ClientDataSetFeedsName.Value := FormRename.NewName;

        ClientDataSetFeeds.Post;

        // Modifier le nom dans la liste des r?gimes

        FeedList[FeedList.IndexOf(FormRename.OldName)] := FormRename.NewName;

      end;

  finally

    FormRename.Release;

  end;

end;

procedure TFormFeedEdition.CheckBoxPhytaseClick(Sender: TObject);

begin

  if CheckBoxPhytase.Checked

  then

  begin

    DBLookupComboBoxPhytase.Enabled := True;

    DBEditPhytaseConcentration.Enabled := True;

    DBEditPhytaseIncorporation.Enabled := True;

    ActiveControl := DBLookupComboBoxPhytase;

  end

  else

  begin

    with DataModuleDeclaration do

    begin

      ClientDataSetFeeds.Edit;

      ClientDataSetFeedsPhytaseId.Clear;

      ClientDataSetFeedsPhytaseConcentration.Clear;

      ClientDataSetFeedsPhytaseIncorporation.Clear;

      ClientDataSetFeeds.Post;

    end;

    DBLookupComboBoxPhytase.Enabled := False;

    DBEditPhytaseConcentration.Enabled := False;

    DBEditPhytaseIncorporation.Enabled := False;

  end;

end;

procedure TFormFeedEdition.ComboBoxClassChange(Sender: TObject);

begin

  with DataModuleDeclaration do

  begin

    ClientDataSetIngredients.Filtered := False;

    FilterOnClass := True;

    FilteredClass := ComboBoxClass.ItemIndex;

    if FilteredClass <> 0

    then

      ClientDataSetIngredients.Filtered := True;

  end;

end;

procedure TFormFeedEdition.DBEditPhytaseConcentrationEnter(Sender: TObject);

begin

//  DataModuleDeclaration.ClientDataSetFeedsPhytaseConcentration.DisplayFormat := '0';

//  DBEditPhytaseConcentration.SelectAll;

end;

procedure TFormFeedEdition.DBEditPhytaseConcentrationExit(Sender: TObject);

begin

//  DataModuleDeclaration.ClientDataSetFeedsPhytaseConcentration.DisplayFormat := '#,###,##0';

end;

procedure TFormFeedEdition.DBGridCompositionDrawColumnCell(Sender: TObject;

  const Rect: TRect; DataCol: Integer; Column: TColumn; State: TGridDrawState);

begin

  with DBGridComposition do

  begin

    if Column.FieldName = 'IngredientName'

    then // Couleur particuli?re pour indiquer la base d'origine

      if gdSelected in State

      then // Cellule courante

      begin

        if DataModuleDeclaration.ClientDataSetCompositionUser.Value

        then // User

          Canvas.Font.Color := clWebPaleTurquoise

        else // InraAfz

          Canvas.Font.Color := clWebLightPink;

        Canvas.Brush.Color := clWebGray;

      end

      else // Cellule normale

      begin

        Canvas.Font.Color := clWebBlack;

        if DataModuleDeclaration.ClientDataSetCompositionUser.Value

        then // User

          Canvas.Brush.Color := clWebPaleTurquoise

        else // InraAfz

          Canvas.Brush.Color := clWebLightPink;

      end

    else // Cellule modifiable

      if gdSelected in State

      then // Cellule courante

      begin

        Canvas.Font.Color := clWebWhite;

        Canvas.Brush.Color := clWebGray;

      end

      else

      begin

        Canvas.Font.Color := clWebBlack;

        Canvas.Brush.Color := clWebWhite;

      end;

    DefaultDrawColumnCell(Rect, DataCol, Column, State);

  end;

end;

procedure TFormFeedEdition.DBGridCompositionKeyPress(Sender: TObject; var Key: Char);

begin

  if Key = AnsiChar(#13)

  then

  begin

    if DBGridComposition.EditorMode

    then

    begin

      DBGridComposition.EditorMode := False;

      with DataModuleDeclaration.ClientDataSetComposition do

        if Modified

        then

          Post;

    end;

    Key := AnsiChar(#0);

  end

  else

    NumEditKeyPress(Sender, Key);

end;

procedure TFormFeedEdition.DBGridIngredientsDblClick(Sender: TObject);

begin

  SpeedButtonAppendClick(nil);

end;

procedure TFormFeedEdition.DBGridIngredientsDrawColumnCell(Sender: TObject;

  const Rect: TRect; DataCol: Integer; Column: TColumn; State: TGridDrawState);

begin

  with DBGridIngredients do

  begin

    if Column.FieldName = DataModuleDeclaration.ClientDataSetIngredients.IndexFieldNames

    then // Colonne tri?e

      Canvas.Font.Style := Canvas.Font.Style + [fsBold];

    if Column.FieldName = 'Name'

    then // Couleur particuli?re pour indiquer la base d'origine

      if gdSelected in State

      then // Cellule courante

      begin

        if DataModuleDeclaration.ClientDataSetIngredientsUser.Value

        then // User

          Canvas.Font.Color := clWebPaleTurquoise

        else // InraAfz

          Canvas.Font.Color := clWebLightPink;

        Canvas.Brush.Color := clWebGray;

      end

      else // Cellule normale

      begin

        Canvas.Font.Color := clWebBlack;

        if DataModuleDeclaration.ClientDataSetIngredientsUser.Value

        then // User

          Canvas.Brush.Color := clWebPaleTurquoise

        else // InraAfz

          Canvas.Brush.Color := clWebLightPink;

      end

    else // Valeurs

      if gdSelected in State

      then // Cellule courante

      begin

        Canvas.Font.Color := clWebWhite;

        Canvas.Brush.Color := clWebGray;

      end

      else

      begin

        Canvas.Font.Color := clWebBlack;

        Canvas.Brush.Color := clWebLightGrey;

      end;

    DefaultDrawColumnCell(Rect, DataCol, Column, State);

  end;

end;

procedure TFormFeedEdition.DBGridIngredientsTitleClick(Column: TColumn);

begin

  with DataModuleDeclaration.ClientDataSetIngredients do

    if IndexFieldNames = Column.FieldName

    then // C'est d?j? l'index => tri selon le num?ro

      IndexFieldNames := 'Name'

    else

      IndexFieldNames := Column.FieldName;

end;

procedure TFormFeedEdition.FormCreate(Sender: TObject);

begin

  if Screen.Fonts.IndexOf('Arial Unicode MS') <> -1

  then

    Font.Name := 'Arial Unicode MS';

//  PanelButtons.Font.Size := PanelButtons.Font.Size + 2;

  PanelButtons.Font.Style := [fsBold];

  LabelName.Font.Style := [fsBold];

  DBEditName.Font.Style := [fsBold];

  LabelWarning.Font.Color := clRed;

  TranslateComponent(Self);

  with DataModuleDeclaration do

  begin

    // Classes

    ComboBoxClass.Items.Add(_('(All)'));

    ClientDataSetClasses.First;

    while not ClientDataSetClasses.Eof do

    begin

      ComboBoxClass.Items.Add(ClientDataSetClassesName.Value);

      ClientDataSetClasses.Next;

    end;

    ComboBoxClass.ItemIndex := 0; // (All) par d?faut

    // Composition

    ClientDataSetComposition.Filter := Format('Feed = %d', [ClientDataSetFeedsId.Value]);

    ClientDataSetComposition.Filtered := True;

    ClientDataSetComposition.First;

  end;

  with FormOptions do

  begin

    DBGridComposition.Columns[1].Title.Caption := Format('%s (%s)', [DBGridComposition.Columns[1].Title.Caption, ComboBoxProximal.Items[Proximal]]);

    DBGridComposition.Columns[2].Title.Caption := Format('%s (%s)', [DBGridComposition.Columns[2].Title.Caption, ComboBoxIncorporation.Items[Incorporation]]);

  end;

  GroupBoxBonus.Caption := GroupBoxBonus.Caption + ' (%)';

end;

procedure TFormFeedEdition.FormShow(Sender: TObject);

begin

  with DataModuleDeclaration do

  begin

    ComboBoxPresentation.ItemIndex := ClientDataSetFeedsPresentation.Value;

    SpinEditBonusC.Value := ClientDataSetFeedsBonusC.Value;

    SpinEditBonusT.Value := ClientDataSetFeedsBonusT.Value;

    // Phytase

    if ClientDataSetFeedsPhytaseId.IsNull

    then

      CheckBoxPhytase.Checked := False;

    // Taux d'incorporation total

    ClientDataSetFeeds.Edit;

    if VarIsEmpty(ClientDataSetComposition.Aggregates[0].Value)

    or VarIsNull(ClientDataSetComposition.Aggregates[0].Value)

    then

      ClientDataSetFeedsLevelSum.Clear

    else

      ClientDataSetFeedsLevelSum.Value := ClientDataSetComposition.Aggregates[0].Value;

    ClientDataSetFeeds.Post;

  end;

  with DBGridComposition do

    Columns[0].Width := Width - Columns[1].Width - Columns[2].Width - 28;

end;

procedure TFormFeedEdition.FormDestroy(Sender: TObject);

begin

  with DataModuleDeclaration do

  begin

    ClientDataSetIngredients.Filtered := False;

    ClientDataSetIngredients.Filter := '';

    FilterOnClass := False;

    ClientDataSetComposition.Filtered := False;

    ClientDataSetComposition.Filter := '';

  end;

end;

procedure TFormFeedEdition.SpeedButtonAppendClick(Sender: TObject);

begin

  with DataModuleDeclaration do

    if ClientDataSetIngredients.RecordCount > 0

    then

    begin

      ClientDataSetComposition.Append;

      ClientDataSetCompositionFeed.Value := ClientDataSetFeedsId.Value;

      ClientDataSetCompositionRank.Value := ClientDataSetComposition.RecordCount + 1;

      ClientDataSetCompositionIngredient.Value := ClientDataSetIngredientsId.Value;

      ClientDataSetCompositionUser.Value := ClientDataSetIngredientsUser.Value;

      ClientDataSetCompositionIngredientName.Value := ClientDataSetIngredientsName.Value;

      ClientDataSetCompositionMS.Value := ClientDataSetIngredientsMS.Value;

      ClientDataSetCompositionLevel.Value := 0;

      ClientDataSetComposition.Post;

      ActiveControl := DBGridComposition;

      DBGridComposition.SelectedField := ClientDataSetCompositionLevel;

    end;

end;

procedure TFormFeedEdition.SpeedButtonDeleteClick(Sender: TObject);

var

  Distance: Integer;

begin

  with DataModuleDeclaration do

    if ClientDataSetComposition.RecordCount > 0

    then

    begin

      ClientDataSetComposition.DisableControls;

      ClientDataSetComposition.Delete;

      // Recalculer l'agr?gat

      AggregateLevelSumUpdate(ClientDataSetComposition.Aggregates[0]);

      Distance := ClientDataSetComposition.RecNo - ClientDataSetComposition.RecordCount;

      while not ClientDataSetComposition.Eof do

      begin

        ClientDataSetComposition.Edit;

        ClientDataSetCompositionRank.Value := ClientDataSetCompositionRank.Value - 1;

        ClientDataSetComposition.Post;

        ClientDataSetComposition.Next;

      end;

      // Res?lectionner l'?l?ment courant

      if Distance < 0 then ClientDataSetComposition.MoveBy(Distance);

      ClientDataSetComposition.EnableControls;

    end;

end;

procedure TFormFeedEdition.SpeedButtonDownClick(Sender: TObject);

var

  Position: Integer;

begin

  with DataModuleDeclaration do

    if ClientDataSetComposition.RecNo < ClientDataSetComposition.RecordCount

    then

    begin

      ClientDataSetComposition.DisableControls;

      Position := ClientDataSetComposition.RecNo;

      // D?caler les ?l?ments suivant l'?l?ment courant

      ClientDataSetComposition.Last;

      while ClientDataSetComposition.RecNo > Position do

      begin

        ClientDataSetComposition.Edit;

        ClientDataSetCompositionRank.Value := ClientDataSetCompositionRank.Value + 1;

        ClientDataSetComposition.Post;

        ClientDataSetComposition.Prior;

      end;

      // L'?l?ment courant deviendra le suivant

      ClientDataSetComposition.Edit;

      ClientDataSetCompositionRank.Value := ClientDataSetCompositionRank.Value + 1;

      ClientDataSetComposition.Post;

      // L'?l?ment suivant devient le pr?c?dent

      ClientDataSetComposition.Next;

      ClientDataSetComposition.Edit;

      ClientDataSetCompositionRank.Value := ClientDataSetCompositionRank.Value - 2;

      ClientDataSetComposition.Post;

      // Ravancer les ?l?ments d?cal?s

      ClientDataSetComposition.Last;

      while ClientDataSetComposition.RecNo > Position + 1 do

      begin

        ClientDataSetComposition.Edit;

        ClientDataSetCompositionRank.Value := ClientDataSetCompositionRank.Value - 1;

        ClientDataSetComposition.Post;

        ClientDataSetComposition.Prior;

      end;

      ClientDataSetComposition.EnableControls;

    end;

end;

procedure TFormFeedEdition.SpeedButtonLevelClick(Sender: TObject);

var

  Position, Distance: Integer;

begin

  with DataModuleDeclaration do

  begin

    Distance := 0;

    Position := ClientDataSetCompositionRank.Value;

    ClientDataSetComposition.DisableControls;

    ClientDataSetComposition.AggregatesActive := False;

    ClientDataSetComposition.IndexName := 'IndexLevel';

    ClientDataSetComposition.First;

    while not ClientDataSetComposition.Eof do

    begin

      if ClientDataSetCompositionRank.Value = Position

      then // Enregistrement courant

        Distance := ClientDataSetComposition.RecNo - ClientDataSetComposition.RecordCount;

      ClientDataSetComposition.Edit;

      ClientDataSetCompositionRank.Value := ClientDataSetComposition.RecNo;

      ClientDataSetComposition.Post;

      ClientDataSetComposition.Next;

    end;

    // Res?lectionner l'?l?ment courant

    if Distance < 0 then ClientDataSetComposition.MoveBy(Distance);

    ClientDataSetComposition.IndexName := 'IndexRank';

    ClientDataSetComposition.AggregatesActive := True;

    ClientDataSetComposition.EnableControls;

  end;

end;

procedure TFormFeedEdition.SpeedButtonNameClick(Sender: TObject);

var

  Position, Distance: Integer;

begin

  with DataModuleDeclaration do

  begin

    Distance := 0;

    Position := ClientDataSetCompositionRank.Value;

    ClientDataSetComposition.DisableControls;

    ClientDataSetComposition.AggregatesActive := False;

    ClientDataSetComposition.IndexName := 'IndexIngredientName';

    ClientDataSetComposition.First;

    while not ClientDataSetComposition.Eof do

    begin

      if ClientDataSetCompositionRank.Value = Position

      then // Enregistrement courant

        Distance := ClientDataSetComposition.RecNo - ClientDataSetComposition.RecordCount;

      ClientDataSetComposition.Edit;

      ClientDataSetCompositionRank.Value := ClientDataSetComposition.RecNo;

      ClientDataSetComposition.Post;

      ClientDataSetComposition.Next;

    end;

    // Res?lectionner l'?l?ment courant

    if Distance < 0 then ClientDataSetComposition.MoveBy(Distance);

    ClientDataSetComposition.IndexName := 'IndexRank';

    ClientDataSetComposition.AggregatesActive := True;

    ClientDataSetComposition.EnableControls;

  end;

end;

procedure TFormFeedEdition.SpeedButtonReplaceClick(Sender: TObject);

begin

  with DataModuleDeclaration do

    if (ClientDataSetIngredients.RecordCount > 0) and (ClientDataSetComposition.RecordCount > 0)

    then

    begin

      ClientDataSetComposition.Edit;

      ClientDataSetCompositionUser.Value := ClientDataSetIngredientsUser.Value;

      ClientDataSetCompositionIngredient.Value := ClientDataSetIngredientsId.Value;

      ClientDataSetCompositionIngredientName.Value := ClientDataSetIngredientsName.Value;

      ClientDataSetCompositionMS.Value := ClientDataSetIngredientsMS.Value;

      ClientDataSetComposition.Post;

      ActiveControl := DBGridComposition;

      DBGridComposition.SelectedField := ClientDataSetCompositionMS;

    end;

end;

procedure TFormFeedEdition.SpeedButtonUpClick(Sender: TObject);

var

  Position: Integer;

begin

  with DataModuleDeclaration do

    if ClientDataSetComposition.RecNo > 1

    then

    begin

      ClientDataSetComposition.DisableControls;

      Position := ClientDataSetComposition.RecNo;

      // D?caler les ?l?ments ? partir de l'?l?ment courant

      ClientDataSetComposition.Last;

      while ClientDataSetComposition.RecNo > Position - 1 do

      begin

        ClientDataSetComposition.Edit;

        ClientDataSetCompositionRank.Value := ClientDataSetCompositionRank.Value + 1;

        ClientDataSetComposition.Post;

        ClientDataSetComposition.Prior;

      end;

      // L'?l?ment pr?c?dent deviendra le suivant

      ClientDataSetComposition.Edit;

      ClientDataSetCompositionRank.Value := ClientDataSetCompositionRank.Value + 1;

      ClientDataSetComposition.Post;

      // L'?l?ment courant devient le pr?c?dent

      ClientDataSetComposition.Next;

      ClientDataSetComposition.Edit;

      ClientDataSetCompositionRank.Value := ClientDataSetCompositionRank.Value - 2;

      ClientDataSetComposition.Post;

      // Ravancer les ?l?ments d?cal?s

      ClientDataSetComposition.Last;

      while ClientDataSetComposition.RecNo > Position do

      begin

        ClientDataSetComposition.Edit;

        ClientDataSetCompositionRank.Value := ClientDataSetCompositionRank.Value - 1;

        ClientDataSetComposition.Post;

        ClientDataSetComposition.Prior;

      end;

      // Res?lectionner l'?l?ment courant (Position - 1)

      ClientDataSetComposition.Prior;

      ClientDataSetComposition.EnableControls;

    end;

end;

procedure TFormFeedEdition.NumEditKeyDown(Sender: TObject;

  var Key: Word; Shift: TShiftState);

begin

  // D?tection de l'appui sur le s?parateur d?cimal du pav? num?rique

  VK_Separator := (Key = VK_DECIMAL);

end;

procedure TFormFeedEdition.NumEditKeyPress(Sender: TObject;

  var Key: Char);

begin

  if VK_Separator then

    // Renvoyer le s?parateur d?cimal des options r?gionales et linguistiques

    Key := DecimalSeparator;

end;

end.