InraPorc

unit UFResBesGestT;

interface

uses

  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,

  Dialogs, StdCtrls, Buttons, ExtCtrls, ComCtrls, CheckLst, Menus, Printers, 

  Math, Contnrs, PBNumEdit, PBSuperSpin, Grids, TeEngine, Series, TeeProcs, 

  Chart, TeeEdit, UVariables, gnugettext;

type

  TFResBesGestT = class(TForm)

    PC: TPageControl;

    TabNRJ: TTabSheet;

    TabAA: TTabSheet;

    CBAA1: TComboBox;

    CBAA3: TComboBox;

    CBAA4: TComboBox;

    CBAA2: TComboBox;

    GBAAT: TGroupBox;

    GBAAY: TGroupBox;

    GBAAX: TGroupBox;

    Graph: TChart;

    GBNRJX: TGroupBox;

    GBNRJY: TGroupBox;

    CBNRJ3: TComboBox;

    CBNRJ4: TComboBox;

    GBNRJT: TGroupBox;

    CBNRJ1: TComboBox;

    CBNRJ2: TComboBox;

    LBAA: TListBox;

    LBNRJ: TListBox;

    TSAli: TTabSheet;

    GBAli1: TGroupBox;

    GBAli2: TGroupBox;

    GBAli3: TGroupBox;

    GBAliMoy: TGroupBox;

    PBDuree2: TPBNumEdit;

    LAliDuree: TLabel;

    LAliQuantite: TLabel;

    PBQuantite2: TPBNumEdit;

    PBDuree1: TPBSuperSpin;

    PBQuantite1: TPBSuperSpin;

    PBDureeMoy: TPBNumEdit;

    PBQuantiteMoy: TPBNumEdit;

    PBDuree3: TPBSuperSpin;

    PBQuantite3: TPBSuperSpin;

    GBAliX: TGroupBox;

    CBAli2: TComboBox;

    PM: TPopupMenu;

    MI3D: TMenuItem;

    MIPreview: TMenuItem;

    MIPrint: TMenuItem;

    PD: TPrintDialog;

    procedure FormClose(Sender: TObject; var Action: TCloseAction);

    procedure FormShow(Sender: TObject);

    procedure PCChange(Sender: TObject);

    procedure CBNRJ1Change(Sender: TObject);

    procedure CBNRJ2Change(Sender: TObject);

    procedure CBNRJ3Change(Sender: TObject);

    procedure CBNRJ4Change(Sender: TObject);

    procedure CBAA1Change(Sender: TObject);

    procedure CBAA2Change(Sender: TObject);

    procedure CBAA3Change(Sender: TObject);

    procedure CBAA4Change(Sender: TObject);

    procedure PBDuree1Change(Sender: TObject);

    procedure PBDuree3Change(Sender: TObject);

    procedure PBQuantite1Change(Sender: TObject);

    procedure PBQuantite3Change(Sender: TObject);

    procedure CBAli2Change(Sender: TObject);

    procedure MI3DClick(Sender: TObject);

    procedure MIPreviewClick(Sender: TObject);

    procedure MIPrintClick(Sender: TObject);

    procedure FormCreate(Sender: TObject);

    procedure WMSysCommand(var Message: TWMSysCommand); message WM_SYSCOMMAND;

  private

    { D?clarations priv?es }

    ListNRJ : TStrings ;

    PieNRJ : TPieSeries ;

    AreaNRJ : array of TAreaSeries ;

    LineNRJ : TLineSeries ;

    ListAA : TStrings ;

    BarAA35 : THorizBarSeries ;

    BarAA105 : THorizBarSeries ;

    AreaAA : array of TAreaSeries ;

    LineAA : TLineSeries ;

    LineAli : array[1..2] of TLineSeries ;

    procedure ResetGraph ;

    procedure InitNRJ ;

    procedure AffGraphNRJ ;

    procedure InitAA ;

    procedure AffGraphAA ;

    procedure InitAli ;

    procedure AffGraphAli ;

  public

    { D?clarations publiques }

  end;

var

  FResBesGestT: TFResBesGestT;

implementation

uses

  UStrings, UFindRec, UUtil, UEchelle, UFBesGestT, UFPrevGraph, UFWarning;

{$R *.dfm}

{ TFResBesGestT }

procedure TFResBesGestT.FormCreate(Sender: TObject);

begin

  if Screen.Fonts.IndexOf('Arial Unicode MS') <> -1

  then

    Font.Name := 'Arial Unicode MS';

  TranslateComponent(Self);

  Constraints.MinWidth := 544 + (Width - ClientWidth);

  Width := 640;

  Constraints.MinHeight := 400 + (Height - ClientHeight);

  Height := 480;

  CBAli2.ItemIndex := 0;

  CBNRJ1.ItemIndex := 0;

  CBNRJ2.ItemIndex := 0;

  CBNRJ3.ItemIndex := 0;

  CBNRJ4.Items.Add(Format('%s/%s', [StrMJ, StrJ]));

  CBNRJ4.Items.Add('%');

  CBNRJ4.ItemIndex := 0;

  CBAA1.ItemIndex := 0;

  CBAA2.ItemIndex := 0;

  CBAA3.ItemIndex := 0;

  CBAA4.Items.Add(Format('%s/%s', [StrG, StrJ]));

  CBAA4.Items.Add('%');

  CBAA4.Items.Add(Format('%s/%s %s', [StrG, StrKg, StrAlimentUnit]));

  CBAA4.Items.Add(Format('%s/%s %s', [StrG, StrMJ, StrED]));

  CBAA4.Items.Add(Format('%s/%s %s', [StrG, StrMJ, StrEM]));

  CBAA4.Items.Add(Format('%s/%s %s', [StrG, StrMJ, StrEN]));

  CBAA4.ItemIndex := 0;

end;

procedure TFResBesGestT.FormShow (Sender : TObject) ;

begin

  MIPrint.Enabled := IsComplete or IsEducation ;

  // Aliment

  InitAli ;

  // Energie

  InitNRJ ;

  // Acides Amin?s

  InitAA ;

  // Initialisation des valeurs

  PBDureeMoy.AsInteger := DureeGest ;

  PBQuantiteMoy.AsFloat := FBesGestT.PBAliment.AsFloat ;

  case TypeAliGest of

    0 : // Une p?riode - Quantit? constante

    begin

      PBDuree2.AsInteger := PBDureeMoy.AsInteger ;

      PBQuantite1.AsFloat := PBQuantiteMoy.AsFloat ;

      PBQuantite3.AsFloat := PBQuantiteMoy.AsFloat ;

    end ;

    1 : // Deux p?riodes - Quantit? finale fix?e

    begin

      PBDuree3.AsInteger := Duree3 ;

      PBQuantite1.AsFloat := PBQuantiteMoy.AsFloat ;

      PBQuantite3.AsFloat := Quantite3 ;

    end ;

    2 : // Deux p?riodes - Augmentation fix?e

    begin

      PBDuree3.AsInteger := Duree3 ;

      PBQuantite1.AsFloat := PBQuantiteMoy.AsFloat ;

      PBQuantite3.AsFloat := (PBQuantiteMoy.AsFloat * PBDureeMoy.AsInteger

          + Augment * PBDuree2.AsInteger)

        / (PBDuree2.AsInteger + Duree3) ;

    end ;

    3 : // Trois p?riodes - Augmentation et quantit? finale fix?es

    begin

      PBDuree1.AsInteger := Duree1 ;

      PBDuree3.AsInteger := Duree3 ;

      PBQuantite3.AsFloat := Quantite3 ;

      PBQuantite1.AsFloat := (PBQuantiteMoy.AsFloat * PBDureeMoy.AsInteger

          - (Quantite3 - Augment) * PBDuree2.AsInteger

          - Quantite3 * Duree3)

        / Duree1 ;

    end ;

    4 : // Trois p?riodes - Quantit?s des p?riodes 2 et 3 fix?es

    begin

      PBDuree1.AsInteger := Duree1 ;

      PBDuree3.AsInteger := Duree3 ;

      PBQuantite3.AsFloat := Quantite3 ;

      PBQuantite1.AsFloat := (PBQuantiteMoy.AsFloat * PBDureeMoy.AsInteger

          - Quantite2 * PBDuree2.AsInteger

          - Quantite3 * Duree3)

        / Duree1 ;

    end ;

    5 : // Trois p?riodes - Augmentation et quantit? initiale fix?es

    begin

      PBDuree1.AsInteger := Duree1 ;

      PBDuree3.AsInteger := Duree3 ;

      PBQuantite1.AsFloat := Quantite1 ;

      PBQuantite3.AsFloat := (PBQuantiteMoy.AsFloat * PBDureeMoy.AsInteger

          - Quantite1 * Duree1

          + Augment * PBDuree2.AsInteger)

        / (Duree3 + PBDuree2.AsInteger) ;

    end ;

  end ;

  // Affichage principal

  PC.ActivePageIndex := 0 ;

  PCChange (nil) ;

end ;

procedure TFResBesGestT.FormClose (Sender : TObject ; var Action : TCloseAction) ;

var

  i : integer ;

begin

  // Aliment

  for i := 1 to 2 do

    LineAli[i].Free ;

  // Energie

  LineNRJ.Free ;

  for i := 0 to ListNRJ.Count - 1 do

    AreaNRJ[i].Free ;

  SetLength (AreaNRJ, 0) ;

  PieNRJ.Free ;

  ListNRJ.Free ;

  // Acides Amin?s

  LineAA.Free ;

  for i := 0 to ListAA.Count - 1 do

    AreaAA[i].Free ;

  SetLength (AreaAA, 0) ;

  BarAA35.Free ;

  BarAA105.Free ;

  ListAA.Free ;

end ;

procedure TFResBesGestT.PCChange (Sender : TObject) ;

begin

  case PC.ActivePageIndex of

    0 : // Aliment

      AffGraphAli ;

    1 : // Energie

      AffGraphNRJ ;

    2 : // Acides Amin?s

      AffGraphAA ;

  end ;

end ;

procedure TFResBesGestT.ResetGraph ;

var

  i : integer ;

begin

  Graph.UndoZoom ;

  Graph.View3D := FALSE ;

  Graph.Legend.Visible := TRUE ;

  Graph.Legend.Inverted := TRUE ;

  Graph.Title.Text.Clear ;

  Graph.SubTitle.Text.Clear ;

  Graph.LeftAxis.Automatic := FALSE ;

  Graph.BottomAxis.MinimumOffset := 0;

  Graph.BottomAxis.MaximumOffset := 0;

  // Aliment

  for i := 1 to 2 do

    LineAli[i].Active := FALSE ;

  // Energie

  PieNRJ.Active := FALSE ;

  for i := 0 to ListNRJ.Count - 1 do

    AreaNRJ[i].Active := FALSE ;

  LineNRJ.Active := FALSE ;

  // Acides Amin?s

  BarAA35.Active := FALSE ;

  BarAA105.Active := FALSE ;

  for i := 0 to ListAA.Count - 1 do

    AreaAA[i].Active := FALSE ;

  LineAA.Active := FALSE ;

end ;

procedure TFResBesGestT.MI3DClick (Sender : TObject) ;

begin

  Graph.View3D := not (Graph.View3D) ;

end ;

procedure TFResBesGestT.MIPreviewClick (Sender : TObject) ;

begin

  FPrevGraph := TFPrevGraph.Create (Self) ;

  with FPrevGraph do

  begin

    TPPGraph.Panels.Add (Graph) ;

    ShowModal ;

    Release ;

  end ;

end ;

procedure TFResBesGestT.MIPrintClick (Sender : TObject) ;

begin

  if PD.Execute

  then

  begin

    Printer.Orientation := poLandscape ;

    Graph.Print ;

  end ;

end ;

/////////////////

//   Aliment   //

/////////////////

procedure TFResBesGestT.InitAli ;

const

  TabColor : array[0..1] of TColor

    = (clBlack, clRed) ;

var

  i : integer ;

begin

  // LineAli : s?ries (lignes) graphiques

  for i := 1 to 2 do

  begin

    LineAli[i] := TLineSeries.Create (Graph) ;

    LineAli[i].ParentChart := Graph ;

    if i = 1

    then // R?f?rence

      LineAli[i].Title := StrReference

    else // Besoin

      LineAli[i].Title := StrBesoin ;

    LineAli[i].SeriesColor := TabColor[i - 1] ;

    LineAli[i].LinePen.Color := LineAli[i].SeriesColor ;

    LineAli[i].LinePen.Width := 2 ;

    Graph.AddSeries (LineAli[i]) ;

  end ;

end ;

procedure TFResBesGestT.AffGraphAli ;

var

  i, j : integer ;

  // Abscisse

  function AliX : double ;

  begin

    case CBAli2.ItemIndex of

      0 : // Age

        result := FBesGestT.PBAgeSail.AsInteger + (j - 1) ;

      1 : // Dur?e

        result := j - 1 ;

      else

        result := 0 ;

    end ;

  end ;

  // Ordonn?e

  function AliY : double ;

  begin

    case i of

      1 : // R?f?rence

        result := FBesGestT.AppAli[j] ;

      2 : // Besoin

        if (j <= PBDuree1.AsInteger)

        then

          result := PBQuantite1.AsFloat

        else

          if (j > PBDureeMoy.AsInteger - PBDuree3.AsInteger)

          then

            result := PBQuantite3.AsFloat

          else

            result := PBQuantite2.AsFloat ;

      else

        result := 0 ;

    end ;

  end ;

// AffGraphAli

begin

  ResetGraph ;

  Graph.Title.Text.Add (TSAli.Caption) ;

  Graph.LeftAxis.Title.Caption := Format ('%s (%s/%s)', [TSAli.Caption, StrKg, StrJ]) ;

  Graph.BottomAxis.Title.Caption := CBAli2.Text ;

  // Affichage des lignes

  for i := 1 to 2 do

    LineAli[i].Active := TRUE ;

  for i := 1 to 2 do

    LineAli[i].Clear ;

  for i := 1 to 2 do

    for j := 1 to DureeGest do

      LineAli[i].AddXY (AliX, AliY, '', clTeeColor) ;

  Graph.LeftAxis.Minimum := 0 ;

  Graph.LeftAxis.Increment := 0.5 ;

  Graph.LeftAxis.MinorTickCount := 4 ;

  Graph.LeftAxis.Maximum := 4.5 ;

  Graph.LeftAxis.Minimum := 1.5 ;

  Graph.LeftAxis.AxisValuesFormat := '# ##0.0' ;

end ;

procedure TFResBesGestT.PBDuree1Change(Sender: TObject);

begin

  PBQuantite1.Visible := PBDuree1.AsInteger > 0 ;

  if (PBDuree1.AsInteger >= PBDuree1.MinValue)

    and (PBDuree1.AsInteger <= PBDuree1.MaxValue)

  then

  begin

    PBDuree2.AsInteger := PBDureeMoy.AsInteger

      - PBDuree1.AsInteger

      - PBDuree3.AsInteger ;

    PBQuantite2.AsFloat := (PBQuantiteMoy.AsFloat * PBDureeMoy.AsInteger

        - PBQuantite1.AsFloat * PBDuree1.AsInteger

        - PBQuantite3.AsFloat * PBDuree3.AsInteger)

      / PBDuree2.AsInteger ;

    AffGraphAli ;

  end ;

end;

procedure TFResBesGestT.PBDuree3Change(Sender: TObject);

begin

  PBQuantite3.Visible := PBDuree3.AsInteger > 0 ;

  if (PBDuree3.AsInteger >= PBDuree3.MinValue)

    and (PBDuree3.AsInteger <= PBDuree3.MaxValue)

  then

  begin

    PBDuree2.AsInteger := PBDureeMoy.AsInteger

      - PBDuree1.AsInteger

      - PBDuree3.AsInteger ;

    PBQuantite2.AsFloat := (PBQuantiteMoy.AsFloat * PBDureeMoy.AsInteger

        - PBQuantite1.AsFloat * PBDuree1.AsInteger

        - PBQuantite3.AsFloat * PBDuree3.AsInteger)

      / PBDuree2.AsInteger ;

    AffGraphAli ;

  end ;

end;

procedure TFResBesGestT.PBQuantite1Change(Sender: TObject);

begin

  PBQuantite2.AsFloat := (PBQuantiteMoy.AsFloat * PBDureeMoy.AsInteger

      - PBQuantite1.AsFloat * PBDuree1.AsInteger

      - PBQuantite3.AsFloat * PBDuree3.AsInteger)

    / PBDuree2.AsInteger ;

  AffGraphAli ;

end;

procedure TFResBesGestT.PBQuantite3Change(Sender: TObject);

begin

  PBQuantite2.AsFloat := (PBQuantiteMoy.AsFloat * PBDureeMoy.AsInteger

      - PBQuantite1.AsFloat * PBDuree1.AsInteger

      - PBQuantite3.AsFloat * PBDuree3.AsInteger)

    / PBDuree2.AsInteger ;

  AffGraphAli ;

end;

procedure TFResBesGestT.CBAli2Change(Sender: TObject);

begin

  AffGraphAli ;

end;

/////////////////

//   Energie   //

/////////////////

procedure TFResBesGestT.InitNRJ ;

const

  TabColor : array[0..4] of TColor

    = (clOlive, clGray, clAqua, clPurple, clNavy) ;

var

  i : integer ;

begin

  // ListNRJ : liste pour l'?nergie

  ListNRJ := TStringList.Create ;

  ListNRJ.Assign (LBNRJ.Items) ;

  // PieNRJ : s?rie (camembert) graphique

  PieNRJ := TPieSeries.Create (Graph) ;

  PieNRJ.ParentChart := Graph ;

  PieNRJ.Marks.ArrowLength := 24 ;

  PieNRJ.Marks.Arrow.Color := clBlack ;

  PieNRJ.Marks.Brush.Style := bsClear ;

  PieNRJ.Marks.Frame.Visible := FALSE ;

  PieNRJ.ValueFormat := Format ('# ##0.0 %s', [StrMJ]) ;

  PieNRJ.PercentFormat := '##0.0 %' ;

  Graph.AddSeries (PieNRJ) ;

  // AreaNRJ : s?ries (aires) graphiques

  SetLength (AreaNRJ, ListNRJ.Count) ;

  for i := 0 to ListNRJ.Count - 1 do

  begin

    AreaNRJ[i] := TAreaSeries.Create (Graph) ;

    AreaNRJ[i].ParentChart := Graph ;

    AreaNRJ[i].Title := ListNRJ[i] ;

    AreaNRJ[i].SeriesColor := TabColor[i] ;

    AreaNRJ[i].AreaLinesPen.Visible := FALSE ;

    Graph.AddSeries (AreaNRJ[i]) ;

  end ;

  // LineNRJ : s?rie (ligne) graphique

  LineNRJ := TLineSeries.Create (Graph) ;

  LineNRJ.ParentChart := Graph ;

  LineNRJ.Title := StrReference ;

  LineNRJ.SeriesColor := clBlack ;

  LineNRJ.LinePen.Color := LineNRJ.SeriesColor ;

  LineNRJ.LinePen.Width := 2 ;

  Graph.AddSeries (LineNRJ) ;

end ;

procedure TFResBesGestT.AffGraphNRJ ;

var

  i, j : integer ;

  y, m, t : double ;

  // Abscisse

  function NRJX : double ;

  begin

    case CBNRJ1.ItemIndex of

      1 : // R?partition dynamique

        case CBNRJ2.ItemIndex of

          0 : // Age

            result := FBesGestT.PBAgeSail.AsInteger + (j - 1) ;

          1 : // Dur?e

            result := j - 1 ;

          else

            result := 0 ;

        end ;

      else

        result := 0 ;

    end ;

  end ;

  // Ordonn?e

  function NRJY : double ;

  var

    BesEM : double ;

  begin

    case CBNRJ1.ItemIndex of

      0 : // R?partition globale

        case i of

          0 : // Entretien

            result := FBesGestT.BesEMEntTot ;

          1 : // Activit?

            result := FBesGestT.BesEMActTot ;

          2 : // Thermor?gulation

            result := FBesGestT.BesEMTheTot ;

          3 : // Port?e

            result := FBesGestT.BesEMPortTot ;

          4 : // R?serve

            result := FBesGestT.BesEMResTot ;

          else

            result := 0 ;

        end ;

      1 : // R?partition dynamique

        case i of

          -1 : // Apport

            result := FBesGestT.AppEM[j] ;

          0 : // Entretien

            result := FBesGestT.BesEMEnt[j] ;

          1 : // Activit?

            result := FBesGestT.BesEMAct[j] ;

          2 : // Thermor?gulation

            result := FBesGestT.BesEMThe[j] ;

          3 : // Port?e

            result := FBesGestT.BesEMPort[j] ;

          4 : // R?serve

          begin

            if (j <= PBDuree1.AsInteger)

            then

              BesEM := PBQuantite1.AsFloat / FBesGestT.AppAliTot * FBesGestT.AppEMTot

            else

              if (j > PBDureeMoy.AsInteger - PBDuree3.AsInteger)

              then

                BesEM := PBQuantite3.AsFloat / FBesGestT.AppAliTot * FBesGestT.AppEMTot

              else

                BesEM := PBQuantite2.AsFloat / FBesGestT.AppAliTot * FBesGestT.AppEMTot ;

            result := Max (BesEM - FBesGestT.BesEMEnt[j] - FBesGestT.BesEMAct[j] - FBesGestT.BesEMPort[j] - FBesGestT.BesEMThe[j], 0) ;

          end ;

          else

            result := 0 ;

        end ;

      else

        result := 0 ;

    end ;

  end ;

// AffGraphNRJ

begin

  ResetGraph ;

  Graph.Title.Text.Add (Format ('%s : %s', [TabNRJ.Caption, CBNRJ1.Text])) ;

  case CBNRJ3.ItemIndex of

    0 : // Energie digestible

      m := FBesGestT.AppEDTot / FBesGestT.AppEMTot ;

    2 : // Energie nette

      m := FBesGestT.AppENTot / FBesGestT.AppEMTot ;

    else

      m := 1 ;

  end ;

  case CBNRJ1.ItemIndex of

    0 : // R?partition globale

    begin

      Graph.View3D := TRUE ;

      Graph.Legend.Visible := FALSE ;

      // Affichage du camembert

      PieNRJ.Active := TRUE ;

      PieNRJ.Clear ;

      if (CBNRJ4.ItemIndex = 1)

      then

        PieNRJ.Marks.Style := smsLabelPercent

      else

        PieNRJ.Marks.Style := smsLabelValue ;

      for i := 0 to ListNRJ.Count - 1 do

      begin

        y := NRJY * m ;

        if (y > PICO)

        then

          PieNRJ.AddPie (y, ListNRJ[i], AreaNRJ[i].SeriesColor) ;

      end ;

      t := FBesGestT.BesEMTot * m ;

      Graph.SubTitle.Text.Add (Format ('%s : %3.1f %s/%s', [StrTotal, t, StrMJ, StrJ])) ;

    end ;

    1 : // R?partition dynamique

    begin

      Graph.LeftAxis.Title.Caption := Format ('%s (%s)', [CBNRJ3.Text, CBNRJ4.Text]) ;

      Graph.BottomAxis.Title.Caption := CBNRJ2.Text ;

      // Affichage des aires

      for i := 0 to ListNRJ.Count - 1 do

        AreaNRJ[i].Active := TRUE ;

      for i := 0 to ListNRJ.Count - 1 do

        AreaNRJ[i].Clear ;

      if (CBNRJ4.ItemIndex = 1)

      then

        for i := 0 to ListNRJ.Count - 1 do

          AreaNRJ[i].MultiArea := maStacked100

      else

        for i := 0 to ListNRJ.Count - 1 do

          AreaNRJ[i].MultiArea := maStacked ;

      for i := 0 to ListNRJ.Count - 1 do

        for j := 1 to DureeGest do

          AreaNRJ[i].AddXY (NRJX, NRJY * m, '', clTeeColor) ;

      // Affichage de la ligne

      if CBNRJ4.ItemIndex <> 1

      then

      begin

        i := -1 ;

        LineNRJ.Active := TRUE ;

        LineNRJ.Clear ;

        for j := 1 to DureeGest do

          LineNRJ.AddXY (NRJX, NRJY * m, '', clTeeColor) ;

      end ;

    end ;

  end ;

  AjustEchelle (Graph) ;

end ;

procedure TFResBesGestT.CBNRJ1Change (Sender : TObject) ;

begin

  case CBNRJ1.ItemIndex of

    0 : // R?partition globale

      CBNRJ2.Visible := FALSE ;

    1 : // R?partition dynamique

      CBNRJ2.Visible := TRUE ;

  end ;

  AffGraphNRJ ;

end ;

procedure TFResBesGestT.CBNRJ2Change (Sender : TObject) ;

begin

  AffGraphNRJ ;

end ;

procedure TFResBesGestT.CBNRJ3Change (Sender : TObject) ;

begin

  AffGraphNRJ ;

end ;

procedure TFResBesGestT.CBNRJ4Change (Sender : TObject) ;

begin

  AffGraphNRJ ;

end ;

///////////////////////

//   Acides amin?s   //

///////////////////////

procedure TFResBesGestT.InitAA ;

const

  TabColor : array[0..3] of TColor

    = (clOlive, clPurple, clNavy, clGreen) ;

var

  i : integer ;

begin

  // ListAA : liste pour les acides amin?s

  ListAA := TStringList.Create ;

  ListAA.Assign (LBAA.Items) ;

  // BarAA35 et BarAA105 : s?ries (barres) graphiques

  BarAA35 := THorizBarSeries.Create (Graph) ;

  BarAA35.ParentChart := Graph ;

  BarAA35.Title := Str35j ;

  BarAA35.SeriesColor := clGreen ;

  BarAA35.BarPen.Color := BarAA35.SeriesColor ;

  BarAA35.Marks.Visible := FALSE ;

  BarAA35.MultiBar := mbSide ;

  Graph.AddSeries (BarAA35) ;

  BarAA105 := THorizBarSeries.Create (Graph) ;

  BarAA105.ParentChart := Graph ;

  BarAA105.Title := Str105j ;

  BarAA105.SeriesColor := clNavy ;

  BarAA105.BarPen.Color := BarAA105.SeriesColor ;

  BarAA105.Marks.Visible := FALSE ;

  BarAA105.MultiBar := mbSide ;

  Graph.AddSeries (BarAA105) ;

  // AreaAA : s?ries (aires) graphiques

  SetLength (AreaAA, ListAA.Count) ;

  for i := 0 to ListAA.Count - 1 do

  begin

    AreaAA[i] := TAreaSeries.Create (Graph) ;

    AreaAA[i].ParentChart := Graph ;

    AreaAA[i].Title := ListAA[i] ;

    AreaAA[i].SeriesColor := TabColor[i] ;

    AreaAA[i].AreaLinesPen.Visible := FALSE ;

    Graph.AddSeries (AreaAA[i]) ;

  end ;

  // LineAA : s?rie (ligne) graphique

  LineAA := TLineSeries.Create (Graph) ;

  LineAA.ParentChart := Graph ;

  LineAA.Title := StrReference ;

  LineAA.SeriesColor := clBlack ;

  LineAA.LinePen.Color := LineAA.SeriesColor ;

  LineAA.LinePen.Width := 2 ;

  Graph.AddSeries (LineAA) ;

end ;

procedure TFResBesGestT.AffGraphAA ;

var

  h, i, j : integer ;

  s : string ;

  // Abscisse

  function AAX : double ;

  begin

    case CBAA1.ItemIndex of

      0 : // R?partition dynamique

        case CBAA2.ItemIndex of

          0 : // Age

            result := FBesGestT.PBAgeSail.AsInteger + (j - 1) ;

          1 : // Dur?e

            result := j - 1 ;

          else

            result := 0 ;

        end ;

      else

        result := 0 ;

    end ;

  end ;

  // Ordonn?e

  function AAY : double ;

  var

    a : integer ;

    d, BesAA, BesEM : double ;

  begin

    case h of

      3 : // met+cys

        a := 13 ;

      7 : // phe+tyr

        a := 14 ;

      else

        a := h ;

    end ;

    case CBAA1.ItemIndex of

      0 : // R?partition dynamique

      begin

        // Diviseur

        if i = -1

        then // Apport

          BesEM := 0

        else

          if j <= PBDuree1.AsInteger

          then

            BesEM := PBQuantite1.AsFloat / FBesGestT.AppAliTot * FBesGestT.AppEMTot

          else

            if j > PBDureeMoy.AsInteger - PBDuree3.AsInteger

            then

              BesEM := PBQuantite3.AsFloat / FBesGestT.AppAliTot * FBesGestT.AppEMTot

            else

              BesEM := PBQuantite2.AsFloat / FBesGestT.AppAliTot * FBesGestT.AppEMTot ;

        case CBAA4.ItemIndex of

          2 : // Aliment

            if i = -1

            then // Apport

              d := FBesGestT.AppAli[j]

            else // Besoin

              d := BesEM * FBesGestT.AppAliTot / FBesGestT.AppEMTot ;

          3 : // ED

            if i = -1

            then // Apport

              d := FBesGestT.AppED[j]

            else // Besoin

              d := BesEM * FBesGestT.AppEDTot / FBesGestT.AppEMTot ;

          4 : // EM

            if i = -1

            then // Apport

              d := FBesGestT.AppEM[j]

            else // Besoin

              d := BesEM ;

          5 : // EN

            if i = -1

            then // Apport

              d := FBesGestT.AppEN[j]

            else // Besoin

              d := BesEM * FBesGestT.AppENTot / FBesGestT.AppEMTot ;

          else

            d := 1 ;

        end ;

        case i of

          -1 : // Apport

            result := FBesGestT.AppAA[a, j] / d ;

          0 : // Entretien

            result := FBesGestT.BesAAEnt[a, j] / d ;

          1 : // Port?e

            result := FBesGestT.BesAAPort[a, j] / d ;

          2 : // R?serve

            result := FBesGestT.BesAARes[a, j] / d ;

          3 : // Exc?s

          begin

            if j <= PBDuree1.AsInteger

            then

              BesAA := PBQuantite1.AsFloat / FBesGestT.PBAliment.AsFloat * FBesGestT.BesAA[a, 105]

            else

              if j > PBDureeMoy.AsInteger - PBDuree3.AsInteger

              then

                BesAA := PBQuantite3.AsFloat / FBesGestT.PBAliment.AsFloat * FBesGestT.BesAA[a, 105]

              else

                BesAA := PBQuantite2.AsFloat / FBesGestT.PBAliment.AsFloat * FBesGestT.BesAA[a, 105] ;

            result := Max (BesAA - FBesGestT.BesAAEnt[a, j] - FBesGestT.BesAAPort[a, j] - FBesGestT.BesAARes[a, j], 0) / d ;

          end ;

          else

            result := 0 ;

        end ;

      end ;

      1 : // Besoin

      begin

        // Diviseur

        case CBAA4.ItemIndex of

          1 : // Lysine

            d := FBesGestT.BesAA[1, j] / 100 ;

          else

            d := 1 ;

        end ;

        result := FBesGestT.BesAA[a, j] / d ;

      end ;

      else

        result := 0 ;

    end ;

  end ;

// AffGraphAA

begin

  ResetGraph ;

  Graph.Title.Text.Add (CBAA1.Text) ;

  Graph.SubTitle.Text.Add(StrDigestStd);

  case CBAA1.ItemIndex of

    0 : // R?partition dynamique

    begin

      Graph.LeftAxis.Title.Caption := Format ('%s (%s)', [CBAA3.Text, CBAA4.Text]) ;

      Graph.BottomAxis.Title.Caption := CBAA2.Text ;

      h := CBAA3.ItemIndex + 1 ;

      // Affichage des aires

      for i := 0 to ListAA.Count - 1 do

        AreaAA[i].Active := TRUE ;

      for i := 0 to ListAA.Count - 1 do

        AreaAA[i].Clear ;

      if (CBAA4.ItemIndex = 1)

      then

        for i := 0 to ListAA.Count - 1 do

          AreaAA[i].MultiArea := maStacked100

      else

        for i := 0 to ListAA.Count - 1 do

          AreaAA[i].MultiArea := maStacked ;

      for i := 0 to ListAA.Count - 1 do

        for j := 1 to DureeGest do

          AreaAA[i].AddXY (AAX, AAY, '', clTeeColor) ;

      // Affichage de la ligne

      if CBAA4.ItemIndex <> 1

      then

      begin

        i := -1 ;

        LineAA.Active := TRUE ;

        LineAA.Clear ;

        for j := 1 to DureeGest do

          LineAA.AddXY (AAX, AAY, '', clTeeColor) ;

      end ;

      AjustEchelle (Graph) ;

    end ;

    1 : // Besoin

    begin

      Graph.Legend.Inverted := FALSE ;

      Graph.LeftAxis.Automatic := TRUE ;

      Graph.LeftAxis.Title.Caption := TabAA.Caption ;

      Graph.BottomAxis.Title.Caption :=  Format ('%s (%s)', [StrBesoin, CBAA4.Text]) ;

      // Affichage des barres

      BarAA35.Active := TRUE ;

      BarAA105.Active := TRUE ;

      BarAA35.Clear ;

      BarAA105.Clear ;

      for h := CBAA3.Items.Count downto 1 do

      begin

        s := CBAA3.Items[h - 1] ;

        j := 35 ;

        BarAA35.AddBar (AAY, s, clTeeColor) ;

        j := 105 ;

        BarAA105.AddBar (AAY, s, clTeeColor) ;

      end ;

    end ;

  end ;

end ;

procedure TFResBesGestT.CBAA1Change (Sender : TObject) ;

begin

  CBAA4.Items.Clear ;

  case CBAA1.ItemIndex of

    0 : // R?partition dynamique

    begin

      CBAA2.Visible := TRUE ;

      CBAA3.Visible := TRUE ;

      // Unit?s

      CBAA4.Items.Add (Format ('%s/%s', [StrG, StrJ])) ;

      CBAA4.Items.Add ('%') ;

      CBAA4.Items.Add (Format ('%s/%s %s', [StrG, StrKg, StrAlimentUnit])) ;

      CBAA4.Items.Add (Format ('%s/%s %s', [StrG, StrMJ, StrED])) ;

      CBAA4.Items.Add (Format ('%s/%s %s', [StrG, StrMJ, StrEM])) ;

      CBAA4.Items.Add (Format ('%s/%s %s', [StrG, StrMJ, StrEN])) ;

    end ;

    1 : // Besoin

    begin

      if AffBesoin

      then

      begin

        FWarning := TFWarning.Create (Self) ;

        with FWarning do

        begin

          Msg := 'Besoin';

          ShowModal ;

          Release ;

          AffBesoin := FALSE ;

        end ;

      end ;

      CBAA2.Visible := FALSE ;

      CBAA3.Visible := FALSE ;

      // Unit?s

      CBAA4.Items.Add (Format ('%s/%s', [StrG, StrJ])) ;

      CBAA4.Items.Add (Format ('%% %s', [StrLys])) ;

    end ;

  end ;

  CBAA4.ItemIndex := 0 ;

  AffGraphAA ;

end ;

procedure TFResBesGestT.CBAA2Change (Sender : TObject) ;

begin

  AffGraphAA ;

end ;

procedure TFResBesGestT.CBAA3Change (Sender : TObject) ;

begin

  AffGraphAA ;

end ;

procedure TFResBesGestT.CBAA4Change (Sender : TObject) ;

begin

  AffGraphAA ;

end ;

procedure TFResBesGestT.WMSysCommand(var Message: TWMSysCommand);

begin

  if Message.CmdType = SC_MINIMIZE

  then

    Application.Minimize

  else

    inherited;

end;

end.