EvaPig

unit UnitFeedCreation;

interface

uses

  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,

  Dialogs, gnugettext, StdCtrls, Grids, DBGrids, DB, ImgList, ActnList,

  JvExStdCtrls, JvButton, JvCtrls, ExtCtrls;

type

  TFormFeedCreation = class(TForm)

    CheckBoxModel: TCheckBox;

    LabelName: TLabel;

    LabelDescription: TLabel;

    ComboBoxModel: TComboBox;

    EditName: TEdit;

    MemoDescription: TMemo;

    JvImgBtnCancel: TJvImgBtn;

    JvImgBtnOK: TJvImgBtn;

    JvImgBtnHelp: TJvImgBtn;

    ActionListButtons: TActionList;

    ActionHelp: TAction;

    ActionOK: TAction;

    ActionCancel: TAction;

    ImageListIcons: TImageList;

    PanelButtons: TPanel;

    procedure FormCreate(Sender: TObject);

    procedure CheckBoxModelClick(Sender: TObject);

    procedure ActionHelpExecute(Sender: TObject);

    procedure ActionOKExecute(Sender: TObject);

    procedure ActionCancelExecute(Sender: TObject);

  private

    { D?clarations priv?es }

  public

    { D?clarations publiques }

  end;

var

  FormFeedCreation: TFormFeedCreation;

implementation

{$R *.dfm}

uses

  UnitDeclaration, UnitOptions;

procedure TFormFeedCreation.ActionCancelExecute(Sender: TObject);

begin

  ModalResult := mrCancel;

end;

procedure TFormFeedCreation.ActionHelpExecute(Sender: TObject);

begin

  Application.HelpContext(HelpContext);

end;

procedure TFormFeedCreation.ActionOKExecute(Sender: TObject);

var

  NewId, ModelId: Integer;

  NewName, NewComment: String;

  USFormatSettings: TFormatSettings;

begin

  NewName := Trim(EditName.Text);

  NewComment := MemoDescription.Text;

  if NewName = ''

  then

  begin

    MessageDlg(_('You must specify a name for this diet.'), mtError, [mbOK], 0);

    ActiveControl := EditName;

    Exit;

  end;

  if DataModuleDeclaration.FeedList.IndexOf(NewName) <> -1

  then

  begin

    MessageDlg(_('This name is already used, please specify another name.'), mtError, [mbOK], 0);

    ActiveControl := EditName;

    Exit;

  end;

  if CheckBoxModel.Checked and (ComboBoxModel.ItemIndex = -1)

  then

  begin

    MessageDlg(_('You must specify a template for this feed.'), mtError, [mbOK], 0);

    ActiveControl := ComboBoxModel;

    Exit;

  end;

  with DataModuleDeclaration do

  begin

    // Rechercher une valeur pour le champs Id

    TableFeeds := DBUser.GetTable('SELECT Id FROM Feeds ORDER BY Id');

    with TableFeeds do

      try

        if RowCount > 0

        then

        begin

          MoveLast;

          NewId := FieldAsInteger(FieldIndex['Id']) + 1;

        end

        else

          NewId := 1;

      finally

        Free;

      end;

    // Cr?er le nouveau r?gime

    GetLocaleFormatSettings(1033, USFormatSettings);

    DBUser.BeginTransaction;

    try

      if CheckBoxModel.Checked

      then // Copier les informations du mod?le

      begin

        ClientDataSetFeeds.Locate('Name', ComboBoxModel.Text, []);

        //ClientDataSetFeeds.RecNo := FeedList.IndexOf(ComboBoxModel.Text) + 1;

        ModelId := ClientDataSetFeedsId.Value;

        DBUser.ExecSQL('INSERT INTO Feeds (Id, Name, Description, Presentation, BonusC, BonusT) VALUES ('

          + Format('%d, ', [NewId])

          + Format('%s, ', [QuotedStr(NewName)])

          + Format('%s, ', [QuotedStr(NewComment)])

          + Format('%d, ', [ClientDataSetFeedsPresentation.Value])

          + Format('%.3f, ', [ClientDataSetFeedsBonusC.Value / 100], USFormatSettings)

          + Format('%.3f)', [ClientDataSetFeedsBonusT.Value / 100], USFormatSettings));

        if not ClientDataSetFeedsPhytaseId.IsNull

        then

          DBUser.ExecSQL('UPDATE Feeds '

            + Format('SET Phytase = %d ', [ClientDataSetFeedsPhytaseId.Value])

            + Format('WHERE Id = %d', [NewId]));

        if not ClientDataSetFeedsPhytaseConcentration.IsNull

        then

          DBUser.ExecSQL('UPDATE Feeds '

            + Format('SET Concentration = %.0f ', [ClientDataSetFeedsPhytaseConcentration.Value], USFormatSettings)

            + Format('WHERE Id = %d', [NewId]));

        if not ClientDataSetFeedsPhytaseIncorporation.IsNull

        then

          DBUser.ExecSQL('UPDATE Feeds '

            + Format('SET Incorporation = %.0f ', [ClientDataSetFeedsPhytaseIncorporation.Value], USFormatSettings)

            + Format('WHERE Id = %d', [NewId]));

      end

      else

        DBUser.ExecSQL('INSERT INTO Feeds (Id, Name, Description, Presentation, BonusC, BonusT) VALUES ('

          + Format('%d, ', [NewId])

          + Format('%s, ', [QuotedStr(NewName)])

          + Format('%s, ', [QuotedStr(NewComment)])

          + '0, '

          + '0, '

          + '0)');

      DBUser.Commit;

    except

      DBUser.RollBack;

      MessageDlg(Format(_('Unknown error: %s %s %s'), ['UnitFeedCreation', 'ActionOKExecute', 'DBUser (INSERT INTO Feeds / UPDATE Feeds)']), mtError, [mbOK], 0);

      Exit;

    end;

    if CheckBoxModel.Checked

    then // Copier la composition du mod?le

    begin

      ClientDataSetComposition.Filter := Format('Feed = %d', [ModelId]);

      ClientDataSetComposition.Filtered := True;

      DBUser.BeginTransaction;

      try

        ClientDataSetComposition.First;

        while not ClientDataSetComposition.Eof do

        begin

          ClientDataSetCompositionUser.DisplayValues := DefaultTrueBoolStr + ';' + DefaultFalseBoolStr;

          DBUser.ExecSQL('INSERT INTO Composition (Feed, Ingredient, User, Rank, MS, Level) VALUES ('

            + Format('%d, ', [NewId])

            + Format('%d, ', [ClientDataSetCompositionIngredient.Value])

            + Format('''%s'', ', [ClientDataSetCompositionUser.AsString])

            + Format('%d, ', [ClientDataSetCompositionRank.Value])

            + Format('%.15f, ', [InputProximal(ClientDataSetCompositionMS.Value, 1, 1, FormOptions.Proximal)], USFormatSettings)

            + Format('%.15f)', [InputIncorporation(ClientDataSetCompositionLevel.Value, FormOptions.Incorporation)], USFormatSettings));

          ClientDataSetComposition.Next;

        end;

        DBUser.Commit;

      except

        DBUser.RollBack;

        MessageDlg(Format(_('Unknown error: %s %s %s'), ['UnitFeedCreation', 'ActionOKExecute', 'DBUser (INSERT INTO Composition)']), mtError, [mbOK], 0);

        Exit;

      end;

      ClientDataSetComposition.Filtered := False;

      ClientDataSetComposition.Filter := '';

      // R?percuter dans ClientDataSetComposition

      Application.ProcessMessages;

      TableComposition := DBUser.GetTable('SELECT * FROM Composition '

        + Format('WHERE Feed = %d', [NewId]));

      while not TableComposition.Eof do

      begin

        ClientDataSetComposition.Append;

        try

          ClientDataSetCompositionFeed.Value := NewId;

          ClientDataSetCompositionIngredient.Value := TableComposition.FieldAsInteger(TableComposition.FieldIndex['Ingredient']);

          ClientDataSetCompositionUser.Value := (TableComposition.FieldAsString(TableComposition.FieldIndex['User']) = DefaultTrueBoolStr);

          if ClientDataSetCompositionUser.Value

          then

            ClientDataSetIngredients.Filter := Format('Id = %d and User', [ClientDataSetCompositionIngredient.Value])

          else

            ClientDataSetIngredients.Filter := Format('Id = %d and not User', [ClientDataSetCompositionIngredient.Value]);

          ClientDataSetIngredients.Filtered := True;

          ClientDataSetCompositionIngredientName.Value := ClientDataSetIngredientsName.Value;

          ClientDataSetIngredients.Filtered := False;

          ClientDataSetIngredients.Filter := '';

          ClientDataSetCompositionRank.Value := TableComposition.FieldAsInteger(TableComposition.FieldIndex['Rank']);

          ClientDataSetCompositionMS.Value := OutputProximal(TableComposition.FieldAsDouble(TableComposition.FieldIndex['MS']), 1, 0, FormOptions.Proximal);

          ClientDataSetCompositionLevel.Value := OutputIncorporation(TableComposition.FieldAsDouble(TableComposition.FieldIndex['Level']), FormOptions.Incorporation);

          ClientDataSetComposition.Post;

        except

          ClientDataSetComposition.Cancel;

          MessageDlg(Format(_('Unknown error: %s %s %s'), ['UnitFeedCreation', 'ActionOKExecute', 'ClientDataSetComposition']), mtError, [mbOK], 0);

          Exit;

        end;

        TableComposition.Next;

      end;

      TableComposition.Free;

    end;

    // Ajouter dans ClientDataSetFeeds

    Application.ProcessMessages;

    TableFeeds := DBUser.GetTable('SELECT * FROM Feeds '

      + Format('WHERE Id = %d', [NewId]));

    ClientDataSetComposition.Filter := Format('Feed = %d', [NewId]);

    ClientDataSetComposition.Filtered := True;

    ClientDataSetFeeds.Append;

    try

      ClientDataSetFeedsId.Value := NewId;

      ClientDataSetFeedsName.Value := NewName;

      ClientDataSetFeedsDescription.Value := NewComment;

      ClientDataSetFeedsPresentation.Value := TableFeeds.FieldAsInteger(TableFeeds.FieldIndex['Presentation']);

      ClientDataSetFeedsBonusC.Value := TableFeeds.FieldAsDouble(TableFeeds.FieldIndex['BonusC']) * 100;

      ClientDataSetFeedsBonusT.Value := TableFeeds.FieldAsDouble(TableFeeds.FieldIndex['BonusT']) * 100;

      if not TableFeeds.FieldIsNull(TableFeeds.FieldIndex['Phytase'])

      then

        ClientDataSetFeedsPhytaseId.Value := TableFeeds.FieldAsInteger(TableFeeds.FieldIndex['Phytase']);

      if not TableFeeds.FieldIsNull(TableFeeds.FieldIndex['Concentration'])

      then

        ClientDataSetFeedsPhytaseConcentration.Value := TableFeeds.FieldAsDouble(TableFeeds.FieldIndex['Concentration']);

      if not TableFeeds.FieldIsNull(TableFeeds.FieldIndex['Incorporation'])

      then

        ClientDataSetFeedsPhytaseIncorporation.Value := TableFeeds.FieldAsDouble(TableFeeds.FieldIndex['Incorporation']);

      CalcFeed;

      ClientDataSetFeeds.Post;

    except

      ClientDataSetFeeds.Cancel;

      MessageDlg(Format(_('Unknown error: %s %s %s'), ['UnitFeedCreation', 'ActionOKExecute', 'ClientDataSetFeeds']), mtError, [mbOK], 0);

      Exit;

    end;

    ClientDataSetComposition.Filtered := False;

    ClientDataSetComposition.Filter := '';

    TableFeeds.Free;

    // Ajouter le nom dans la liste des aliments

    FeedList.Add(NewName);

  end;

  ModalResult := mrOk;

end;

procedure TFormFeedCreation.CheckBoxModelClick(Sender: TObject);

begin

  ComboBoxModel.Enabled := CheckBoxModel.Checked;

end;

procedure TFormFeedCreation.FormCreate(Sender: TObject);

begin

  if Screen.Fonts.IndexOf('Arial Unicode MS') <> -1

  then

    Font.Name := 'Arial Unicode MS';

//  PanelButtons.Font.Size := PanelButtons.Font.Size + 2;

  PanelButtons.Font.Style := [fsBold];

  LabelName.Font.Style := [fsBold];

  EditName.Font.Style := [fsBold];

  TranslateComponent(Self);

  with DataModuleDeclaration do

    if ClientDataSetFeeds.IsEmpty

    then // Table aliment vide

      CheckBoxModel.Enabled := False

    else

    begin

      ComboBoxModel.Items.Assign(FeedList);

      ComboBoxModel.ItemIndex := ComboBoxModel.Items.IndexOf(ClientDataSetFeedsName.Value);

    end;

end;

end.