EvaPig

unit UnitIngredientCreation;

interface

uses

  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,

  Dialogs, gnugettext, StdCtrls, Mask, DB, DBCtrls, JvExMask, JvSpin,

  JvExStdCtrls, JvEdit, JvValidateEdit, ComCtrls, JvExControls, JvEnterTab,

  JvButton, JvCtrls, ActnList, ImgList, ExtCtrls;

type

  TFormIngredientCreation = class(TForm)

    ValidateEditMSCopy: TJvValidateEdit;

    ValidateEditModel: TJvValidateEdit;

    PageControlCreation: TPageControl;

    TabSheetCopy: TTabSheet;

    TabSheetOriginal: TTabSheet;

    ValidateEditMSOriginal: TJvValidateEdit;

    GroupBoxOriginalStep2: TGroupBox;

    GroupBoxOriginalStep5: TGroupBox;

    GroupBoxOriginalStep4: TGroupBox;

    GroupBoxOriginalStep6: TGroupBox;

    ValidateEditMAT: TJvValidateEdit;

    ValidateEditMM: TJvValidateEdit;

    CheckBoxMAT: TCheckBox;

    CheckBoxMM: TCheckBox;

    GroupBoxOriginalStep7: TGroupBox;

    GroupBoxOriginalStep3: TGroupBox;

    ValidateEditMG: TJvValidateEdit;

    CheckBoxMG: TCheckBox;

    CheckBoxEB: TCheckBox;

    ValidateEditEB: TJvValidateEdit;

    ValidateEditAmidon: TJvValidateEdit;

    CheckBoxAmidon: TCheckBox;

    ValidateEditSucres: TJvValidateEdit;

    CheckBoxSucres: TCheckBox;

    ValidateEditCB: TJvValidateEdit;

    ValidateEditNDF: TJvValidateEdit;

    ValidateEditADF: TJvValidateEdit;

    CheckBoxCB: TCheckBox;

    CheckBoxNDF: TCheckBox;

    CheckBoxADF: TCheckBox;

    GroupBoxCopyStep1: TGroupBox;

    GroupBoxCopyStep2: TGroupBox;

    GroupBoxOriginalStep1: TGroupBox;

    EnterAsTab: TJvEnterAsTab;

    ButtonNext: TButton;

    LabelName: TLabel;

    LabelClass: TLabel;

    LabelDefinition: TLabel;

    LabelModel: TLabel;

    LabelMSCopy: TLabel;

    LabelMSCopyWarning: TLabel;

    LabelOptionComment: TLabel;

    LabelMM: TLabel;

    LabelMG: TLabel;

    LabelEB: TLabel;

    LabelMGComment: TLabel;

    LabelEBComment: TLabel;

    LabelCB: TLabel;

    LabelNDF: TLabel;

    LabelADF: TLabel;

    LabelAmidon: TLabel;

    LabelSucres: TLabel;

    LabelMAT: TLabel;

    LabelMSOriginal: TLabel;

    LabelMSOriginalWarning: TLabel;

    ComboBoxClass: TComboBox;

    ComboBoxModel: TComboBox;

    ComboBoxMSCopy: TComboBox;

    ComboBoxMM: TComboBox;

    ComboBoxMG: TComboBox;

    ComboBoxEB: TComboBox;

    ComboBoxFibre: TComboBox;

    ComboBoxAmidon: TComboBox;

    ComboBoxSucres: TComboBox;

    ComboBoxMAT: TComboBox;

    ComboBoxMSOriginal: TComboBox;

    EditName: TEdit;

    MemoDefinition: TMemo;

    ImageListIcons: TImageList;

    ActionListButtons: TActionList;

    ActionHelp: TAction;

    JvImgBtnHelp: TJvImgBtn;

    JvImgBtnOK: TJvImgBtn;

    JvImgBtnCancel: TJvImgBtn;

    ActionOK: TAction;

    ActionCancel: TAction;

    PanelButtons: TPanel;

    PanelHead: TPanel;

    procedure FormCreate(Sender: TObject);

    procedure ComboBoxClassChange(Sender: TObject);

    procedure ComboBoxModelChange(Sender: TObject);

    procedure ComboBoxMSCopyChange(Sender: TObject);

    procedure ButtonNextClick(Sender: TObject);

    procedure ComboBoxMSOriginalChange(Sender: TObject);

    procedure ComboBoxMMChange(Sender: TObject);

    procedure ComboBoxMATChange(Sender: TObject);

    procedure ComboBoxMGChange(Sender: TObject);

    procedure ComboBoxEBChange(Sender: TObject);

    procedure ComboBoxFibreChange(Sender: TObject);

    procedure ComboBoxAmidonChange(Sender: TObject);

    procedure ComboBoxSucresChange(Sender: TObject);

    procedure CheckBoxMMClick(Sender: TObject);

    procedure CheckBoxMATClick(Sender: TObject);

    procedure CheckBoxMGClick(Sender: TObject);

    procedure CheckBoxEBClick(Sender: TObject);

    procedure CheckBoxCBClick(Sender: TObject);

    procedure CheckBoxNDFClick(Sender: TObject);

    procedure CheckBoxADFClick(Sender: TObject);

    procedure CheckBoxAmidonClick(Sender: TObject);

    procedure CheckBoxSucresClick(Sender: TObject);

    procedure FormDestroy(Sender: TObject);

    procedure ActionHelpExecute(Sender: TObject);

    procedure ActionOKExecute(Sender: TObject);

    procedure ActionCancelExecute(Sender: TObject);

    procedure NumEditKeyDown(Sender: TObject; var Key: Word;

      Shift: TShiftState);

    procedure NumEditKeyPress(Sender: TObject; var Key: Char);

  private

    { D?clarations priv?es }

    ModelList: TStrings;

    procedure EditActivate(Edit: TJvValidateEdit);

    procedure EditEmpty(Edit: TJvValidateEdit);

  public

    { D?clarations publiques }

  end;

var

  FormIngredientCreation: TFormIngredientCreation;

implementation

{$R *.dfm}

uses

  UnitDeclaration, UnitOptions;

var

  VK_Separator: boolean;

procedure TFormIngredientCreation.ActionCancelExecute(Sender: TObject);

begin

  ModalResult := mrCancel;

end;

procedure TFormIngredientCreation.ActionHelpExecute(Sender: TObject);

begin

  Application.HelpContext(HelpContext);

end;

procedure TFormIngredientCreation.ActionOKExecute(Sender: TObject);

var

  NewId: Integer;

  NewName, NewComment: String;

  Nb: Integer;

  MM, MAT, MG, Fibre, Amidon, Sucres, CB, NDF, ADF: Double;

  USFormatSettings: TFormatSettings;

begin

  NewName := Trim(EditName.Text);

  NewComment := MemoDefinition.Text;

  if NewName = ''

  then

  begin

    MessageDlg(_('You must specify a name for this ingredient.'), mtError, [mbOK], 0);

    ActiveControl := EditName;

    Exit;

  end;

  if DataModuleDeclaration.UserList.IndexOf(NewName) <> -1

  then

  begin

    MessageDlg(_('This name is already used, please specify another name.'), mtError, [mbOK], 0);

    ActiveControl := EditName;

    Exit;

  end;

  if ComboBoxClass.ItemIndex = -1

  then

  begin

    MessageDlg(_('You must specify a class for this ingredient.'), mtError, [mbOK], 0);

    ActiveControl := ComboBoxClass;

    Exit;

  end;

  if PageControlCreation.TabIndex = 0

  then // Copie

  begin

    if ComboBoxModel.ItemIndex = -1

    then

    begin

      MessageDlg(_('You must specify a reference for this ingredient.'), mtError, [mbOK], 0);

      ActiveControl := ComboBoxModel;

      Exit;

    end;

    if ValidateEditMSCopy.Value = 0

    then

    begin

      MessageDlg(_('You must specify a dry matter value for this ingredient.'), mtError, [mbOK], 0);

      ActiveControl := ValidateEditMSCopy;

      Exit;

    end;

  end

  else // Cr?ation originale

  begin

    if not CheckBoxMM.Checked

    then

    begin

      MessageDlg(_('You must specify an ash value for this ingredient.'), mtError, [mbOK], 0);

      ActiveControl := CheckBoxMM;

      Exit;

    end;

    if not CheckBoxMAT.Checked

    then

    begin

      MessageDlg(_('You must specify a crude protein value for this ingredient.'), mtError, [mbOK], 0);

      ActiveControl := CheckBoxMAT;

      Exit;

    end;

    if not CheckBoxCB.Checked and not CheckBoxNDF.Checked and not CheckBoxADF.Checked

    then

    begin

      MessageDlg(_('You must specify a fiber value (crude fiber, NDF or ADF) for this ingredient.'), mtError, [mbOK], 0);

      ActiveControl := CheckBoxCB;

      Exit;

    end;

    if not CheckBoxMG.Checked and not CheckBoxEB.Checked

    then

    begin

      MessageDlg(_('You must specify a crude fat value or a gross energy value for this ingredient.'), mtError, [mbOK], 0);

      ActiveControl := CheckBoxMG;

      Exit;

    end;

    with DataModuleDeclaration do

      RapMS := InputProximal(ValidateEditMSOriginal.AsFloat, 1, 1, ComboBoxMSOriginal.ItemIndex);

    if CheckBoxMM.Checked

    then

      with DataModuleDeclaration do

        MM := InputProximal(ValidateEditMM.AsFloat, RapMS, ComboBoxMM.ItemIndex div 2, ComboBoxMM.ItemIndex mod 2)

    else

      MM := 0;

    if CheckBoxMAT.Checked

    then

      with DataModuleDeclaration do

        MAT := InputProximal(ValidateEditMAT.AsFloat, RapMS, ComboBoxMAT.ItemIndex div 2, ComboBoxMAT.ItemIndex mod 2)

    else

      MAT := 0;

    if CheckBoxMG.Checked

    then

      with DataModuleDeclaration do

        MG := InputProximal(ValidateEditMG.AsFloat, RapMS, ComboBoxMG.ItemIndex div 2, ComboBoxMG.ItemIndex mod 2)

    else

      MG := 0;

    Nb := 0;

    if CheckBoxCB.Checked

    then

    begin

      with DataModuleDeclaration do

        CB := InputProximal(ValidateEditCB.AsFloat, RapMS, ComboBoxFibre.ItemIndex div 2, ComboBoxFibre.ItemIndex mod 2);

      Inc(Nb);

    end

    else

      CB := 0;

    if CheckBoxNDF.Checked

    then

    begin

      with DataModuleDeclaration do

        NDF := InputProximal(ValidateEditNDF.AsFloat, RapMS, ComboBoxFibre.ItemIndex div 2, ComboBoxFibre.ItemIndex mod 2);

      Inc(Nb);

    end

    else

      NDF := 0;

    if CheckBoxADF.Checked

    then

    begin

      with DataModuleDeclaration do

        ADF := InputProximal(ValidateEditADF.AsFloat, RapMS, ComboBoxFibre.ItemIndex div 2, ComboBoxFibre.ItemIndex mod 2);

      Inc(Nb);

    end

    else

      ADF := 0;

    if Nb = 0

    then

      Fibre := 0

    else // Moyenne des ?quations significatives

      Fibre := (CB * NDF_CB + NDF + ADF * NDF_ADF) / Nb;

    if CheckBoxAmidon.Checked

    then

      with DataModuleDeclaration do

        Amidon := InputProximal(ValidateEditAmidon.AsFloat, RapMS, ComboBoxAmidon.ItemIndex div 2, ComboBoxAmidon.ItemIndex mod 2)

    else

      Amidon := 0;

    if CheckBoxSucres.Checked

    then

      with DataModuleDeclaration do

        Sucres := InputProximal(ValidateEditSucres.AsFloat, RapMS, ComboBoxSucres.ItemIndex div 2, ComboBoxSucres.ItemIndex mod 2)

    else

      Sucres := 0;

    if MM + MAT + MG + Fibre + Amidon + Sucres > MAX_SUM

    then

      if MessageDlg(_('The sum of nutrients is estimated to more than 100% of the dry matter.' + sLineBreak + 'Are you sure you want to continue?'), mtError, [mbYes, mbNo], 0) <> mrYes

      then

        Exit;

  end;

  with DataModuleDeclaration do

  begin

    // Rechercher une valeur pour le champs Id

    TableIngredients := DBUser.GetTable('SELECT Id FROM Ingredients ORDER BY Id');

    with TableIngredients do

      try

        if RowCount > 0

        then

        begin

          MoveLast;

          NewId := FieldAsInteger(FieldIndex['Id']) + 1;

        end

        else

          NewId := 1;

      finally

        Free;

      end;

    // Cr?er la nouvelle mati?re premi?re

    GetLocaleFormatSettings(1033, USFormatSettings);

    DBUser.BeginTransaction;

    try

      if PageControlCreation.TabIndex = 0

      then // Copie

        DBUser.ExecSQL('INSERT INTO Ingredients (Id, Name, Definition, Class, Model, MS, Bonus) VALUES ('

          + Format('%d, ', [NewId])

          + Format('%s, ', [QuotedStr(NewName)])

          + Format('%s, ', [QuotedStr(NewComment)])

          + Format('%d, ', [ComboBoxClass.ItemIndex + 1])

          + Format('%d, ', [ValidateEditModel.AsInteger])

          + Format('%.15f, ', [InputProximal(ValidateEditMSCopy.AsFloat, 1, 1, ComboBoxMSCopy.ItemIndex)], USFormatSettings)

          + '0)')

      else // Cr?ation originale

      begin

        DBUser.ExecSQL('INSERT INTO Ingredients (Id, Name, Definition, Class, MS, Bonus) VALUES ('

          + Format('%d, ', [NewId])

          + Format('%s, ', [QuotedStr(NewName)])

          + Format('%s, ', [QuotedStr(NewComment)])

          + Format('%d, ', [ComboBoxClass.ItemIndex + 1])

          + Format('%.15f, ', [RapMS], USFormatSettings)

          + '0)');

        if CheckBoxMM.Checked

        then

          DBUser.ExecSQL('UPDATE Ingredients '

            + Format('SET MM = %.15f ', [InputProximal(ValidateEditMM.AsFloat, RapMS, ComboBoxMM.ItemIndex div 2, ComboBoxMM.ItemIndex mod 2)], USFormatSettings)

            + Format('WHERE Id = %d', [NewId]));

        if CheckBoxMAT.Checked

        then

          DBUser.ExecSQL('UPDATE Ingredients '

            + Format('SET MAT = %.15f ', [InputProximal(ValidateEditMAT.AsFloat, RapMS, ComboBoxMAT.ItemIndex div 2, ComboBoxMAT.ItemIndex mod 2)], USFormatSettings)

            + Format('WHERE Id = %d', [NewId]));

        if CheckBoxMG.Checked

        then

          DBUser.ExecSQL('UPDATE Ingredients '

            + Format('SET MG = %.15f ', [InputProximal(ValidateEditMG.AsFloat, RapMS, ComboBoxMG.ItemIndex div 2, ComboBoxMG.ItemIndex mod 2)], USFormatSettings)

            + Format('WHERE Id = %d', [NewId]));

        if CheckBoxEB.Checked

        then

          DBUser.ExecSQL('UPDATE Ingredients '

            + Format('SET EB = %.15f ', [InputEnergy(ValidateEditEB.AsFloat, RapMS, ComboBoxEB.ItemIndex div 2, ComboBoxEB.ItemIndex mod 2)], USFormatSettings)

            + Format('WHERE Id = %d', [NewId]));

        if CheckBoxCB.Checked

        then

          DBUser.ExecSQL('UPDATE Ingredients '

            + Format('SET CB = %.15f ', [InputProximal(ValidateEditCB.AsFloat, RapMS, ComboBoxFibre.ItemIndex div 2, ComboBoxFibre.ItemIndex mod 2)], USFormatSettings)

            + Format('WHERE Id = %d', [NewId]));

        if CheckBoxNDF.Checked

        then

          DBUser.ExecSQL('UPDATE Ingredients '

            + Format('SET NDF = %.15f ', [InputProximal(ValidateEditNDF.AsFloat, RapMS, ComboBoxFibre.ItemIndex div 2, ComboBoxFibre.ItemIndex mod 2)], USFormatSettings)

            + Format('WHERE Id = %d', [NewId]));

        if CheckBoxADF.Checked

        then

          DBUser.ExecSQL('UPDATE Ingredients '

            + Format('SET ADF = %.15f ', [InputProximal(ValidateEditADF.AsFloat, RapMS, ComboBoxFibre.ItemIndex div 2, ComboBoxFibre.ItemIndex mod 2)], USFormatSettings)

            + Format('WHERE Id = %d', [NewId]));

        if CheckBoxAmidon.Checked

        then

          DBUser.ExecSQL('UPDATE Ingredients '

            + Format('SET Amidon = %.15f ', [InputProximal(ValidateEditAmidon.AsFloat, RapMS, ComboBoxAmidon.ItemIndex div 2, ComboBoxAmidon.ItemIndex mod 2)], USFormatSettings)

            + Format('WHERE Id = %d', [NewId]));

        if CheckBoxSucres.Checked

        then

          DBUser.ExecSQL('UPDATE Ingredients '

            + Format('SET Sucres = %.15f ', [InputProximal(ValidateEditSucres.AsFloat, RapMS, ComboBoxSucres.ItemIndex div 2, ComboBoxSucres.ItemIndex mod 2)], USFormatSettings)

            + Format('WHERE Id = %d', [NewId]));

      end;

      DBUser.Commit;

    except

      DBUser.RollBack;

      MessageDlg(Format(_('Unknown error: %s %s %s'), ['UnitIngredientCreation', 'ActionOKExecute', 'DBUser (INSERT INTO Ingredients / UPDATE Ingredients)']), mtError, [mbOK], 0);

      Exit;

    end;

    // Ajouter dans ClientDataSetIngredients

    Application.ProcessMessages;

    TableIngredients := DBUser.GetTable('SELECT * FROM Ingredients '

      + Format('WHERE Id = %d', [NewId]));

    ClientDataSetIngredients.Append;

    try

      ClientDataSetIngredientsId.Value := NewId;

      ClientDataSetIngredientsName.Value := NewName;

      ClientDataSetIngredientsDefinition.Value := NewComment;

      ClientDataSetIngredientsClass.Value := ComboBoxClass.ItemIndex + 1;

      ClientDataSetIngredientsUser.Value := True;

      if PageControlCreation.TabIndex = 0

      then // Copie bas?e sur un mod?le

      begin

        ClientDataSetIngredientsModel.Value := ValidateEditModel.AsInteger;

        ClientDataSetInraAfz.Locate('Id', ClientDataSetIngredientsModel.Value, []);

        ClientDataSetIngredientsSource.Value := Format(_('Copy of "%s"'), [dgettext('InraAfz', WideString(ClientDataSetInraAfzName.Value))]);

        CalcCopy;

      end

      else // Cr?ation originale

      begin

        ClientDataSetIngredientsSource.Value := _('Original item');

        CalcOriginal;

      end;

      ClientDataSetIngredients.Post;

    except

      ClientDataSetIngredients.Cancel;

      MessageDlg(Format(_('Unknown error: %s %s %s'), ['UnitIngredientCreation', 'ActionOKExecute', 'ClientDataSetIngredients']), mtError, [mbOK], 0);

      Exit;

    end;

    TableIngredients.Free;

    // Ajouter le nom dans la liste des mati?res premi?res utilisateur

    UserList.Add(NewName);

  end;

  ModalResult := mrOk;

end;

procedure TFormIngredientCreation.ButtonNextClick(Sender: TObject);

begin

  if ValidateEditMSOriginal.Value = 0

  then

  begin

    MessageDlg(_('You must specify a dry matter value for this ingredient.'), mtError, [mbOK], 0);

    ActiveControl := ValidateEditMSOriginal;

  end

  else

  begin

    CheckBoxMM.Enabled := True;

    ComboBoxMM.Enabled := True;

    CheckBoxMAT.Enabled := True;

    ComboBoxMAT.Enabled := True;

    CheckBoxCB.Enabled := True;

    CheckBoxNDF.Enabled := True;

    CheckBoxADF.Enabled := True;

    ComboBoxFibre.Enabled := True;

    CheckBoxMG.Enabled := True;

    ComboBoxMG.Enabled := True;

    CheckBoxEB.Enabled := True;

    ComboBoxEB.Enabled := True;

    CheckBoxAmidon.Enabled := True;

    ComboBoxAmidon.Enabled := True;

    CheckBoxSucres.Enabled := True;

    ComboBoxSucres.Enabled := True;

    ActiveControl := CheckBoxMM;

    ValidateEditMSOriginal.Enabled := False;

    ComboBoxMSOriginal.Enabled := False;

    ButtonNext.Visible := False;

  end;

end;

procedure TFormIngredientCreation.CheckBoxADFClick(Sender: TObject);

begin

  if CheckBoxADF.Checked

  then // Activer la saisie

    EditActivate(ValidateEditADF)

  else // Valeur inconnue

    EditEmpty(ValidateEditADF);

  ComboBoxFibreChange(nil);

end;

procedure TFormIngredientCreation.CheckBoxAmidonClick(Sender: TObject);

begin

  if CheckBoxAmidon.Checked

  then // Activer la saisie

    EditActivate(ValidateEditAmidon)

  else // Valeur inconnue

    EditEmpty(ValidateEditAmidon);

  ComboBoxAmidonChange(nil);

end;

procedure TFormIngredientCreation.CheckBoxCBClick(Sender: TObject);

begin

  if CheckBoxCB.Checked

  then // Activer la saisie

    EditActivate(ValidateEditCB)

  else // Valeur inconnue

    EditEmpty(ValidateEditCB);

  ComboBoxFibreChange(nil);

end;

procedure TFormIngredientCreation.CheckBoxEBClick(Sender: TObject);

begin

  if CheckBoxEB.Checked

  then // Activer la saisie

    EditActivate(ValidateEditEB)

  else // Valeur inconnue

    EditEmpty(ValidateEditEB);

  ComboBoxEBChange(nil);

end;

procedure TFormIngredientCreation.CheckBoxMATClick(Sender: TObject);

begin

  if CheckBoxMAT.Checked

  then // Activer la saisie

    EditActivate(ValidateEditMAT)

  else // Valeur inconnue

    EditEmpty(ValidateEditMAT);

  ComboBoxMATChange(nil);

end;

procedure TFormIngredientCreation.CheckBoxMGClick(Sender: TObject);

begin

  if CheckBoxMG.Checked

  then // Activer la saisie

    EditActivate(ValidateEditMG)

  else // Valeur inconnue

    EditEmpty(ValidateEditMG);

  ComboBoxMGChange(nil);

end;

procedure TFormIngredientCreation.CheckBoxMMClick(Sender: TObject);

begin

  if CheckBoxMM.Checked

  then // Activer la saisie

    EditActivate(ValidateEditMM)

  else // Valeur inconnue

    EditEmpty(ValidateEditMM);

  ComboBoxMMChange(nil);

end;

procedure TFormIngredientCreation.CheckBoxNDFClick(Sender: TObject);

begin

  if CheckBoxNDF.Checked

  then // Activer la saisie

    EditActivate(ValidateEditNDF)

  else // Valeur inconnue

    EditEmpty(ValidateEditNDF);

  ComboBoxFibreChange(nil);

end;

procedure TFormIngredientCreation.CheckBoxSucresClick(Sender: TObject);

begin

  if CheckBoxSucres.Checked

  then // Activer la saisie

    EditActivate(ValidateEditSucres)

  else // Valeur inconnue

    EditEmpty(ValidateEditSucres);

  ComboBoxSucresChange(nil);

end;

procedure TFormIngredientCreation.ComboBoxAmidonChange(Sender: TObject);

begin

  if ComboBoxAmidon.ItemIndex mod 2 = 0

  then // %

  begin

    ValidateEditAmidon.DecimalPlaces := 2;

    ValidateEditAmidon.MaxValue := 100;

  end

  else // g/kg

  begin

    ValidateEditAmidon.DecimalPlaces := 1;

    ValidateEditAmidon.MaxValue := 1000;

  end;

end;

procedure TFormIngredientCreation.ComboBoxClassChange(Sender: TObject);

var

  Model: String;

begin

  ModelList.Clear;

  with DataModuleDeclaration do

  begin

    ClientDataSetInraAfz.Filtered := False;

    if ComboBoxClass.ItemIndex <> -1

    then

    begin

      ClientDataSetInraAfz.Filter := Format('Class = %d', [ComboBoxClass.ItemIndex + 1]);

      ClientDataSetInraAfz.Filtered := True;

    end;

    ClientDataSetInraAfz.First;

    while not ClientDataSetInraAfz.Eof do

    begin

      ModelList.Add(dgettext('InraAfz', WideString(ClientDataSetInraAfzName.Value)));

      ClientDataSetInraAfz.Next;

    end;

  end;

  Model := ComboBoxModel.Text;

  ComboBoxModel.Clear;

  ComboBoxModel.Items.Assign(ModelList);

  ComboBoxModel.ItemIndex := ComboBoxModel.Items.IndexOf(Model);

end;

procedure TFormIngredientCreation.ComboBoxEBChange(Sender: TObject);

begin

  if ComboBoxEB.ItemIndex mod 2 = 0

  then // MJ/kg

    ValidateEditEB.DecimalPlaces := 2

  else // kcal/kg

    ValidateEditEB.DecimalPlaces := 0;

end;

procedure TFormIngredientCreation.ComboBoxFibreChange(Sender: TObject);

begin

  if ComboBoxFibre.ItemIndex mod 2 = 0

  then // %

  begin

    ValidateEditCB.DecimalPlaces := 2;

    ValidateEditNDF.DecimalPlaces := 2;

    ValidateEditADF.DecimalPlaces := 2;

    ValidateEditCB.MaxValue := 100;

    ValidateEditNDF.MaxValue := 100;

    ValidateEditADF.MaxValue := 100;

  end

  else // g/kg

  begin

    ValidateEditCB.DecimalPlaces := 1;

    ValidateEditNDF.DecimalPlaces := 1;

    ValidateEditADF.DecimalPlaces := 1;

    ValidateEditCB.MaxValue := 1000;

    ValidateEditNDF.MaxValue := 1000;

    ValidateEditADF.MaxValue := 1000;

  end;

end;

procedure TFormIngredientCreation.ComboBoxMATChange(Sender: TObject);

begin

  if ComboBoxMAT.ItemIndex mod 2 = 0

  then // %

  begin

    ValidateEditMAT.DecimalPlaces := 2;

    ValidateEditMAT.MaxValue := 100;

  end

  else // g/kg

  begin

    ValidateEditMAT.DecimalPlaces := 1;

    ValidateEditMAT.MaxValue := 1000;

  end;

end;

procedure TFormIngredientCreation.ComboBoxMGChange(Sender: TObject);

begin

  if ComboBoxMG.ItemIndex mod 2 = 0

  then // %

  begin

    ValidateEditMG.DecimalPlaces := 2;

    ValidateEditMG.MaxValue := 100;

  end

  else // g/kg

  begin

    ValidateEditMG.DecimalPlaces := 1;

    ValidateEditMG.MaxValue := 1000;

  end;

end;

procedure TFormIngredientCreation.ComboBoxMMChange(Sender: TObject);

begin

  if ComboBoxMM.ItemIndex mod 2 = 0

  then // %

  begin

    ValidateEditMM.DecimalPlaces := 2;

    ValidateEditMM.MaxValue := 100;

  end

  else // g/kg

  begin

    ValidateEditMM.DecimalPlaces := 1;

    ValidateEditMM.MaxValue := 1000;

  end;

end;

procedure TFormIngredientCreation.ComboBoxModelChange(Sender: TObject);

begin

  if ComboBoxModel.ItemIndex <> -1

  then

    with DataModuleDeclaration do

    begin

      ClientDataSetInraAfz.RecNo := ModelList.IndexOf(ComboBoxModel.Text) + 1;

      ValidateEditModel.AsInteger := ClientDataSetInraAfzId.Value;

      ValidateEditMSCopy.AsFloat := OutputProximal(ClientDataSetInraAfzMS.Value, 1, 1, FormOptions.Proximal);

      ComboBoxClass.ItemIndex := ClientDataSetInraAfzClass.Value - 1;

      ComboBoxClassChange(nil);

    end;

end;

procedure TFormIngredientCreation.ComboBoxMSCopyChange(Sender: TObject);

begin

  if ComboBoxMSCopy.ItemIndex = 0

  then // %

  begin

    ValidateEditMSCopy.DecimalPlaces := 2;

    ValidateEditMSCopy.MaxValue := 100;

  end

  else // g/kg

  begin

    ValidateEditMSCopy.DecimalPlaces := 1;

    ValidateEditMSCopy.MaxValue := 1000;

  end;

end;

procedure TFormIngredientCreation.ComboBoxMSOriginalChange(Sender: TObject);

begin

  if ComboBoxMSOriginal.ItemIndex = 0

  then // %

  begin

    ValidateEditMSOriginal.DecimalPlaces := 2;

    ValidateEditMSOriginal.MaxValue := 100;

  end

  else // g/kg

  begin

    ValidateEditMSOriginal.DecimalPlaces := 1;

    ValidateEditMSOriginal.MaxValue := 1000;

  end;

end;

procedure TFormIngredientCreation.ComboBoxSucresChange(Sender: TObject);

begin

  if ComboBoxSucres.ItemIndex mod 2 = 0

  then // %

  begin

    ValidateEditSucres.DecimalPlaces := 2;

    ValidateEditSucres.MaxValue := 100;

  end

  else // g/kg

  begin

    ValidateEditSucres.DecimalPlaces := 1;

    ValidateEditSucres.MaxValue := 1000;

  end;

end;

procedure TFormIngredientCreation.EditActivate(Edit: TJvValidateEdit);

begin

  Edit.DisplayFormat := dfFloat;

  Edit.Enabled := True;

  ActiveControl := Edit;

  Edit.SelectAll;

end;

procedure TFormIngredientCreation.EditEmpty(Edit: TJvValidateEdit);

begin

  Edit.DisplayFormat := dfNone;

  Edit.Value := '';

  Edit.Enabled := False;

end;

procedure TFormIngredientCreation.FormCreate(Sender: TObject);

var

  i: Integer;

begin

  if Screen.Fonts.IndexOf('Arial Unicode MS') <> -1

  then

    Font.Name := 'Arial Unicode MS';

//  PanelButtons.Font.Size := PanelButtons.Font.Size + 2;

  PanelButtons.Font.Style := [fsBold];

  LabelName.Font.Style := [fsBold];

  EditName.Font.Style := [fsBold];

  LabelMSCopyWarning.Font.Color := clRed;

  LabelMSOriginalWarning.Font.Color := clRed;

  TranslateComponent(Self);

  ComboBoxMSCopy.ItemIndex := FormOptions.Proximal;

  ComboBoxMSCopyChange(nil);

  ComboBoxMSOriginal.ItemIndex := FormOptions.Proximal;

  ComboBoxMSOriginalChange(nil);

  for i := 0 to FormOptions.ComboBoxProximal.Items.Count - 1 do

    ComboBoxMM.Items.Add(Format('%s %s', [FormOptions.ComboBoxProximal.Items[i], _('DM')]));

  ComboBoxMM.ItemIndex := FormOptions.Proximal + 2 * FormOptions.Expression;

  ComboBoxMMChange(nil);

  for i := 0 to FormOptions.ComboBoxProximal.Items.Count - 1 do

    ComboBoxMAT.Items.Add(Format('%s %s', [FormOptions.ComboBoxProximal.Items[i], _('DM')]));

  ComboBoxMAT.ItemIndex := FormOptions.Proximal + 2 * FormOptions.Expression;

  ComboBoxMATChange(nil);

  for i := 0 to FormOptions.ComboBoxProximal.Items.Count - 1 do

    ComboBoxMG.Items.Add(Format('%s %s', [FormOptions.ComboBoxProximal.Items[i], _('DM')]));

  ComboBoxMG.ItemIndex := FormOptions.Proximal + 2 * FormOptions.Expression;

  ComboBoxMGChange(nil);

  for i := 0 to FormOptions.ComboBoxEnergy.Items.Count - 1 do

    ComboBoxEB.Items.Add(Format('%s %s', [FormOptions.ComboBoxEnergy.Items[i], _('DM')]));

  ComboBoxEB.ItemIndex := FormOptions.Energy + 2 * FormOptions.Expression;

  ComboBoxEBChange(nil);

  for i := 0 to FormOptions.ComboBoxProximal.Items.Count - 1 do

    ComboBoxFibre.Items.Add(Format('%s %s', [FormOptions.ComboBoxProximal.Items[i], _('DM')]));

  ComboBoxFibre.ItemIndex := FormOptions.Proximal + 2 * FormOptions.Expression;

  ComboBoxFibreChange(nil);

  for i := 0 to FormOptions.ComboBoxProximal.Items.Count - 1 do

    ComboBoxAmidon.Items.Add(Format('%s %s', [FormOptions.ComboBoxProximal.Items[i], _('DM')]));

  ComboBoxAmidon.ItemIndex := FormOptions.Proximal + 2 * FormOptions.Expression;

  ComboBoxAmidonChange(nil);

  for i := 0 to FormOptions.ComboBoxProximal.Items.Count - 1 do

    ComboBoxSucres.Items.Add(Format('%s %s', [FormOptions.ComboBoxProximal.Items[i], _('DM')]));

  ComboBoxSucres.ItemIndex := FormOptions.Proximal + 2 * FormOptions.Expression;

  ComboBoxSucresChange(nil);

  ModelList := TStringList.Create;

  with DataModuleDeclaration do

  begin

    // Classes

    ClientDataSetClasses.First;

    while not ClientDataSetClasses.Eof do

    begin

      ComboBoxClass.Items.Add(ClientDataSetClassesName.Value);

      ClientDataSetClasses.Next;

    end;

    ComboBoxClassChange(nil); // Contruction de la liste des mod?les

    // Mod?le

    if not ClientDataSetIngredientsUser.Value

    then // Pr?s?lectionner l'enregistrement courant

    begin

      ComboBoxModel.ItemIndex := ComboBoxModel.Items.IndexOf(ClientDataSetIngredientsName.Value);

      ComboBoxModelChange(nil);

    end;

  end;

  PageControlCreation.TabIndex := 0;

  ActiveControl := EditName;

end;

procedure TFormIngredientCreation.FormDestroy(Sender: TObject);

begin

  with DataModuleDeclaration do

    ClientDataSetInraAfz.Filtered := False;

end;

procedure TFormIngredientCreation.NumEditKeyDown(Sender: TObject;

  var Key: Word; Shift: TShiftState);

begin

  // D?tection de l'appui sur le s?parateur d?cimal du pav? num?rique

  VK_Separator := (Key = VK_DECIMAL);

end;

procedure TFormIngredientCreation.NumEditKeyPress(Sender: TObject;

  var Key: Char);

begin

  if VK_Separator then

    // Renvoyer le s?parateur d?cimal des options r?gionales et linguistiques

    Key := DecimalSeparator;

end;

end.