InraPorc

unit UFRationP;

interface

uses

  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,

  Dialogs, StdCtrls, Buttons, ExtCtrls, Math, PBNumEdit, TeEngine, Series, 

  TeeProcs, Chart, JvExControls, JvComponent, JvEnterTab, UVariables, 

  gnugettext;

type

  TFRationP = class(TForm)

    GBRation: TGroupBox;

    SBAddRation: TSpeedButton;

    SBDelRation: TSpeedButton;

    CBRation: TComboBox;

    GBRule: TGroupBox;

    LModeFin: TLabel;

    LNo: TLabel;

    SBAddRule: TSpeedButton;

    SBDelRule: TSpeedButton;

    LAli: TLabel;

    LBRule: TListBox;

    GBEnd: TGroupBox;

    PBValFin: TPBNumEdit;

    GBAjust: TGroupBox;

    GBParam: TGroupBox;

    LUnite: TLabel;

    LEqPV: TLabel;

    CBUnite: TComboBox;

    PBaPV: TPBNumEdit;

    RBCoef: TRadioButton;

    RBIngere: TRadioButton;

    PBbPV: TPBNumEdit;

    PBIng50: TPBNumEdit;

    PBIng100: TPBNumEdit;

    Graph: TChart;

    SeriesLigne: TLineSeries;

    SBRename: TSpeedButton;

    SBComment: TSpeedButton;

    PEqPV: TPanel;

    PCoefPV: TPanel;

    CBModeFin: TComboBox;

    PUnite: TPanel;

    LType: TLabel;

    CBType: TComboBox;

    PQuantite: TPanel;

    LQuantite: TLabel;

    PBQuantite: TPBNumEdit;

    CBEqPV: TComboBox;

    CBX: TComboBox;

    CBY: TComboBox;

    GBSim: TGroupBox;

    CBSim: TComboBox;

    GBY: TGroupBox;

    GBX: TGroupBox;

    PRation: TPanel;

    SBSave: TSpeedButton;

    SBPrint: TSpeedButton;

    PPercent: TPanel;

    LPercent: TLabel;

    PBPercent: TPBNumEdit;

    JvEnterAsTab: TJvEnterAsTab;

    LGaspillage: TLabel;

    PBGaspillage: TPBNumEdit;

    LaPV: TLabel;

    LbPV: TLabel;

    LIng100: TLabel;

    LIng50: TLabel;

    PCoefDuree: TPanel;

    LaDuree: TLabel;

    LbDuree: TLabel;

    PBaDuree: TPBNumEdit;

    PBbDuree: TPBNumEdit;

    PEqDuree: TPanel;

    LEqDuree: TLabel;

    CBEqDuree: TComboBox;

    GBGraph: TGroupBox;

    PGraphTop: TPanel;

    PRules: TPanel;

    LProfilRef: TLabel;

    LSeqAliRef: TLabel;

    LWastage: TLabel;

    PRight: TPanel;

    procedure FormClose(Sender: TObject; var Action: TCloseAction);

    procedure FormShow(Sender: TObject);

    procedure CBRationChange(Sender: TObject);

    procedure SBAddRationClick(Sender: TObject);

    procedure SBDelRationClick(Sender: TObject);

    procedure LBRuleClick(Sender: TObject);

    procedure LBRuleDrawItem(Control: TWinControl; Index: Integer;

      Rect: TRect; State: TOwnerDrawState);

    procedure SBAddRuleClick(Sender: TObject);

    procedure SBDelRuleClick(Sender: TObject);

    procedure PBValFinChange(Sender: TObject);

    procedure CBUniteChange(Sender: TObject);

    procedure RBCoefClick(Sender: TObject);

    procedure PBaPVChange(Sender: TObject);

    procedure PBbPVChange(Sender: TObject);

    procedure PBIng50Change(Sender: TObject);

    procedure PBIng100Change(Sender: TObject);

    procedure FormDeactivate(Sender: TObject);

    procedure SBRenameClick(Sender: TObject);

    procedure SBCommentClick(Sender: TObject);

    procedure PBQuantiteChange(Sender: TObject);

    procedure CBTypeChange(Sender: TObject);

    procedure CBModeFinChange(Sender: TObject);

    procedure FormActivate(Sender: TObject);

    procedure CBEqDureeChange(Sender: TObject);

    procedure CBEqPVChange(Sender: TObject);

    procedure CBXChange(Sender: TObject);

    procedure CBYChange(Sender: TObject);

    procedure CBSimChange(Sender: TObject);

    procedure SBSaveClick(Sender: TObject);

    procedure SBPrintClick(Sender: TObject);

    procedure FormCreate(Sender: TObject);

    procedure PBPercentChange(Sender: TObject);

    procedure PBGaspillageChange(Sender: TObject);

    procedure PBaDureeChange(Sender: TObject);

    procedure PBbDureeChange(Sender: TObject);

  private

    { D?clarations priv?es }

    Update, Modified: boolean;

    IdxRationP, NumRule: integer;

    PResSimulP: PTabResSimulP;

    procedure Save;

    procedure AffGraph;

  public

    { D?clarations publiques }

    function StrModeFin(n: integer): String;

    function StrEquation(n: integer): String;

  end;

var

  FRationP: TFRationP;

implementation

uses

  UStrings, UInit, UUtil, UFindRec, UCalcul, UEchelle, UFComment, UCalcSimulP,

  UFRapRationP;

{$R *.dfm}

{ TFRationP }

procedure TFRationP.FormCreate(Sender: TObject);

begin

  if Screen.Fonts.IndexOf('Arial Unicode MS') <> -1

  then

    Font.Name := 'Arial Unicode MS';

  TranslateComponent(Self);

  Constraints.MinWidth := 748 + (Width - ClientWidth);

  Width := Constraints.MinWidth;

  Constraints.MinHeight := 440 + (Height - ClientHeight);

  Height := Constraints.MinHeight;

  CBModeFin.ItemIndex := 0;

  CBType.ItemIndex := 0;

  CBUnite.ItemIndex := 0;

  CBEqDuree.ItemIndex := 0;

  CBEqPV.ItemIndex := 0;

  CBX.ItemIndex := 0;

  CBY.ItemIndex := 0;

end;

procedure TFRationP.FormShow(Sender: TObject);

begin

  Modified := False;

  // Abscisses par d?faut

  CBX.ItemIndex := XCrois;

  New(PResSimulP);

  StringsRationP(CBRation.Items, True);

  SBAddRation.Enabled := IsComplete or (ListRationP.Count < 5);

  SBSave.Enabled := IsComplete or IsEducation;

  IdxRationP := -1;

//  CBRationChange(nil);

end;

procedure TFRationP.FormClose(Sender: TObject; var Action: TCloseAction);

begin

  if Modified then Save;

  Dispose(PResSimulP);

  Action := caFree;

  NumWinRationP := -1;

end;

procedure TFRationP.FormActivate(Sender: TObject);

begin

  StringsSimulP(CBSim.Items, False);

//  if IdxRationP <> -1

//  then

//    PRationP := ListRationP[IdxRationP];

  CBRationChange(nil);

  PRation.Enabled := IsComplete or IsEducation or IsEvaluation;

  SBAddRule.Visible := PRation.Enabled;

  SBDelRule.Visible := PRation.Enabled;

end;

procedure TFRationP.FormDeactivate(Sender: TObject);

begin

  if Modified then Save;

end;

procedure TFRationP.Save;

var

  s: string;

begin

  Modified := False;

  if IsComplete or IsEducation

  then

    if MessageDlg(Caption + sLineBreak + MsgSave, mtConfirmation, [mbYes, mbNo], 0) = mrYes

    then

    begin

      SaveRationP;

      if not RationPValid(PRationP)

      then

        MessageDlg(Format(MsgInvalidData, [Caption, PRationP.Nom]), mtWarning, [mbOK], 0);

    end

    else

    begin

      LoadRationP;

      s := CBRation.Text;

      StringsRationP(CBRation.Items, True);

      if FindIdxRationP(s) = -1

      then

      begin

        IdxRationP := -1;

        CBRationChange(nil);

      end

      else

        CBRation.ItemIndex := CBRation.Items.IndexOf(s);

    end;

end;

procedure TFRationP.CBRationChange (Sender : TObject) ;

var

  i : integer ;

begin

  if (IdxRationP <> -1) and (CBRation.Text <> PRationP.Nom)

  then

    if Modified then Save ;

  IdxRationP := FindIdxRationP (CBRation.Text) ;

  LBRule.Clear ;

  if IdxRationP = -1

  then

  begin

    CBRation.Repaint ;

    SBDelRation.Enabled := FALSE ;

    SBRename.Enabled := FALSE ;

    SBComment.Enabled := FALSE ;

    SBSave.Enabled := FALSE ;

    SBPrint.Enabled := FALSE ;

    PRation.Visible := FALSE ;

  end

  else // Affichage de l'enregistrement

  begin

    SBDelRation.Enabled := TRUE ;

    SBRename.Enabled := TRUE ;

    SBComment.Enabled := TRUE ;

    SBSave.Enabled := TRUE ;

    SBPrint.Enabled := TRUE ;

    PRation.Visible := TRUE ;

    PRationP := ListRationP[IdxRationP] ;

    with PRationP^ do

      CBRation.Hint := Memo ;

    with PRationP^ do

      for i := 1 to NbRule do

        LBRule.Items.Add ('') ;

    LBRule.ItemIndex := 0 ;

    LBRuleClick (nil) ;

    CBSimChange (nil) ;

  end ;

end ;

procedure TFRationP.SBAddRationClick (Sender : TObject) ;

var

  i, n, q : integer ;

  s : string ;

  ok : boolean ;

  PBackup : PRecRationP ;

begin

  if Modified then Save ;

  if IdxRationP = -1

  then

    q := mrNo

  else

    q := MessageDlg (MsgCopy, mtConfirmation, [mbYes, mbNo], 0) ;

  // saisie du nouveau nom

  s := '' ;

  repeat

    if InputQuery (FRationP.Caption, MsgName, s)

    then // V?rification du nom

    begin

      s := Trim (s) ; // Suppression des espaces au d?but et ? la fin

      if s = ''

      then // Pas de nom

      begin

        ok := FALSE ;

        MessageDlg (MsgNameEmpty, mtWarning, [mbOk], 0) ;

      end

      else

        if Length (s) > 25

        then // Nom trop long

        begin

          ok := FALSE ;

          MessageDlg (Format (MsgNameTooLarge, [25]), mtWarning, [mbOk], 0) ;

          s := Copy (s, 1, 25) ;

        end

        else

        begin

          ok := TRUE ;

          i := 0 ;

          while ok and (i < ListRationP.Count) do

          begin

            PRationP := ListRationP[i] ;

            if PRationP.Nom = s

            then // Nom d?j? utilis?

            begin

              ok := FALSE ;

              MessageDlg (MsgNameExists, mtWarning, [mbOk], 0) ;

            end

            else

              Inc (i) ;

          end ;

        end ;

    end

    else // Annulation

    begin

      s := '' ;

      if (IdxRationP <> -1)

      then

        PRationP := ListRationP[IdxRationP] ;

      ok := TRUE ;

    end ;

  until ok ;

  if s <> ''

  then // Cr?ation du nouvel enregistrement

  begin

    // recherche du premier num?ro libre

    n := 0 ;

    repeat

      Inc (n) ;

      ok := TRUE ;

      i := 0 ;

      while ok and (i < ListRationP.Count) do

      begin

        PRationP := ListRationP[i] ;

        if PRationP.Num = n

        then

          ok := FALSE

        else

          Inc (i) ;

      end ;

    until ok ;

    New (PRationP) ;

    with PRationP^ do

    begin

      Nom := s ;

      Num := n ;

      if q = mrYes

      then

      begin

        PBackup := ListRationP[IdxRationP] ;

        Memo := PBackup.Memo ;

        NbRule := PBackup.NbRule ;

        Rule := PBackup.Rule ;

      end

      else

      begin

        Memo := '';

        NbRule := 1;

        for i := 1 to MAX_RULE do

          with Rule[i] do

          begin

            ModeFin := -1;

            ValFin := 0;

            Gaspillage := 0;

            RuleType := -1;

            Unite := -1;

            EqDuree := -1;

            EqPV := -1;

            Percent := 1;

            Quantity := 0;

            aDuree := 0;

            bDuree := 0;

            aPV := 0;

            bPV := 0;

         end;

      end;

    end ;

    ListRationP.Add (PRationP) ;

    CBRation.Items.Add (PRationP.Nom) ;

    CBRation.ItemIndex := CBRation.Items.IndexOf (PRationP.Nom) ;

    CBRationChange (nil) ;

    Modified := TRUE ;

    SBAddRation.Enabled := IsComplete or (ListRationP.Count < 5) ;

    SBCommentClick (nil) ;

  end ;

end;

procedure TFRationP.SBDelRationClick (Sender : TObject) ;

begin

  if RationPUsed (PRationP.Num)

  then // Enregistrement utilis?

    MessageDlg (MsgDelErr, mtWarning, [mbOk], 0)

  else // Suppression de l'enregistrement

    if MessageDlg (MsgDel, mtConfirmation, [mbYes, mbNo], 0) = mrYes

    then

    begin

      Dispose (PRationP) ;

      ListRationP.Delete (IdxRationP) ;

      SaveRationP ; // Sauvegarde !

      Modified := FALSE ;

      CBRation.DeleteSelected ;

      IdxRationP := -1 ;

      CBRation.ItemIndex := -1 ;

      CBRationChange (nil) ;

      SBAddRation.Enabled := IsComplete or (ListRationP.Count < 5) ;

    end ;

end ;

procedure TFRationP.SBRenameClick (Sender : TObject) ;

var

  i : integer ;

  s : string ;

  ok : boolean ;

begin

  // Saisie du nouveau nom

  s := CBRation.Text ;

  repeat

    if InputQuery (FRationP.Caption, MsgRename, s) and (s <> CBRation.Text)

    then // V?rification du nom

    begin

      s := Trim (s) ; // Suppression des espaces au d?but et ? la fin

      if s = ''

      then // Pas de nom

      begin

        ok := FALSE ;

        MessageDlg (MsgNameEmpty, mtWarning, [mbOk], 0) ;

      end

      else

        if Length (s) > 25

        then // Nom trop long

        begin

          ok := FALSE ;

          MessageDlg (Format (MsgNameTooLarge, [25]), mtWarning, [mbOk], 0) ;

          s := Copy (s, 1, 25) ;

        end

        else

        begin

          ok := TRUE ;

          i := 0 ;

          while ok and (i < ListRationP.Count) do

          begin

            PRationP := ListRationP[i] ;

            if PRationP.Nom = s

            then // Nom d?j? utilis?

            begin

              ok := FALSE ;

              MessageDlg (MsgNameExists, mtWarning, [mbOk], 0) ;

            end

            else

              Inc (i) ;

          end ;

        end ;

    end

    else // Annulation

    begin

      s := '' ;

      ok := TRUE ;

    end ;

  until ok ;

  PRationP := ListRationP[IdxRationP] ;

  if s <> ''

  then // Renommer l'enregistrement

  begin

    PRationP.Nom := s ;

    Modified := TRUE ;

    StringsRationP (CBRation.Items, TRUE) ;

    CBRation.ItemIndex := CBRation.Items.IndexOf (s) ;

  end ;

end ;

procedure TFRationP.SBCommentClick (Sender : TObject) ;

begin

  // Saisie du commentaire

  FComment := TFComment.Create (Self) ;

  with FComment do

  begin

    Memo.Text := PRationP.Memo ;

    if ShowModal = mrOk

    then // Commenter l'enregistrement

    begin

      PRationP.Memo := Memo.Text ;

      Modified := TRUE ;

      CBRation.Hint := PRationP.Memo ;

    end ;

    Release ;

  end ;

end ;

procedure TFRationP.SBSaveClick(Sender: TObject);

begin

  SaveRationP ;

  if not RationPValid (PRationP)

  then

    MessageDlg(Format (MsgInvalidData, [Caption, PRationP.Nom]), mtWarning, [mbOK], 0) ;

  Modified := FALSE ;

end;

procedure TFRationP.SBPrintClick(Sender: TObject);

begin

  FRapRationP := TFRapRationP.Create (Self) ;

  FRapRationP.QRRapport.PreviewModal ;

  FRapRationP.Release ;

end;

procedure TFRationP.LBRuleClick(Sender: TObject);

begin

  NumRule := LBRule.ItemIndex + 1;

  SBAddRule.Enabled := LBRule.Items.Count < MAX_RULE;

  SBDelRule.Enabled := NumRule < PRationP.NbRule;

  GBEnd.Visible := SBDelRule.Enabled;

  with PRationP.Rule[NumRule] do

  begin

    Update := True;

    CBModeFin.ItemIndex := ModeFin;

    CBModeFinChange(nil);

    PBValFin.AsFloat := ValFin;

    PBGaspillage.AsFloat := Gaspillage * 100;

    CBType.ItemIndex := RuleType;

    CBTypeChange(nil);

    CBUnite.ItemIndex := Unite;

    CBUniteChange(nil);

    CBEqDuree.ItemIndex := EqDuree;

    CBEqDureeChange(nil);

    CBEqPV.ItemIndex := EqPV;

    CBEqPVChange(nil);

    PBPercent.Value := Percent * 100;

    PBQuantite.AsFloat := Quantity / (1 - Gaspillage);

    PBaDuree.AsFloat := aDuree / (1 - Gaspillage);

    PBbDuree.AsFloat := bDuree / (1 - Gaspillage);

    PBaPV.AsFloat := aPV / (1 - Gaspillage);

    if EqPV = 0

    then // a+b*PV

      PBbPV.AsFloat := bPV / (1 - Gaspillage)

    else

      PBbPV.AsFloat := bPV;

    PBIng50.AsFloat := CalcIngere(EqPV, Unite, PBaPV.AsFloat, PBbPV.AsFloat, 50);

    PBIng100.AsFloat := CalcIngere(EqPV, Unite, PBaPV.AsFloat, PBbPV.AsFloat, 100);

    Update := False;

  end;

end;

procedure TFRationP.LBRuleDrawItem(Control: TWinControl; Index: Integer; Rect: TRect; State: TOwnerDrawState);

begin

  with (Control as TListBox).Canvas do

  begin

    // Cadre principal

    FillRect(Rect);

    // Texte

    SetTextAlign(Handle, TA_RIGHT);

    Rect.Right := LBRule.Width - 4;

    TextRect(Rect, Rect.Right, Rect.Top, Format('%1.0f%%', [PRationP.Rule[Index + 1].Gaspillage * 100]));

    Rect.Right := 338;

    SetTextAlign(Handle, TA_LEFT);

    Rect.Left := 22;

    TextRect(Rect, Rect.Left, Rect.Top, StrModeFin(Index + 1));

    Rect.Left := 182;

    TextRect(Rect, Rect.Left, Rect.Top, StrEquation(Index + 1));

    Rect.Left := 0;

    // Num?ro

    SetTextAlign(Handle, TA_RIGHT);

    Rect.Right := 14;

    TextRect(Rect, Rect.Right, Rect.Top, Format('%d', [Index + 1]));

  end;

end;

procedure TFRationP.SBAddRuleClick (Sender : TObject) ;

var

  i : integer ;

begin

  for i := PRationP.NbRule downto NumRule do

    PRationP.Rule[i + 1] := PRationP.Rule[i] ;

  with PRationP.Rule[NumRule] do

  begin

    ModeFin := -1 ;

    ValFin := 0 ;

  end ;

  Inc (PRationP.NbRule) ;

  LBRule.Items.Add ('') ;

  LBRule.ItemIndex := NumRule - 1 ;

  LBRuleClick (nil) ;

  Modified := TRUE ;

  ActiveControl := CBModeFin ;

end ;

procedure TFRationP.SBDelRuleClick (Sender : TObject) ;

var

  i : integer ;

begin

  PRationP.NbRule := PRationP.NbRule - 1 ;

  for i := NumRule to PRationP.NbRule do

    PRationP.Rule[i] := PRationP.Rule[i + 1] ;

  i := NumRule ; // Position courante

  LBRule.DeleteSelected ;

  LBRule.ItemIndex := i - 1 ;

  LBRuleClick (nil) ;

  CBSimChange (nil) ;

  ActiveControl := LBRule ;

  Modified := TRUE ;

end ;

procedure TFRationP.CBModeFinChange(Sender: TObject);

begin

  PBValFin.Visible := CBModeFin.ItemIndex <> -1;

  if CBModeFin.ItemIndex >= 4

  then // Consommation

    PBValFin.Decimals := 3

  else

    PBValFin.Decimals := 0;

  if not Update

  then

  begin

    Modified := True;

    PRationP.Rule[NumRule].ModeFin := CBModeFin.ItemIndex;

    LBRule.Repaint;

    CBSimChange(nil);

  end;

end;

procedure TFRationP.PBValFinChange(Sender : TObject);

begin

  if not Update

  then

  begin

    Modified := True;

    PRationP.Rule[NumRule].ValFin := PBValFin.AsFloat;

    LBRule.Repaint;

    CBSimChange(nil);

  end;

end;

procedure TFRationP.PBGaspillageChange(Sender: TObject);

begin

  if not Update

  then

  begin

    Modified := True;

    PRationP.Rule[NumRule].Gaspillage := PBGaspillage.AsFloat / 100;

    // Recalculer Quantity

    PRationP.Rule[NumRule].Quantity := PBQuantite.AsFloat * (1 - PRationP.Rule[NumRule].Gaspillage);

    // Recalculer aDuree et bDuree

    PRationP.Rule[NumRule].aDuree := PBaDuree.AsFloat * (1 - PRationP.Rule[NumRule].Gaspillage);

    PRationP.Rule[NumRule].bDuree := PBbDuree.AsFloat * (1 - PRationP.Rule[NumRule].Gaspillage);

    // Recalculer aPV et bPV

    PRationP.Rule[NumRule].aPV := PBaPV.AsFloat * (1 - PRationP.Rule[NumRule].Gaspillage);

    if CBEqPV.ItemIndex = 0

    then // a+b*PV

      PRationP.Rule[NumRule].bPV := PBbPV.AsFloat * (1 - PRationP.Rule[NumRule].Gaspillage);

    LBRule.Repaint;

    CBSimChange(nil);

  end;

end;

procedure TFRationP.CBTypeChange(Sender: TObject);

begin

  PUnite.Visible := False;

  PPercent.Visible := False;

  PQuantite.Visible := False;

  PEqDuree.Visible := False;

  PCoefDuree.Visible := False;

  PEqPV.Visible := False;

  PCoefPV.Visible := False;

  case CBType.ItemIndex of

    0: // % Ad libitum

      PPercent.Visible := True;

    1: // Constant

    begin

      PUnite.Visible := True;

      PQuantite.Visible := True;

    end;

    2: // f(dur?e)

    begin

      PUnite.Visible := True;

      PEqDuree.Visible := True;

      CBEqDureeChange(nil);

    end;

    3: // f(poids vif)

    begin

      PUnite.Visible := True;

      PEqPV.Visible := True;

      CBEqPVChange(nil);

    end;

  end;

  if not Update

  then

  begin

    Modified := True;

    PRationP.Rule[NumRule].RuleType := CBType.ItemIndex;

    LBRule.Repaint;

    CBSimChange(nil);

  end;

end;

procedure TFRationP.CBUniteChange(Sender: TObject);

var

  etat: boolean;

  d, m, Ing50, Ing100: Double;

begin

  etat := Update;

  Update := True;

  // Ajustement de la pr?cision de Quantity, aDuree, bDuree, Ing50 et Ing100

  if (CBUnite.ItemIndex = 0) or (CBUnite.ItemIndex = 4)

  then // kg (QI ou MS)

  begin

    PBQuantite.Decimals := 3;

    PBaDuree.Decimals := 3;

    PBbDuree.Decimals := 3;

    PBIng50.Decimals := 3;

    PBIng100.Decimals := 3;

  end

  else // MJ (ED, EM ou EN)

  begin

    PBQuantite.Decimals := 2;

    PBaDuree.Decimals := 2;

    PBbDuree.Decimals := 2;

    PBIng50.Decimals := 2;

    PBIng100.Decimals := 2;

  end;

  Update := etat;

  if not Update

  then

  begin

    Update := True;

    CBEqPVChange(nil);

    Update := False;

    // Ancienne unit? (diviseur)

    case PProfilP.Unite of

      0: // Quantit? (kg/j)

        d := cGammaFrais;

      1: // ED (MJ/j)

        d := cGammaED;

      2: // EM (MJ/j)

        d := cGammaEM;

      3: // EN (MJ/j)

        d := cGammaEN;

      4: // MS (kg/j)

        d := cGammaMS;

      else

        d := 1;

    end;

    // Nouvelle unit? (multiplicateur)

    case CBUnite.ItemIndex of

      0: // Quantit? (kg/j)

        m := cGammaFrais;

      1: // ED (MJ/j)

        m := cGammaED;

      2: // EM (MJ/j)

        m := cGammaEM;

      3: // EN (MJ/j)

        m := cGammaEN;

      4: // MS (kg/j)

        m := cGammaMS;

      else

        m := 1;

    end;

    Modified := True;

    PRationP.Rule[NumRule].Unite := CBUnite.ItemIndex;

    if d <> m

    then // Conversion

    begin

      Update := True;

      RBIngere.Checked := True;

      PBIng50.AsFloat := m * PBIng50.AsFloat / d;

      PBIng100.AsFloat := m * PBIng100.AsFloat / d;

      with PRationP.Rule[NumRule] do

      begin

        Ing50 := PBIng50.AsFloat * (1 - Gaspillage);

        Ing100 := PBIng100.AsFloat * (1 - Gaspillage);

        CalcCoef(EqPV, Unite, Ing50, Ing100, aPV, bPV);

        PBaPV.AsFloat := aPV / (1 - Gaspillage);

        if EqPV = 0

        then // a+b*PV

          PBbPV.AsFloat := bPV / (1 - Gaspillage)

        else

          PBbPV.AsFloat := bPV;

      end;

      Update := False;

    end;

    LBRule.Repaint;

    CBSimChange(nil);

  end;

end;

procedure TFRationP.CBEqDureeChange(Sender: TObject);

begin

  PCoefDuree.Visible := (CBType.ItemIndex = 2) and (CBEqDuree.ItemIndex <> -1);

  if not Update

  then

  begin

    Modified := True;

    PRationP.Rule[NumRule].EqDuree := CBEqDuree.ItemIndex;

    LBRule.Repaint;

    CBSimChange(nil);

  end;

end;

procedure TFRationP.CBEqPVChange(Sender: TObject);

var

  etat: Boolean;

  Ing50, Ing100: Double;

begin

  etat := Update;

  Update := True;

  // Ajustement de la pr?cision des coefficients a et b

  case CBEqPV.ItemIndex of

    0: // a+b*PV

      if (CBUnite.ItemIndex = 0) or (CBUnite.ItemIndex = 4)

      then // kg (QI ou MS)

      begin

        PBaPV.Decimals := 3;

        PBbPV.Decimals := 3;

      end

      else // MJ (ED, EM ou EN)

      begin

        PBaPV.Decimals := 2;

        PBbPV.Decimals := 2;

      end;

    1: // a*PV^b

    begin

      if (CBUnite.ItemIndex = 0) or (CBUnite.ItemIndex = 4)

      then // kg (QI ou MS)

        PBaPV.Decimals := 4

      else // MJ (ED, EM ou EN)

        PBaPV.Decimals := 3;

      PBbPV.Decimals := 4;

    end;

    2: // a*(1-exp(-b*PV))

    begin

      if (CBUnite.ItemIndex = 0) or (CBUnite.ItemIndex = 4)

      then // kg (QI ou MS)

        PBaPV.Decimals := 3

      else // MJ (ED, EM ou EN)

        PBaPV.Decimals := 2;

      PBbPV.Decimals := 5;

    end;

  end;

  Update := etat;

  PCoefPV.Visible := (CBType.ItemIndex = 3) and (CBEqPV.ItemIndex <> -1);

  if not Update

  then

  begin

    Modified := True;

    PRationP.Rule[NumRule].EqPV := CBEqPV.ItemIndex;

    Update := True;

    RBIngere.Checked := True;

    with PRationP.Rule[NumRule] do

    begin

      Ing50 := PBIng50.AsFloat * (1 - Gaspillage);

      Ing100 := PBIng100.AsFloat * (1 - Gaspillage);

      CalcCoef(EqPV, Unite, Ing50, Ing100, aPV, bPV);

      PBaPV.AsFloat := aPV / (1 - Gaspillage);

      if EqPV = 0

      then // a+b*PV

        PBbPV.AsFloat := bPV / (1 - Gaspillage)

      else

        PBbPV.AsFloat := bPV;

    end;

    Update := False;

    LBRule.Repaint;

    CBSimChange(nil);

  end;

end;

procedure TFRationP.PBPercentChange(Sender: TObject);

begin

  if not Update

  then

  begin

    Modified := True;

    PRationP.Rule[NumRule].Percent := PBPercent.AsInteger / 100;

    LBRule.Repaint;

    CBSimChange(nil);

  end;

end;

procedure TFRationP.PBQuantiteChange(Sender: TObject);

begin

  if not Update

  then

  begin

    Modified := True;

    PRationP.Rule[NumRule].Quantity := PBQuantite.AsFloat * (1 - PRationP.Rule[NumRule].Gaspillage);

    LBRule.Repaint;

    CBSimChange(nil);

  end;

end;

procedure TFRationP.PBaDureeChange(Sender: TObject);

begin

  if not Update

  then

  begin

    Modified := True;

    PRationP.Rule[NumRule].aDuree := PBaDuree.AsFloat * (1 - PRationP.Rule[NumRule].Gaspillage);

    LBRule.Repaint;

    CBSimChange(nil);

  end;

end;

procedure TFRationP.PBbDureeChange(Sender: TObject);

begin

  if not Update

  then

  begin

    Modified := True;

    PRationP.Rule[NumRule].bDuree := PBbDuree.AsFloat * (1 - PRationP.Rule[NumRule].Gaspillage);

    LBRule.Repaint;

    CBSimChange(nil);

  end;

end;

procedure TFRationP.RBCoefClick(Sender: TObject);

begin

  PBaPV.Enabled := RBCoef.Checked;

  PBbPV.Enabled := RBCoef.Checked;

  PBIng50.Enabled := RBIngere.Checked;

  PBIng100.Enabled := RBIngere.Checked;

end;

procedure TFRationP.PBaPVChange(Sender: TObject);

begin

  if not Update

  then

  begin

    Modified := True;

    PRationP.Rule[NumRule].aPV := PBaPV.AsFloat * (1 - PRationP.Rule[NumRule].Gaspillage);

    Update := True;

    with PRationP.Rule[NumRule] do

    begin

      PBIng50.AsFloat := CalcIngere(EqPV, Unite, PBaPV.AsFloat, PBbPV.AsFloat, 50);

      PBIng100.AsFloat := CalcIngere(EqPV, Unite, PBaPV.AsFloat, PBbPV.AsFloat, 100);

    end;

    Update := False;

    LBRule.Repaint;

    CBSimChange(nil);

  end;

end;

procedure TFRationP.PBbPVChange(Sender: TObject);

begin

  if not Update

  then

  begin

    Modified := True;

    if CBEqPV.ItemIndex = 0

    then // a+b*PV

      PRationP.Rule[NumRule].bPV := PBbPV.AsFloat * (1 - PRationP.Rule[NumRule].Gaspillage)

    else

      PRationP.Rule[NumRule].bPV := PBbPV.AsFloat;

    Update := True;

    with PRationP.Rule[NumRule] do

    begin

      PBIng50.AsFloat := CalcIngere(EqPV, Unite, PBaPV.AsFloat, PBbPV.AsFloat, 50);

      PBIng100.AsFloat := CalcIngere(EqPV, Unite, PBaPV.AsFloat, PBbPV.AsFloat, 100);

    end;

    Update := False;

    LBRule.Repaint;

    CBSimChange(nil);

  end;

end;

procedure TFRationP.PBIng50Change(Sender: TObject);

var

  Ing50, Ing100: Double;

begin

  if not Update

  then

  begin

    Modified := True;

    Update := True;

    with PRationP.Rule[NumRule] do

    begin

      Ing50 := PBIng50.AsFloat * (1 - Gaspillage);

      Ing100 := PBIng100.AsFloat * (1 - Gaspillage);

      CalcCoef(EqPV, Unite, Ing50, Ing100, aPV, bPV);

      PBaPV.AsFloat := aPV / (1 - Gaspillage);

      if EqPV = 0

      then // a+b*PV

        PBbPV.AsFloat := bPV / (1 - Gaspillage)

      else

        PBbPV.AsFloat := bPV;

    end;

    Update := False;

    LBRule.Repaint;

    CBSimChange(nil);

  end;

end;

procedure TFRationP.PBIng100Change(Sender: TObject);

var

  Ing50, Ing100: Double;

begin

  if not Update

  then

  begin

    Modified := True;

    Update := True;

    with PRationP.Rule[NumRule] do

    begin

      Ing50 := PBIng50.AsFloat * (1 - Gaspillage);

      Ing100 := PBIng100.AsFloat * (1 - Gaspillage);

      CalcCoef(EqPV, Unite, Ing50, Ing100, aPV, bPV);

      PBaPV.AsFloat := aPV / (1 - Gaspillage);

      if EqPV = 0

      then // a+b*PV

        PBbPV.AsFloat := bPV / (1 - Gaspillage)

      else

        PBbPV.AsFloat := bPV;

    end;

    Update := False;

    LBRule.Repaint;

    CBSimChange(nil);

  end;

end;

function TFRationP.StrModeFin(n: integer): String;

begin

  if n = PRationP.NbRule

  then // Fin de simulation

    result := _('End of simulation')

  else

    with PRationP.Rule[n] do

      case ModeFin of

        0, 1, 2, 3 : // Dur?e, Age, Poids vif ou Cumul aliment

          result := Format('%s=%1.0f', [CBModeFin.Items[ModeFin], ValFin]);

        4..8 : // Consommation

          result := Format('%s=%s', [CBModeFin.Items[ModeFin], DblToStr(ValFin, 3)]);

        else

          result := '';

      end;

end;

function TFRationP.StrEquation(n: integer): String;

begin

  with PRationP.Rule[n] do

    case RuleType of

      0: // % Ad libitum

        result := Format('%1.0f%% %s', [Percent * 100, StrAdLib]);

      1: // Constant

        if (Unite = 0) or (Unite = 4)

        then // kg (QI ou MS)

          result := Format('%s=%s', [CBUnite.Items[Unite], DblToStr(Quantity / (1 - Gaspillage), 3)])

        else // MJ (ED, EM ou EN)

          result := Format('%s=%s', [CBUnite.Items[Unite], DblToStr(Quantity / (1 - Gaspillage), 2)]);

      2: // f(dur?e)

        case EqDuree of

          0: // a+b*jour

            if (Unite = 0) or (Unite = 4)

            then // kg (QI ou MS)

              result := Format('%s=%s+%s*%s', [CBUnite.Items[Unite], DblToStr(aDuree / (1 - Gaspillage), 3), DblToStr (bDuree / (1 - Gaspillage), 2), _('Day')])

            else // MJ (ED, EM ou EN)

              result := Format('%s=%s+%s*%s', [CBUnite.Items[Unite], DblToStr(aDuree / (1 - Gaspillage), 2), DblToStr (bDuree / (1 - Gaspillage), 3), _('Day')]);

          1: // a+b*semaine

            if (Unite = 0) or (Unite = 4)

            then // kg (QI ou MS)

              result := Format('%s=%s+%s*%s', [CBUnite.Items[Unite], DblToStr(aDuree / (1 - Gaspillage), 3), DblToStr (bDuree / (1 - Gaspillage), 2), _('Week')])

            else // MJ (ED, EM ou EN)

              result := Format('%s=%s+%s*%s', [CBUnite.Items[Unite], DblToStr(aDuree / (1 - Gaspillage), 2), DblToStr (bDuree / (1 - Gaspillage), 3), _('Week')]);

          else

            result := '';

        end;

      3: // f(poids vif)

        case EqPV of

          0: // a+b*PV

            if (Unite = 0) or (Unite = 4)

            then // kg (QI ou MS)

              result := Format('%s=%s+%s*%s', [CBUnite.Items[Unite], DblToStr(aPV / (1 - Gaspillage), 3), DblToStr(bPV / (1 - Gaspillage), 2), _('BW')])

            else // MJ (ED, EM ou EN)

              result := Format('%s=%s+%s*%s', [CBUnite.Items[Unite], DblToStr(aPV / (1 - Gaspillage), 2), DblToStr(bPV / (1 - Gaspillage), 3), _('BW')]);

          1: // a*PV^b

            if (Unite = 0) or (Unite = 4)

            then // kg (QI ou MS)

              result := Format('%s=%s*%s^%s', [CBUnite.Items[Unite], DblToStr(aPV / (1 - Gaspillage), 4), _('BW'), DblToStr(bPV, 4)])

            else // MJ (ED, EM ou EN)

              result := Format('%s=%s*%s^%s', [CBUnite.Items[Unite], DblToStr(aPV / (1 - Gaspillage), 3), _('BW'), DblToStr(bPV, 4)]);

          2: // a*(1-exp(-b*PV))

            if (Unite = 0) or (Unite = 4)

            then // kg (QI ou MS)

              result := Format('%s=%s*(1-exp(-%s*%s))', [CBUnite.Items[Unite], DblToStr(aPV / (1 - Gaspillage), 3), DblToStr(bPV, 5), _('BW')])

            else // MJ (ED, EM ou EN)

              result := Format('%s=%s*(1-exp(-%s*%s))', [CBUnite.Items[Unite], DblToStr(aPV / (1 - Gaspillage), 2), DblToStr(bPV, 5), _('BW')]);

          else

            result := '';

        end;

      else

        result := '';

    end;

end;

procedure TFRationP.AffGraph;

var

  j: integer;

  // Abscisse

  function X: double;

  begin

    case CBX.ItemIndex of

      0: // Poids vif

        result := PResSimulP.TabResult[2, j];

      1: // Age

        result := PResSimulP.TabResult[1, j];

      2: // Jours

        result := j;

      3: // Semaines

        result := j / 7;

      else

        result := 0;

    end;

  end;

  // Ordonn?e

  function Y: double;

  begin

    case CBY.ItemIndex of

      0: // QI

        result := PResSimulP.TabResult[113, j];

      1: // MS

        result := PResSimulP.TabResult[106, j] * PResSimulP.TabResult[113, j];

      2: // ED

        result := PResSimulP.TabResult[109, j] * PResSimulP.TabResult[113, j];

      3: // EM

        result := PResSimulP.TabResult[89, j] * PResSimulP.TabResult[113, j];

      4: // EN

        result := PResSimulP.TabResult[90, j] * PResSimulP.TabResult[113, j];

      else

        result := 0;

    end;

  end;

// AffGraph

begin

  Graph.LeftAxis.Title.Caption := CBY.Text;

  Graph.BottomAxis.Title.Caption := CBX.Text;

  SeriesLigne.Clear;

  if (CBSim.ItemIndex <> -1) and RationPValid (PRationP)

  then // Affichage de la ligne

    for j := 1 to PResSimulP.NbJSim do

      SeriesLigne.AddXY (X, Y, '', clTeeColor);

  if CBX.ItemIndex = 3

  then

    Graph.BottomAxis.Increment := 1

  else

    Graph.BottomAxis.Increment := 10;

  AjustEchelle(Graph);

end;

procedure TFRationP.CBXChange(Sender: TObject);

begin

  AffGraph;

end;

procedure TFRationP.CBYChange(Sender: TObject);

begin

  AffGraph;

end;

procedure TFRationP.CBSimChange(Sender: TObject);

begin

  if RationPValid(PRationP) and (CBSim.ItemIndex <> -1)

  then

  begin

    PSimulP := ListSimulP[FindIdxSimulP(CBSim.Text)];

    CBSim.Hint := PSimulP.Memo ;

    LProfilRef.Caption := Format(StrRationProfil, [FindNomProfilP(PSimulP.Profil)]);

    LSeqAliRef.Caption := Format(StrRationSeqAli, [FindNomSeqAliP(PSimulP.SeqAli)]);

    CalcSimulP(PSimulP.Num, -1, -1, PRationP.Num, -1, 1, {1,} PResSimulP);

  end

  else

  begin

    CBSim.Hint := '';

    LProfilRef.Caption := '';

    LSeqAliRef.Caption := '';

  end ;

  AffGraph;

end;

end.