InraPorc

unit UFResBesGestE;

interface

uses

  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,

  Dialogs, StdCtrls, Buttons, ExtCtrls, ComCtrls, CheckLst, Menus, Printers,

  Math, Contnrs, PBNumEdit, PBSuperSpin, Grids, TeEngine, Series, TeeProcs,

  Chart, TeeEdit, UVariables, gnugettext;

type

  TFResBesGestE = class(TForm)

    PC: TPageControl;

    TabNRJ: TTabSheet;

    TabAA: TTabSheet;

    CBAA3: TComboBox;

    CBAA4: TComboBox;

    GBAAY: TGroupBox;

    Graph: TChart;

    GBNRJY: TGroupBox;

    CBNRJ3: TComboBox;

    LBAA: TListBox;

    LBNRJ: TListBox;

    TSAli: TTabSheet;

    TSMin: TTabSheet;

    GBMinY: TGroupBox;

    CBMin3: TComboBox;

    CBMin4: TComboBox;

    CBNRJ4: TComboBox;

    PM: TPopupMenu;

    MI3D: TMenuItem;

    MIPreview: TMenuItem;

    MIPrint: TMenuItem;

    PD: TPrintDialog;

    procedure FormClose(Sender: TObject; var Action: TCloseAction);

    procedure FormShow(Sender: TObject);

    procedure PCChange(Sender: TObject);

    procedure CBNRJ3Change(Sender: TObject);

    procedure CBNRJ4Change(Sender: TObject);

    procedure CBAA3Change(Sender: TObject);

    procedure CBAA4Change(Sender: TObject);

    procedure CBAli2Change(Sender: TObject);

    procedure CBMin3Change(Sender: TObject);

    procedure CBMin4Change(Sender: TObject);

    procedure MI3DClick(Sender: TObject);

    procedure MIPreviewClick(Sender: TObject);

    procedure MIPrintClick(Sender: TObject);

    procedure FormCreate(Sender: TObject);

    procedure WMSysCommand(var Message: TWMSysCommand); message WM_SYSCOMMAND;

  private

    { D?clarations priv?es }

    BarAli : TBarSeries ;

    ListNRJ : TStrings ;

    BarNRJ : array of TBarSeries ;

    ListAA : TStrings ;

    BarAA35 : TBarSeries ;

    BarAA105 : TBarSeries ;

    BarMin35 : TBarSeries ;

    BarMin105 : TBarSeries ;

    procedure ResetGraph ;

    procedure InitAli ;

    procedure AffGraphAli ;

    procedure InitNRJ ;

    procedure AffGraphNRJ ;

    procedure InitAA ;

    procedure AffGraphAA ;

    procedure InitMin ;

    procedure AffGraphMin ;

  public

    { D?clarations publiques }

  end;

var

  FResBesGestE: TFResBesGestE;

implementation

uses

  UStrings, UFindRec, UUtil, UEchelle, UFBesGestE, UFPrevGraph ;

{$R *.dfm}

{ TFResBesGestE }

procedure TFResBesGestE.FormCreate(Sender: TObject);

begin

  if Screen.Fonts.IndexOf('Arial Unicode MS') <> -1

  then

    Font.Name := 'Arial Unicode MS';

  TranslateComponent(Self);

  Constraints.MinWidth := 544 + (Width - ClientWidth);

  Width := 640;

  Constraints.MinHeight := 400 + (Height - ClientHeight);

  Height := 480;

  CBNRJ3.ItemIndex := 0;

  CBNRJ4.Items.Add(Format('%s/%s', [StrMJ, StrJ]));

  CBNRJ4.Items.Add('%');

  CBNRJ4.ItemIndex := 0;

  CBAA3.ItemIndex := 0;

  CBAA4.Items.Add(Format('%s/%s', [StrG, StrJ]));

  CBAA4.Items.Add(Format('%s/%s %s', [StrG, StrKg, StrAlimentUnit]));

  CBAA4.ItemIndex := 0;

  CBMin3.ItemIndex := 0;

  CBMin4.Items.Add(Format('%s/%s', [StrG, StrJ]));

  CBMin4.Items.Add(Format('%s/%s %s', [StrG, StrKg, StrAlimentUnit]));

  CBMin4.ItemIndex := 0;

end;

procedure TFResBesGestE.FormShow (Sender : TObject) ;

begin

  MIPrint.Enabled := IsComplete or IsEducation ;

  // Aliment

  InitAli ;

  // Energie

  InitNRJ ;

  // Acides Amin?s

  InitAA ;

  // Min?raux

  InitMin ;

  // Affichage principal

  PC.ActivePageIndex := 0 ;

  PCChange (nil) ;

end ;

procedure TFResBesGestE.FormClose (Sender : TObject ; var Action : TCloseAction) ;

var

  i : integer ;

begin

  // Aliment

  BarAli.Free ;

  // Energie

  for i := 0 to ListNRJ.Count - 1 do

    BarNRJ[i].Free ;

  SetLength (BarNRJ, 0) ;

  ListNRJ.Free ;

  // Acides Amin?s

  BarAA35.Free ;

  BarAA105.Free ;

  ListAA.Free ;

  // Min?raux

  BarMin35.Free ;

  BarMin105.Free ;

end ;

procedure TFResBesGestE.PCChange (Sender : TObject) ;

begin

  case PC.ActivePageIndex of

    0 : // Aliment

      AffGraphAli ;

    1 : // Energie

      AffGraphNRJ ;

    2 : // Acides Amin?s

      AffGraphAA ;

    3 : // Min?raux

      AffGraphMin ;

  end ;

end ;

procedure TFResBesGestE.ResetGraph ;

var

  i : integer ;

begin

  Graph.UndoZoom ;

  Graph.View3D := FALSE ;

  Graph.Legend.Visible := TRUE ;

  Graph.Legend.Inverted := TRUE ;

  Graph.Title.Text.Clear ;

  Graph.SubTitle.Text.Clear ;

  Graph.LeftAxis.Automatic := FALSE ;

  Graph.BottomAxis.MinimumOffset := 0;

  Graph.BottomAxis.MaximumOffset := 0;

  // Aliment

  BarAli.Active := FALSE ;

  // Energie

  for i := 0 to ListNRJ.Count - 1 do

    BarNRJ[i].Active := FALSE ;

  // Acides Amin?s

  BarAA35.Active := FALSE ;

  BarAA105.Active := FALSE ;

  // Min?raux

  BarMin35.Active := FALSE ;

  BarMin105.Active := FALSE ;

end ;

procedure TFResBesGestE.MI3DClick (Sender : TObject) ;

begin

  Graph.View3D := not (Graph.View3D) ;

end ;

procedure TFResBesGestE.MIPreviewClick (Sender : TObject) ;

begin

  FPrevGraph := TFPrevGraph.Create (Self) ;

  with FPrevGraph do

  begin

    TPPGraph.Panels.Add (Graph) ;

    ShowModal ;

    Release ;

  end ;

end ;

procedure TFResBesGestE.MIPrintClick (Sender : TObject) ;

begin

  if PD.Execute

  then

  begin

    Printer.Orientation := poLandscape ;

    Graph.Print ;

  end ;

end ;

/////////////////

//   Aliment   //

/////////////////

procedure TFResBesGestE.InitAli ;

begin

  // BarAli : s?rie (barre) graphique

  BarAli := TBarSeries.Create (Graph) ;

  BarAli.ParentChart := Graph ;

  BarAli.Title := ' ' ;

  BarAli.SeriesColor := clTeal ;

  BarAli.BarPen.Color := BarAli.SeriesColor ;

  BarAli.Marks.Style := smsValue ;

  BarAli.Marks.ArrowLength := 0 ;

  BarAli.Marks.Arrow.Visible := FALSE ;

  BarAli.Marks.Brush.Style := bsClear ;

  BarAli.Marks.Frame.Visible := FALSE ;

  BarAli.Marks.Font.Style := [fsBold] ;

  Graph.AddSeries (BarAli) ;

end ;

procedure TFResBesGestE.AffGraphAli ;

var

  j : integer ;

  // Ordonn?e

  function AliY : double ;

  begin

    with FBesGestE do

      if (AppEMTot[j] = 0)

      then

        result := 0

      else

        result := BesEMTot[j] * AppAliTot[j] / AppEMTot[j] ;

  end ;

// AffGraphAli

begin

  ResetGraph ;

  Graph.Legend.Visible := FALSE ;

  Graph.Title.Text.Add (TSAli.Caption) ;

  Graph.LeftAxis.Title.Caption := Format ('%s (%s/%s)', [TSAli.Caption, StrKg, StrJ]) ;

  Graph.BottomAxis.Title.Caption := _('Litter');

  // Affichage de la barre

  BarAli.Active := TRUE ;

  BarAli.Clear ;

  for j := 1 to NB_CYCLES do

    BarAli.AddBar (AliY, Format ('%d', [j]), clTeeColor) ;

  AjustEchelle (Graph) ;

end ;

procedure TFResBesGestE.CBAli2Change(Sender: TObject);

begin

end;

/////////////////

//   Energie   //

/////////////////

procedure TFResBesGestE.InitNRJ ;

const

  TabColor : array[0..4] of TColor

    = (clOlive, clGray, clAqua, clPurple, clNavy) ;

var

  i : integer ;

begin

  // ListNRJ : liste pour l'?nergie

  ListNRJ := TStringList.Create ;

  ListNRJ.Assign (LBNRJ.Items) ;

  // BarNRJ : s?ries (barres) graphiques

  SetLength (BarNRJ, ListNRJ.Count) ;

  for i := 0 to ListNRJ.Count - 1 do

  begin

    BarNRJ[i] := TBarSeries.Create (Graph) ;

    BarNRJ[i].ParentChart := Graph ;

    BarNRJ[i].Title := ListNRJ[i] ;

    BarNRJ[i].SeriesColor := TabColor[i] ;

    BarNRJ[i].BarPen.Color := BarNRJ[i].SeriesColor ;

    BarNRJ[i].Marks.Visible := FALSE ;

    Graph.AddSeries (BarNRJ[i]) ;

  end ;

end ;

procedure TFResBesGestE.AffGraphNRJ ;

var

  i, j : integer ;

  m : double ;

  // Ordonn?e

  function NRJY : double ;

  begin

    case i of

      0 : // Entretien

        result := FBesGestE.BesEMEntTot[j] ;

      1 : // Activit?

        result := FBesGestE.BesEMActTot[j] ;

      2 : // Thermor?gulation

        result := FBesGestE.BesEMTheTot[j] ;

      3 : // Port?e

        result := FBesGestE.BesEMPortTot[j] ;

      4 : // R?serve

        result := FBesGestE.BesEMResTot[j] ;

      else

        result := 0 ;

    end ;

  end ;

// AffGraphNRJ

begin

  ResetGraph ;

  Graph.Title.Text.Add (TabNRJ.Caption) ;

  Graph.LeftAxis.Title.Caption := Format ('%s (%s)', [CBNRJ3.Text, CBNRJ4.Text]) ;

  Graph.BottomAxis.Title.Caption := _('Litter');

  // Affichage des barres

  for i := 0 to ListNRJ.Count - 1 do

    BarNRJ[i].Active := TRUE ;

  for i := 0 to ListNRJ.Count - 1 do

    BarNRJ[i].Clear ;

  if (CBNRJ4.ItemIndex = 1)

  then

    for i := 0 to ListNRJ.Count - 1 do

      BarNRJ[i].MultiBar := mbStacked100

  else

    for i := 0 to ListNRJ.Count - 1 do

      BarNRJ[i].MultiBar := mbStacked ;

  for j := 1 to NB_CYCLES do

  begin

    case CBNRJ3.ItemIndex of

      0 : // Energie digestible

        m := FBesGestE.AppEDTot[j] / FBesGestE.AppEMTot[j] ;

      2 : // Energie nette

        m := FBesGestE.AppENTot[j] / FBesGestE.AppEMTot[j] ;

      else

        m := 1 ;

    end ;

    for i := 0 to ListNRJ.Count - 1 do

      BarNRJ[i].AddBar (NRJY * m, Format ('%d', [j]), clTeeColor) ;

  end ;

  AjustEchelle (Graph) ;

end ;

procedure TFResBesGestE.CBNRJ3Change (Sender : TObject) ;

begin

  AffGraphNRJ ;

end ;

procedure TFResBesGestE.CBNRJ4Change (Sender : TObject) ;

begin

  AffGraphNRJ ;

end ;

///////////////////////

//   Acides amin?s   //

///////////////////////

procedure TFResBesGestE.InitAA ;

const

  TabColor : array[0..3] of TColor

    = (clOlive, clPurple, clNavy, clGreen) ;

begin

  // ListAA : liste pour les acides amin?s

  ListAA := TStringList.Create ;

  ListAA.Assign (LBAA.Items) ;

  // BarAA35 et BarAA105 : s?ries (barres) graphiques

  BarAA35 := TBarSeries.Create (Graph) ;

  BarAA35.ParentChart := Graph ;

  BarAA35.Title := Str35j ;

  BarAA35.SeriesColor := clGreen ;

  BarAA35.BarPen.Color := BarAA35.SeriesColor ;

  BarAA35.Marks.Visible := FALSE ;

  Graph.AddSeries (BarAA35) ;

  BarAA105 := TBarSeries.Create (Graph) ;

  BarAA105.ParentChart := Graph ;

  BarAA105.Title := Str105j ;

  BarAA105.SeriesColor := clNavy ;

  BarAA105.BarPen.Color := BarAA105.SeriesColor ;

  BarAA105.Marks.Visible := FALSE ;

  Graph.AddSeries (BarAA105) ;

end ;

procedure TFResBesGestE.AffGraphAA ;

var

  h, i, j : integer ;

  // Ordonn?e

  function AAY : double ;

  var

    a : integer ;

    d : double ;

  begin

    case h of

      3 : // met+cys

        a := 13 ;

      7 : // phe+tyr

        a := 14 ;

      else

        a := h ;

    end ;

    // Diviseur

    case CBAA4.ItemIndex of

      1 : // Aliment

        d := FBesGestE.BesEMTot[j] * FBesGestE.AppAliTot[j] / FBesGestE.AppEMTot[j] ;

      else

        d := 1 ;

    end ;

    result := FBesGestE.BesAA[j, a, i] / d ;

  end ;

// AffGraphAA

begin

  ResetGraph ;

  Graph.Title.Text.Add (TabAA.Caption) ;

  Graph.SubTitle.Text.Add(StrDigestStd);

  Graph.Legend.Inverted := FALSE ;

  Graph.LeftAxis.Title.Caption := Format ('%s (%s)', [CBAA3.Text, CBAA4.Text]) ;

  Graph.BottomAxis.Title.Caption := _('Litter');

  // Affichage des barres

  BarAA35.Active := TRUE ;

  BarAA105.Active := TRUE ;

  BarAA35.Clear ;

  BarAA105.Clear ;

  BarAA35.MultiBar := mbSide ;

  BarAA105.MultiBar := mbSide ;

  h := CBAA3.ItemIndex + 1 ;

  for j := 1 to NB_CYCLES do

  begin

    i := 35 ;

    BarAA35.AddBar (AAY, Format ('%d', [j]), clTeeColor) ;

    i := 105 ;

    BarAA105.AddBar (AAY, Format ('%d', [j]), clTeeColor) ;

  end ;

  AjustEchelle (Graph) ;

end ;

procedure TFResBesGestE.CBAA3Change (Sender : TObject) ;

begin

  AffGraphAA ;

end ;

procedure TFResBesGestE.CBAA4Change (Sender : TObject) ;

begin

  AffGraphAA ;

end ;

//////////////////

//   Min?raux   //

//////////////////

procedure TFResBesGestE.InitMin ;

begin

  // BarMin35 et BarMin105 : s?ries (barres) graphiques

  BarMin35 := TBarSeries.Create (Graph) ;

  BarMin35.ParentChart := Graph ;

  BarMin35.Title := Str35j ;

  BarMin35.SeriesColor := clGreen ;

  BarMin35.BarPen.Color := BarMin35.SeriesColor ;

  BarMin35.Marks.Visible := FALSE ;

  Graph.AddSeries (BarMin35) ;

  BarMin105 := TBarSeries.Create (Graph) ;

  BarMin105.ParentChart := Graph ;

  BarMin105.Title := Str105j ;

  BarMin105.SeriesColor := clNavy ;

  BarMin105.BarPen.Color := BarMin105.SeriesColor ;

  BarMin105.Marks.Visible := FALSE ;

  Graph.AddSeries (BarMin105) ;

end ;

procedure TFResBesGestE.AffGraphMin ;

var

  i, j : integer ;

  // Ordonn?e

  function MinY : double ;

  var

    d : double ;

  begin

    // Diviseur

    case CBMin4.ItemIndex of

      1 : // Aliment

        d := FBesGestE.AppAli[j, i] ;

      else

        d := 1 ;

    end ;

    case CBMin3.ItemIndex of

      0 : // Phosphore digestible

        result := FBesGestE.BesP[j, i] / d ;

      1 : // Calcium total

        result := FBesGestE.BesCa[j, i] / d ;

      else

        result := 0 ;

    end ;

  end ;

// AffGraphMin

begin

  ResetGraph ;

  Graph.Title.Text.Add (TSMin.Caption) ;

  Graph.Legend.Inverted := FALSE ;

  Graph.LeftAxis.Title.Caption := Format ('%s (%s)', [CBMin3.Text, CBMin4.Text]) ;

  Graph.BottomAxis.Title.Caption := _('Litter');

  // Affichage de la barre

  BarMin35.Active := TRUE ;

  BarMin105.Active := TRUE ;

  BarMin35.Clear ;

  BarMin105.Clear ;

  BarMin35.MultiBar := mbSide ;

  BarMin105.MultiBar := mbSide ;

  for j := 1 to NB_CYCLES do

  begin

    i := 35 ;

    BarMin35.AddBar (MinY, Format ('%d', [j]), clTeeColor) ;

    i := 105 ;

    BarMin105.AddBar (MinY, Format ('%d', [j]), clTeeColor) ;

  end ;

  AjustEchelle (Graph) ;

end ;

procedure TFResBesGestE.CBMin3Change(Sender: TObject);

begin

  AffGraphMin ;

end;

procedure TFResBesGestE.CBMin4Change(Sender: TObject);

begin

  AffGraphMin ;

end;

procedure TFResBesGestE.WMSysCommand(var Message: TWMSysCommand);

begin

  if Message.CmdType = SC_MINIMIZE

  then

    Application.Minimize

  else

    inherited;

end;

end.