InraPorc

[ISPP]

#define Project "Ludo"

#define Publisher "INRA"

#define URL "https://inraporc.inra.fr/inraporc/"

; Version

#define Major

#define Minor

#define Release

#define Build

#expr ParseVersion(SourcePath + '\..\' + Project + '.exe',Major,Minor,Release,Build)

[Setup]

; Compiller

PrivilegesRequired=none

OutputBaseFilename={#Project}Setup

OutputDir=.

VersionInfoCompany={#Publisher}

VersionInfoDescription=InraPorc population Setup

VersionInfoVersion={#Major}.{#Minor}.{#Release}.{#Build}

; Installer

AppMutex={#Project}

AppName={#Project}

AppVerName={cm:NameAndVersion,{#Project},{#Major}.{#Minor}.{#Release}.{#Build}}

AppVersion={#Major}.{#Minor}.{#Release}.{#Build}

AppPublisher={#Publisher}

AppPublisherURL={#URL}

DefaultDirName={code:DefDirRoot}\InraPorc

DefaultGroupName=InraPorc

AllowNoIcons=true

DisableDirPage=yes

DisableProgramGroupPage=yes

[Tasks]

Name: desktopicon; Description: {cm:CreateDesktopIcon}; GroupDescription: {cm:AdditionalIcons}

Name: quicklaunchicon; Description: {cm:CreateQuickLaunchIcon}; GroupDescription: {cm:AdditionalIcons}; Flags: unchecked

[Files]

Source: ..\{#Project}.exe; DestDir: {app}; Flags: ignoreversion

[Icons]

Name: {group}\InraPorc population; Filename: {app}\{#Project}.exe; WorkingDir: {app}

Name: {userdesktop}\InraPorc population; Filename: {app}\{#Project}.exe; WorkingDir: {app}; Tasks: desktopicon

Name: {userappdata}\Microsoft\Internet Explorer\Quick Launch\InraPorc population; Filename: {app}\{#Project}.exe; WorkingDir: {app}; Tasks: quicklaunchicon

[Code]

function IsRegularUser(): Boolean;

begin

  Result := not (IsAdminLoggedOn or IsPowerUserLoggedOn);

end;

function DefDirRoot(Param: String): String;

begin

  if IsRegularUser then

    Result := ExpandConstant('{localappdata}')

  else

    Result := ExpandConstant('{pf}')

end;