InraPorc

unit UFTarif ;

interface

uses

  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,

  Dialogs, Grids, ValEdit, StdCtrls, PBNumEdit, UVariables, gnugettext;

type

  TFTarif = class(TForm)

    LBAliment: TListBox;

    LAliment: TLabel;

    PBPrix: TPBNumEdit;

    LMonnaie: TLabel;

    procedure FormClose(Sender: TObject; var Action: TCloseAction);

    procedure FormShow(Sender: TObject);

    procedure FormActivate(Sender: TObject);

    procedure FormDeactivate(Sender: TObject);

    procedure LBAlimentClick(Sender: TObject);

    procedure PBPrixChange(Sender: TObject);

    procedure LBAlimentDrawItem(Control: TWinControl; Index: Integer;

      Rect: TRect; State: TOwnerDrawState);

    procedure PBPrixKeyPress(Sender: TObject; var Key: Char);

    procedure FormCreate(Sender: TObject);

  private

    { D?clarations priv?es }

    Update, Modified : boolean ;

    procedure Save ;

  public

    { D?clarations publiques }

  end;

var

  FTarif: TFTarif;

implementation

uses

  UStrings, UInit, UFindRec ;

{$R *.dfm}

{ TFTarif }

procedure TFTarif.FormCreate(Sender: TObject);

begin

  if Screen.Fonts.IndexOf('Arial Unicode MS') <> -1

  then

    Font.Name := 'Arial Unicode MS';

  TranslateComponent(Self);

  Constraints.MinWidth := 304 + (Width - ClientWidth);

  Width := Constraints.MinWidth;

  Constraints.MinHeight := 328 + (Height - ClientHeight);

  Height := Constraints.MinHeight;

end;

procedure TFTarif.FormShow (Sender : TObject) ;

begin

  Modified := FALSE ;

end ;

procedure TFTarif.FormClose (Sender : TObject ; var Action : TCloseAction) ;

begin

  if Modified then Save ;

  Action := caFree ;

  NumWinTarif := -1 ;

end ;

procedure TFTarif.FormActivate (Sender : TObject) ;

begin

  LMonnaie.Caption := Format ('%s / 1000 %s', [CurrencySign, StrKg]) ;

  StringsAliment (LBAliment.Items, 0, TRUE) ;

  LBAlimentClick (nil) ;

end ;

procedure TFTarif.FormDeactivate (Sender : TObject) ;

begin

  if Modified then Save ;

end ;

procedure TFTarif.Save ;

begin

  Modified := FALSE ;

  if MessageDlg (MsgSave, mtConfirmation, [mbYes, mbNo], 0) = mrYes

  then

    SaveAliment

  else

  begin

    LoadAliment ;

    LBAliment.Repaint ;

  end ;

end ;

procedure TFTarif.LBAlimentClick (Sender : TObject) ;

begin

  if LBAliment.ItemIndex = -1

  then

  begin

    PBPrix.Enabled := FALSE ;

    Update := TRUE ;

    PBPrix.Text := '' ;

    Update := FALSE ;

  end

  else

  begin

    PBPrix.Enabled := TRUE ;

    Update := TRUE ;

    PAliment := ListAliment[FindIdxAliment (LBAliment.Items[LBAliment.ItemIndex])] ;

    PBPrix.AsFloat := PAliment.Prix ;

    Update := FALSE ;

    ActiveControl := PBPrix ;

    PBPrix.SelectAll ;

  end ;

end ;

procedure TFTarif.LBAlimentDrawItem (Control : TWinControl ; Index : Integer ;

  Rect : TRect ; State : TOwnerDrawState) ;

begin

  with (Control as TListBox).Canvas do

  begin

    // Cadre principal

    FillRect (Rect) ;

    // Nom

    SetTextAlign (Handle, TA_LEFT) ;

    TextRect (Rect, Rect.Left + 2, Rect.Top, LBAliment.Items[Index]) ;

    // Prix

    Rect.Left := 224 ;

    if (LBAliment.Items.Count > 20)

    then

      Rect.Right := Rect.Right - 1

    else

      // L'ascensseur fait 17 pixels

      Rect.Right := Rect.Right - 18 ;

    SetTextAlign (Handle, TA_RIGHT) ;

    PAliment := ListAliment[FindIdxAliment (LBAliment.Items[Index])] ;

    TextRect (Rect, Rect.Right - 2, Rect.Top, Format ('%6.2f', [PAliment.Prix])) ;

  end ;

end ;

procedure TFTarif.PBPrixChange (Sender : TObject) ;

begin

  if not Update

  then

  begin

    Modified := TRUE ;

    PAliment := ListAliment[FindIdxAliment (LBAliment.Items[LBAliment.ItemIndex])] ;

    PAliment.Prix := PBPrix.AsFloat ;

    LBAliment.Repaint ;

  end ;

end ;

procedure TFTarif.PBPrixKeyPress(Sender: TObject; var Key: Char);

begin

  if Key = #13

  then

    if LBAliment.ItemIndex < LBAliment.Count - 1

    then

    begin

      LBAliment.ItemIndex := LBAliment.ItemIndex + 1 ;

      LBAlimentClick (nil) ;

      Key := #0 ;

    end ;

end;

end.