InraPorc

unit UFGraph3D;

interface

uses

  Windows, Forms, Classes, Controls, Messages, ComCtrls, StdCtrls, ExtCtrls,

  Grids, Chart, Series, TeeProcs, TeEngine, TeePoin3, TeeSurfa, PBNumEdit,

  PBSuperSpin, JvExControls, JvxSlider, UVariables;

type

  TFGraph3D = class(TForm)

    Chart3D: TChart;

    SeriesAdLib: TPoint3DSeries;

    PanelData: TPanel;

    GroupBoxX: TGroupBox;

    GroupBoxY: TGroupBox;

    GroupBoxZ: TGroupBox;

    ComboBoxX: TComboBox;

    ComboBoxY: TComboBox;

    ComboBoxZ: TComboBox;

    SliderRotation: TJvxSlider;

    Panel3D: TPanel;

    SliderElevation: TJvxSlider;

    SliderPerspective: TJvxSlider;

    SliderZoom: TJvxSlider;

    GroupBoxAdLib: TGroupBox;

    LabelA: TLabel;

    LabelUnite: TLabel;

    LabelEquation: TLabel;

    LabelB: TLabel;

    SuperSpinA: TPBSuperSpin;

    SuperSpinB: TPBSuperSpin;

    GroupBoxPotential: TGroupBox;

    LabelEntretien: TLabel;

    LabelPrecocite: TLabel;

    LabelPDMoy: TLabel;

    SuperSpinPDMoy: TPBSuperSpin;

    SuperSpinPrecocite: TPBSuperSpin;

    SuperSpinEntretien: TPBSuperSpin;

    LabelPVPDmax: TLabel;

    SuperSpinPVPDmax: TPBSuperSpin;

    GroupBoxType: TGroupBox;

    RadioButton2D: TRadioButton;

    RadioButton3D: TRadioButton;

    GroupBoxResult: TGroupBox;

    StringGridResult: TStringGrid;

    Panel2D: TPanel;

    TrackBarJour: TTrackBar;

    Chart2D: TChart;

    SeriesCourbePD: TLineSeries;

    SeriesLimitePD: TLineSeries;

    SeriesPointPD: TLineSeries;

    SeriesDroitePD: TLineSeries;

    SeriesCourbeLD: TLineSeries;

    SeriesPointLD: TLineSeries;

    SeriesDroiteLD: TLineSeries;

    LabelLimitPD2D: TLabel;

    SeriesSurface: TSurfaceSeries;

    SeriesRation: TPoint3DSeries;

    EditUnit: TEdit;

    EditEquation: TEdit;

    LabelLimitPD3D: TLabel;

    SeriesPointPDAdLib: TLineSeries;

    SeriesPointLDAdLib: TLineSeries;

    procedure FormShow(Sender: TObject);

    procedure FormClose(Sender: TObject; var Action: TCloseAction);

    procedure ComboBoxXChange(Sender: TObject);

    procedure ComboBoxYChange(Sender: TObject);

    procedure ComboBoxZChange(Sender: TObject);

    procedure SliderRotationChange(Sender: TObject);

    procedure SliderElevationChange(Sender: TObject);

    procedure SliderPerspectiveChange(Sender: TObject);

    procedure SliderZoomChange(Sender: TObject);

    procedure RadioButton2DClick(Sender: TObject);

    procedure RadioButton3DClick(Sender: TObject);

    procedure SuperSpinAChange(Sender: TObject);

    procedure SuperSpinBChange(Sender: TObject);

    procedure SuperSpinPDMoyChange(Sender: TObject);

    procedure SuperSpinPrecociteChange(Sender: TObject);

    procedure SuperSpinEntretienChange(Sender: TObject);

    procedure SuperSpinPVPDmaxChange(Sender: TObject);

    procedure StringGridResultDrawCell(Sender: TObject; ACol,

      ARow: Integer; Rect: TRect; State: TGridDrawState);

    procedure StringGridResultMouseMove(Sender: TObject;

      Shift: TShiftState; X, Y: Integer);

    procedure TrackBarJourChange(Sender: TObject);

    procedure FormCreate(Sender: TObject);

    procedure WMSysCommand(var Message: TWMSysCommand); message WM_SYSCOMMAND;

  private

    { D?clarations priv?es }

    Update : boolean ;

    PResSimulP: PTabResSimulP;

    procedure AfficheSimulation;

    procedure AfficheResult;

    procedure AfficheGraph2D;

    procedure AfficheGraph3D;

  public

    { D?clarations publiques }

  end;

var

  FGraph3D: TFGraph3D;

implementation

uses

  Graphics, Math, SysUtils, gnugettext, UCalcSimulP, UStrings, UFProfilP;

{$R *.dfm}

procedure TFGraph3D.FormCreate(Sender: TObject);

begin

  if Screen.Fonts.IndexOf('Arial Unicode MS') <> -1

  then

    Font.Name := 'Arial Unicode MS';

  TranslateComponent(Self);

  Constraints.MinWidth := 184 + (Width - ClientWidth);

  Width := 800;

  Constraints.MinHeight := 528 + (Height - ClientHeight);

  Height := 600;

  ComboBoxX.ItemIndex := 0;

  ComboBoxY.ItemIndex := 0;

  ComboBoxZ.ItemIndex := 0;

end;

procedure TFGraph3D.FormShow(Sender: TObject);

begin

  Update := True;

  EditUnit.Text := FProfilP.CBUnite.Text;

  EditEquation.Text := FProfilP.CBEquation.Text;

  SuperSpinA.Decimals := FProfilP.PBCoefA.Decimals;

  SuperSpinA.Increment := FProfilP.PBCoefA.Increment;

  SuperSpinA.AsFloat := FProfilP.PBCoefA.AsFloat;

  SuperSpinB.Decimals := FProfilP.PBCoefB.Decimals;

  SuperSpinB.Increment := FProfilP.PBCoefB.Increment;

  SuperSpinB.AsFloat := FProfilP.PBCoefB.AsFloat;

  SuperSpinPDMoy.AsFloat := FProfilP.PBPDMoy.AsFloat;

  SuperSpinPrecocite.AsFloat := FProfilP.PBComport.AsFloat;

  SuperSpinEntretien.AsFloat := FProfilP.PBEntretien.AsFloat;

  SuperSpinPVPDmax.AsFloat := FProfilP.PBPVmr2.AsFloat;

  Update := False;

  SliderRotation.Value := Chart3D.View3DOptions.Rotation;

  SliderElevation.Value := Chart3D.View3DOptions.Elevation;

  SliderPerspective.Value := Chart3D.View3DOptions.Perspective;

  SliderZoom.Value := Chart3D.View3DOptions.Zoom;

  New(PResSimulP);

  AfficheSimulation;

end;

procedure TFGraph3D.FormClose(Sender: TObject; var Action: TCloseAction);

begin

  Dispose(PResSimulP);

end;

procedure TFGraph3D.SuperSpinAChange(Sender: TObject);

begin

  if not Update

  then

  begin

    PProfilP.a := SuperSpinA.AsFloat;

    AfficheSimulation;

  end;

end;

procedure TFGraph3D.SuperSpinBChange(Sender: TObject);

begin

  if not Update

  then

  begin

    PProfilP.b := SuperSpinB.AsFloat;

    AfficheSimulation;

  end;

end;

procedure TFGraph3D.SuperSpinPDMoyChange(Sender: TObject);

begin

  if not Update and (SuperSpinPDMoy.AsInteger >= SuperSpinPDMoy.MinValue)

  then

  begin

    PProfilP.PDMoy := SuperSpinPDMoy.AsFloat;

    AfficheSimulation;

  end;

end;

procedure TFGraph3D.SuperSpinPrecociteChange(Sender: TObject);

begin

  if not Update and (SuperSpinPrecocite.AsFloat >= SuperSpinPrecocite.MinValue)

  then

  begin

    PProfilP.BGompertz := SuperSpinPrecocite.AsFloat;

    AfficheSimulation;

  end;

end;

procedure TFGraph3D.SuperSpinEntretienChange(Sender: TObject);

begin

  if not Update and (SuperSpinEntretien.AsFloat >= SuperSpinEntretien.MinValue)

  then

  begin

    PProfilP.Entretien := SuperSpinEntretien.AsFloat;

    AfficheSimulation;

  end;

end;

procedure TFGraph3D.SuperSpinPVPDmaxChange(Sender: TObject);

begin

  if not Update and (SuperSpinPVPDmax.AsFloat >= SuperSpinPVPDmax.MinValue)

  then

  begin

    PProfilP.PVmr2 := SuperSpinPVPDmax.AsFloat;

    AfficheSimulation;

  end;

end;

procedure TFGraph3D.RadioButton2DClick(Sender: TObject);

begin

  GroupBoxX.Visible := False;

  GroupBoxY.Visible := False;

  GroupBoxZ.Visible := False;

  Panel3D.Visible := False;

  GroupBoxResult.Visible := True;

  Panel2D.Visible := True;

  AfficheResult;

  AfficheGraph2D;

end;

procedure TFGraph3D.RadioButton3DClick(Sender: TObject);

begin

  GroupBoxResult.Visible := False;

  Panel2D.Visible := False;

  GroupBoxX.Visible := True;

  GroupBoxY.Visible := True;

  GroupBoxZ.Visible := True;

  Panel3D.Visible := True;

  AfficheGraph3D;

end;

procedure TFGraph3D.StringGridResultDrawCell(Sender: TObject; ACol,

  ARow: Integer; Rect: TRect; State: TGridDrawState);

begin

  with (Sender as TStringGrid).Canvas do

  begin

    if ACol = 0

    then // Titre

      Brush.Color := clBtnFace

    else // Donn?es

      Brush.Color := clWhite;

    // Fond

    FillRect(Rect);

    // Texte

    Font.Color := clDefault;

    SetTextAlign(Handle, TA_CENTER);

    TextRect(Rect, Rect.Left + (Rect.Right - Rect.Left) div 2, Rect.Top + 2, (Sender as TStringGrid).Cells[ACol, ARow]);

  end;

end;

procedure TFGraph3D.StringGridResultMouseMove(Sender: TObject;

  Shift: TShiftState; X, Y: Integer);

var

  Col, Lig: integer;

  Unite, s: String;

begin

  (Sender as TStringGrid).MouseToCell(X, Y, Col, Lig);

  // Unit?

  case Lig of

    0: Unite := _('d');

    1: Unite := _('kg');

    3: Unite := Format('%s/%s', [_('kg'), _('d')]);

    4, 6, 8: Unite := Format('%s/%s', [_('g'), _('d')]);

    5, 7: Unite := Format('%s/%s %s', [_('g'), _('kg'), _('feed')]);

    2, 9: Unite := Format('x %s', [_('maintenance')]);

  else

    Unite := '';

  end;

  // Hint

  case Lig of

    0: s := Format('%s (%s)', [_('Age'), Unite]);

    1: s := Format('%s (%s)', [_('Body weight'), Unite]);

    2: s := Format('%s (%s)', [_('Net energy intake'), Unite]);

    3: s := Format('%s (%s)', [_('Feed intake'), Unite]);

    4: s := Format('%s (%s)', [_('Protein deposition'), Unite]);

    5: s := Format('%s (%s)', [_('Marginal protein deposition'), Unite]);

    6: s := Format('%s (%s)', [_('Lipid deposition'), Unite]);

    7: s := Format('%s (%s)', [_('Marginal lipid deposition'), Unite]);

    8: s := Format('%s (%s)', [_('Protein deposition at the plateau'), Unite]);

    9: s := Format('%s (%s)', [_('Feeding level required to attain the plateau'), Unite]);

    10: s := _('Fraction of net energy deposited as protein');

  else

    s := '';

  end ;

  if (Sender as TStringGrid).Hint <> s

  then // Changement de cellule

  begin

    (Sender as TStringGrid).Hint := s;

    Application.ActivateHint(Mouse.CursorPos);

  end ;

end;

procedure TFGraph3D.TrackBarJourChange(Sender: TObject);

begin

  TrackBarJour.SelEnd := TrackBarJour.Position;

  AfficheResult;

  AfficheGraph2D;

end;

procedure TFGraph3D.ComboBoxXChange(Sender: TObject);

begin

  AfficheGraph3D;

end;

procedure TFGraph3D.ComboBoxYChange(Sender: TObject);

begin

  AfficheGraph3D;

end;

procedure TFGraph3D.ComboBoxZChange(Sender: TObject);

begin

  AfficheGraph3D;

end;

procedure TFGraph3D.AfficheSimulation;

begin

//  CalcSimulP(-1, -1, -1, -1, -1, 1, {1,} PResSimulP);

  CalcSimulP(-1, PProfilP.Num, PProfilP.SeqAli, PProfilP.Ration, -1, 1, PResSimulP);

  TrackBarJour.Max := PResSimulP.NbJSim;

  if RadioButton2D.Checked

  then

  begin

    AfficheResult;

    AfficheGraph2D;

  end

  else

    AfficheGraph3D;

end;

procedure TFGraph3D.AfficheResult;

var

  j: Integer;

  F, PDmaxE, a, b, px1, py1, PD, LD, NEmAL, NEcrois, PDLimit, PentePD, PenteLD, Correction: Double;

begin

  j := TrackBarJour.Position;

  F := PResSimulP.TabResult[52, j];

  PDmaxE := PResSimulP.TabResult[69, j];

  a := PResSimulP.TabResult[74, j];

  b := PResSimulP.TabResult[75, j];

  px1 := PResSimulP.TabResult[76, j];

  py1 := PResSimulP.TabResult[77, j];

  PD := PResSimulP.TabResult[79, j];

  LD := PResSimulP.TabResult[80, j];

  NEmAL := PResSimulP.TabResult[71, j];

  NEcrois := PResSimulP.TabResult[90, j] * 1000;

  PDLimit := PResSimulP.TabResult[47, j];

  if (px1 < F) and (PD < PDLimit)

  then

    PentePD := (a + 2 * b * (px1 - 1)) / GEProtJaap

  else

    PentePD := 0;

  if px1 < F

  then

    Correction := LD / ((NEmAL * (px1 - 1) - (a * (px1 - 1) + b * Power (px1 - 1, 2)) * (1 + NEPD)) / ValEnergie[2, 2])

  else

    Correction := LD / ((NEmAL * (px1 - 1) - PDmaxE * (1 + NEPD)) / ValEnergie[2, 2]);

  if px1 < F

  then

    PenteLD := Correction * ((NEmAL - (a + 2 * b * (px1 - 1)) * (1 + NEPD)) / ValEnergie[2, 2])

  else

    PenteLD := Correction * (NEmAL / ValEnergie[2, 2]);

  // Titre

  StringGridResult.Cells[0, 0] := StrAge;

  StringGridResult.Cells[0, 1] := StrPV;

  StringGridResult.Cells[0, 2] := StrEN;

  StringGridResult.Cells[0, 3] := StrIngere;

  StringGridResult.Cells[0, 4] := StrPD;

  StringGridResult.Cells[0, 5] := StrPDMarginal;

  StringGridResult.Cells[0, 6] := StrLD;

  StringGridResult.Cells[0, 7] := StrLDMarginal;

  StringGridResult.Cells[0, 8] := StrPDmax;

  StringGridResult.Cells[0, 9] := StrF;

  StringGridResult.Cells[0, 10] := StrX;

  // Valeurs

  StringGridResult.Cells[1, 0] := FloatToStrF(PResSimulP.TabResult[1, j], ffFixed, 15, 0);

  StringGridResult.Cells[1, 1] := FloatToStrF(PResSimulP.TabResult[2, j], ffFixed, 15, 1);

  StringGridResult.Cells[1, 2] := FloatToStrF(px1, ffFixed, 15, 2);

  StringGridResult.Cells[1, 3] := FloatToStrF(px1 * (NEmAL / NEcrois), ffFixed, 15, 2);

  StringGridResult.Cells[1, 4] := FloatToStrF(PD, ffFixed, 15, 1);

  StringGridResult.Cells[1, 5] := FloatToStrF(PentePD / (NEmAL / NEcrois), ffFixed, 15, 1);

  StringGridResult.Cells[1, 6] := FloatToStrF(LD, ffFixed, 15, 1);

  StringGridResult.Cells[1, 7] := FloatToStrF(PenteLD / (NEmAL / NEcrois), ffFixed, 15, 1);

  StringGridResult.Cells[1, 8] := FloatToStrF(PDmaxE / GEProtJaap, ffFixed, 15, 1);

  StringGridResult.Cells[1, 9] := FloatToStrF(F, ffFixed, 15, 2);

  StringGridResult.Cells[1, 10] := FloatToStrF((1 + NEPD) * py1 / ((px1 - 1) * NEmAL), ffFixed, 15, 2);

end;

procedure TFGraph3D.AfficheGraph2D;

const

  pas = 100;

var

  i, j: Integer;

  F, PDmaxE, a, b, px1, PD, LD, NEmAL, NEcrois, PDLimit, x, y, PentePD, PenteLD, Correction, px1AL: Double;

begin

  j := TrackBarJour.Position;

  F := PResSimulP.TabResult[52, j];

  PDmaxE := PResSimulP.TabResult[69, j];

  a := PResSimulP.TabResult[74, j];

  b := PResSimulP.TabResult[75, j];

  px1 := PResSimulP.TabResult[76, j];

  PD := PResSimulP.TabResult[79, j];

  LD := PResSimulP.TabResult[80, j];

  NEmAL := PResSimulP.TabResult[71, j];

  NEcrois := PResSimulP.TabResult[90, j] * 1000;

  PDLimit := PResSimulP.TabResult[47, j];

  px1AL := PResSimulP.TabResult[110, j];

  //

  // PD

  //

  // Courbe

  SeriesCourbePD.Clear;

  SeriesLimitePD.Clear;

  for i := 1 * pas to 6 * pas do

  begin

    x := i / pas;

    if x < F

    then // curvilin?aire

      y := (a * (x - 1) + b * Power(x - 1, 2)) / GEProtJaap

    else // plateau

      y := PDmaxE / GEProtJaap;

    SeriesCourbePD.AddXY(x, y, '', clTeeColor);

    if (PD = PDLimit) and (y > PD)

    then // pointill?s

      if i mod pas div 5 = 0 then SeriesLimitePD.AddXY(x, PD, '', clTeeColor);

  end;

  // Point

  SeriesPointPD.Clear;

  SeriesPointPD.AddXY(px1, PD, '', clTeeColor);

  // Droite

  SeriesDroitePD.Clear;

  if (px1 < F) and (PD < PDLimit)

  then

    PentePD := (a + 2 * b * (px1 - 1)) / GEProtJaap

  else

    PentePD := 0;

  SeriesDroitePD.AddXY(px1 - 1, PD - PentePD, '', clTeeColor);

  SeriesDroitePD.AddXY(px1 + 1, PD + PentePD, '', clTeeColor);

  // AdLib

  SeriesPointPDAdLib.Clear;

  if px1AL <> px1 then

  begin

    if px1AL < F

    then // curvilin?aire

      y := (a * (px1AL - 1) + b * Power(px1AL - 1, 2)) / GEProtJaap

    else // plateau

      y := PDmaxE / GEProtJaap;

    SeriesPointPDAdLib.AddXY(px1AL, y, '', clTeeColor);

  end;

  //

  // LD

  //

  if px1 < F

  then

    Correction := LD / ((NEmAL * (px1 - 1) - (a * (px1 - 1) + b * Power(px1 - 1, 2)) * (1 + NEPD)) / ValEnergie[2, 2])

  else

    Correction := LD / ((NEmAL * (px1 - 1) - PDmaxE * (1 + NEPD)) / ValEnergie[2, 2]);

  // Courbe

  SeriesCourbeLD.Clear;

  for i := 1 * pas to 6 * pas do

  begin

    x := i / pas;

    if x < F

    then

      y := Correction * ((NEmAL * (x - 1) - (a * (x - 1) + b * Power(x - 1, 2)) * (1 + NEPD)) / ValEnergie[2, 2])

    else

      y := Correction * ((NEmAL * (x - 1) - PDmaxE * (1 + NEPD)) / ValEnergie[2, 2]);

    SeriesCourbeLD.AddXY(x, y, '', clTeeColor);

  end ;

  // Point

  SeriesPointLD.Clear;

  SeriesPointLD.AddXY(px1, LD, '', clTeeColor);

  // Droite

  SeriesDroiteLD.Clear;

  if px1 < F

  then

    PenteLD := Correction * ((NEmAL - (a + 2 * b * (px1 - 1)) * (1 + NEPD)) / ValEnergie[2, 2])

  else

    PenteLD := Correction * (NEmAL / ValEnergie[2, 2]);

  SeriesDroiteLD.AddXY(px1 - 1, LD - PenteLD, '', clTeeColor);

  SeriesDroiteLD.AddXY(px1 + 1, LD + PenteLD, '', clTeeColor);

  // AdLib

  SeriesPointLDAdLib.Clear;

  if px1AL <> px1 then

  begin

    if px1AL < F

    then

      y := Correction * ((NEmAL * (px1AL - 1) - (a * (px1AL - 1) + b * Power(px1AL - 1, 2)) * (1 + NEPD)) / ValEnergie[2, 2])

    else

      y := Correction * ((NEmAL * (px1AL - 1) - PDmaxE * (1 + NEPD)) / ValEnergie[2, 2]);

    SeriesPointLDAdLib.AddXY(px1AL, y, '', clTeeColor);

  end;

  // Ajustement de la taille des axes

  Chart2D.TopAxis.Minimum := 0;

  Chart2D.TopAxis.Maximum := Chart2D.BottomAxis.Maximum * (NEmAL / NEcrois);

  Chart2D.TopAxis.Minimum := Chart2D.BottomAxis.Minimum * (NEmAL / NEcrois);

  LabelLimitPD2D.Visible := (PD = PDLimit);

end;

procedure TFGraph3D.AfficheGraph3D;

const

  pas = 10;

var

  i, j, debut, fin: Integer;

  x, y, z, entretien, F, PDmaxE, a, b, px1, LD, NEmAL, NEcrois, Correction: Double;

begin

  SeriesSurface.Clear;

  SeriesAdLib.Clear;

  SeriesRation.Clear;

  Chart3D.BottomAxis.Title.Caption := ComboBoxX.Text;

  Chart3D.LeftAxis.Title.Caption := ComboBoxY.Text;

  Chart3D.DepthAxis.Title.Caption := ComboBoxZ.Text;

  if ComboBoxZ.ItemIndex = 1

  then // x Entretien

  begin

    debut := 1 * pas;

    fin := 4 * pas;

  end

  else // kg aliment

  begin

    debut := 0 * pas;

    fin := 4 * pas;

  end;

  Chart3D.DepthAxis.Minimum := debut / pas;

  Chart3D.DepthAxis.Maximum := fin / pas;

  for j := 1 to PResSimulP.NbJSim do

  begin

    case ComboBoxX.ItemIndex of

      1: // Age

        x := PResSimulP.TabResult[1, j];

      2: // Poids vif

        x := PResSimulP.TabResult[2, j];

      else // Dur?e

        x := j;

    end;

    F := PResSimulP.TabResult[52, j];

    PDmaxE := PResSimulP.TabResult[69, j];

    a := PResSimulP.TabResult[74, j];

    b := PResSimulP.TabResult[75, j];

    px1 := PResSimulP.TabResult[76, j] ;

    LD := PResSimulP.TabResult[80, j];

    NEmAL := PResSimulP.TabResult[71, j];

    NEcrois := PResSimulP.TabResult[90, j] * 1000;

    if px1 < F

    then

      Correction := LD / ((NEmAL * (px1 - 1) - (a * (px1 - 1) + b * Power(px1 - 1, 2)) * (1 + NEPD)) / ValEnergie[2, 2])

    else

      Correction := LD / ((NEmAL * (px1 - 1) - PDmaxE * (1 + NEPD)) / ValEnergie[2, 2]) ;

    // Surface

    entretien := 1;

    if ComboBoxZ.ItemIndex = 1

    then // x Entretien

      z := entretien

    else // kg aliment

      z := Trunc(pas * (NEmAL / NEcrois)) / pas;

    SeriesSurface.AddXYZ(x, 0, z);

    for i := debut to fin do

    begin

      if ComboBoxZ.ItemIndex = 1

      then // x Entretien

        entretien := i / pas

      else // kg aliment

        entretien := i / pas / (NEmAL / NEcrois);

      if ComboBoxY.ItemIndex = 0

      then // PD

        if entretien < F

        then // curvilin?aire

          y := (a * (entretien - 1) + b * Power(entretien - 1, 2)) / GEProtJaap

        else // plateau

          y := PDmaxE / GEProtJaap

      else // LD

        if entretien < F

        then

          y := Correction * ((NEmAL * (entretien - 1) - (a * (entretien - 1) + b * Power(entretien - 1, 2)) * (1 + NEPD)) / ValEnergie[2, 2])

        else

          y := Correction * ((NEmAL * (entretien - 1) - PDmaxE * (1 + NEPD)) / ValEnergie[2, 2]);

      z := i / pas;

      if entretien > 1

      then

        SeriesSurface.AddXYZ(x, y, z);

    end ;

    // Ligne (ad libitum)

    entretien := PResSimulP.TabResult[110, j]; // px1AL

    if ComboBoxY.ItemIndex = 0

    then // PD

      if entretien < F

      then // curvilin?aire

        y := (a * (entretien - 1) + b * Power(entretien - 1, 2)) / GEProtJaap

      else // plateau

        y := PDmaxE / GEProtJaap

    else // LD

      if entretien < F

      then

        y := Correction * ((NEmAL * (entretien - 1) - (a * (entretien - 1) + b * Power(entretien - 1, 2)) * (1 + NEPD)) / ValEnergie[2, 2])

      else

        y := Correction * ((NEmAL * (entretien - 1) - PDmaxE * (1 + NEPD)) / ValEnergie[2, 2]);

    if ComboBoxZ.ItemIndex = 1

    then // x Entretien

      z := entretien

    else // kg aliment

      z := entretien * (NEmAL / NEcrois);

    SeriesAdLib.AddXYZ (x, y, z);

    // Ligne (plan de rationnement)

    entretien := px1;

    if ComboBoxY.ItemIndex = 0

    then // PD

      if entretien < F

      then // curvilin?aire

        y := (a * (entretien - 1) + b * Power(entretien - 1, 2)) / GEProtJaap

      else // plateau

        y := PDmaxE / GEProtJaap

    else // LD

      if entretien < F

      then

        y := Correction * ((NEmAL * (entretien - 1) - (a * (entretien - 1) + b * Power(entretien - 1, 2)) * (1 + NEPD)) / ValEnergie[2, 2])

      else

        y := Correction * ((NEmAL * (entretien - 1) - PDmaxE * (1 + NEPD)) / ValEnergie[2, 2]);

    if ComboBoxZ.ItemIndex = 1

    then // x Entretien

      z := entretien

    else // kg aliment

      z := entretien * (NEmAL / NEcrois);

    SeriesRation.AddXYZ (x, y, z);

  end;

  i := 0;

  for j := 1 to PResSimulP.NbJSim do

    if PResSimulP.TabResult[79, j] = PResSimulP.TabResult[47, j]

    then // PD = PDFirstLimit

      Inc(i);

  LabelLimitPD3D.Visible := (i > 0);

end;

procedure TFGraph3D.SliderRotationChange(Sender: TObject);

begin

  Chart3D.View3DOptions.Rotation := SliderRotation.Value;

end;

procedure TFGraph3D.SliderElevationChange(Sender: TObject);

begin

  Chart3D.View3DOptions.Elevation := SliderElevation.Value;

end;

procedure TFGraph3D.SliderPerspectiveChange(Sender: TObject);

begin

  Chart3D.View3DOptions.Perspective := SliderPerspective.Value;

end;

procedure TFGraph3D.SliderZoomChange(Sender: TObject);

begin

  Chart3D.View3DOptions.Zoom := SliderZoom.Value;

end;

procedure TFGraph3D.WMSysCommand(var Message: TWMSysCommand);

begin

  if Message.CmdType = SC_MINIMIZE

  then

    Application.Minimize

  else

    inherited;

end;

end.