InraPorc

unit UFLudo;

interface

uses

  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,

  Dialogs, ComCtrls, StdCtrls, Mask, JvExMask, JvToolEdit, JvExStdCtrls,

  JvCombobox, JvExComCtrls, JvComCtrls, JvSpeedButton, JvRadioButton,

  JvExControls, JvComponent, JvLabel, JvEdit, JvValidateEdit, JvSpin,

  JvStatusBar, JvGroupBox, DB, JvCsvData, Math, MidasLib, UVariables, ExtCtrls,

  Buttons, TeeProcs, TeEngine, Chart, ASGSQLite3, Series, dmath, Registry,

  XPMan;

type

  TFLudo = class(TForm)

    JvDEFolder:   TJvDirectoryEdit;

    JvFEImport:   TJvFilenameEdit;

    JvFEResult:   TJvFilenameEdit;

    JvCsvDSImport: TJvCsvDataSet;

    JvCsvDSResult: TJvCsvDataSet;

    JvFEBilan:    TJvFilenameEdit;

    JvCsvDSBilan: TJvCsvDataSet;

    PFolder:      TPanel;

    PC:           TPageControl;

    TSImport:     TTabSheet;

    TSObserv:     TTabSheet;

    TSCalibr:     TTabSheet;

    TSGraph:      TTabSheet;

    TSSimul:      TTabSheet;

    MImport:      TMemo;

    MSimul:       TMemo;

    LFolder:      TLabel;

    LImport:      TLabel;

    LBilan:       TLabel;

    LResult:      TLabel;

    LRation2:     TLabel;

    LSeqAli2:     TLabel;

    CBRation2:    TComboBox;

    CBSeqAli2:    TComboBox;

    SBImport:     TSpeedButton;

    SBSimul:      TSpeedButton;

    JvCsvDSObserv: TJvCsvDataSet;

    JvFEObserv:   TJvFilenameEdit;

    MObserv:      TMemo;

    LObserv:      TLabel;

    SBObserv:     TSpeedButton;

    LRation1:     TLabel;

    LSeqAli1:     TLabel;

    CBRation1:    TComboBox;

    CBSeqAli1:    TComboBox;

    SBCalibr:     TSpeedButton;

    MCalibr:      TMemo;

    LProfil:      TLabel;

    CBProfil:     TComboBox;

    CGraph:       TChart;

    LUnite:       TLabel;

    CBUnite:      TComboBox;

    LEquation:    TLabel;

    CBEquation:   TComboBox;

    GBAdLib:      TGroupBox;

    LY50:         TLabel;

    LY100:        TLabel;

    LCarcasse:    TLabel;

    LPDMoy:       TLabel;

    LPrecocite:   TLabel;

    LEntretien:   TLabel;

    LPVmr2:       TLabel;

    JvVECarcasse: TJvValidateEdit;

    JvVEPDMoy:    TJvValidateEdit;

    JvVEPrecocite: TJvValidateEdit;

    JvVEEntretien: TJvValidateEdit;

    JvVEPVmr2:    TJvValidateEdit;

    JvVEY50:      TJvValidateEdit;

    JvVEY100:     TJvValidateEdit;

    ASQLite3DBInraPorc: TASQLite3DB;

    ASQLite3TableObserv: TASQLite3Table;

    EY50:         TEdit;

    EY100:        TEdit;

    EPDMoy:       TEdit;

    EPrecocite:   TEdit;

    EEntretien:   TEdit;

    LineFeed:     TLineSeries;

    LineWeight:   TLineSeries;

    PointFeed:    TLineSeries;

    PointWeight:  TLineSeries;

    CheckBox1:    TCheckBox;

    CheckBox2:    TCheckBox;

    CheckBox3:    TCheckBox;

    CheckBox4:    TCheckBox;

    CheckBox5:    TCheckBox;

    CheckBox7:    TCheckBox;

    CheckBox8:    TCheckBox;

    CheckBox9:    TCheckBox;

    TSExport:     TTabSheet;

    LExport:      TLabel;

    SBExport:     TSpeedButton;

    JvFEExport:   TJvFilenameEdit;

    MExport:      TMemo;

    JvCsvDSExport: TJvCsvDataSet;

    XPManifestStyle: TXPManifest;

    GroupBoxFin:  TGroupBox;

    JvValidateEditDuree: TJvValidateEdit;

    JvValidateEditPVFin: TJvValidateEdit;

    RadioButtonPVFin: TRadioButton;

    RadioButtonDuree: TRadioButton;

    CheckBoxProfil: TCheckBox;

    CheckBox6: TCheckBox;

    CBAALimitCalibr: TCheckBox;

    EPVInit: TEdit;

    CBAALimitSimul: TCheckBox;

    CBAALimitGraph: TCheckBox;

    procedure JvDEFolderChange(Sender: TObject);

    procedure SBImportClick(Sender: TObject);

    procedure SBSimulClick(Sender: TObject);

    procedure FormShow(Sender: TObject);

    procedure FormClose(Sender: TObject; var Action: TCloseAction);

    procedure SBObservClick(Sender: TObject);

    procedure SBCalibrClick(Sender: TObject);

    procedure CBProfilChange(Sender: TObject);

    procedure CBUniteChange(Sender: TObject);

    procedure FormCreate(Sender: TObject);

    procedure SBExportClick(Sender: TObject);

    procedure CheckBoxProfilClick(Sender: TObject);

  private

    { D?clarations priv?es }

    dUnite, mUnite: double;

    procedure LoadAliment;

    procedure LoadSeqAliP;

    procedure LoadRationP;

    procedure LoadProfilP;

    procedure FreeAliment;

    procedure FreeSeqAliP;

    procedure FreeRationP;

    procedure FreeProfilP;

    procedure FreeSimulP;

    procedure StringsSeqAliP(Liste: TStrings);

    procedure StringsRationP(Liste: TStrings);

    procedure StringsProfilP(Liste: TStrings);

    procedure SaveProfilP;

  public

    { D?clarations publiques }

  end;

var

  FLudo: TFLudo;

implementation

uses

  SHFolder, UFindRec, UUtil, UCalcul, UCalcSimulP;

{$R *.dfm}

const

  MaxIter = 100;

  Tol = MICRO;

type

  RecCalibr = record

    Age: integer;

    Id:  integer; // 1=Feed, 2=Weight, 3=Backfat, 4=Lean

    Observ: extended;

    Predict: extended;

  end;

  PRecCalibr = ^RecCalibr;

var

  ListRecCalibr: TList;

  NVar, NVarDep, NData: integer;

  X, G: TVector;

  H_inv: TMatrix;

  F_min, Det: Float;

  Inv: array[1..6] of Float;

  Nb:  array[1..4] of integer;

  Tot, M, w: array[1..4] of double;

// Fonction de minimisation des ?carts entre les valeurs pr?dites et celles observ?es

function Func(X: TVector): Float;

var

  i, jour: integer;

  Y50, Y100, cumul: Float;

  rec: PRecCalibr;

begin

  i := 0;

  if FLudo.CheckBox5.Checked

  then

  begin

    Inc(i);

    if X[i] <= 0 then

      PProfilP.PVInit := MILLI

    else

      PProfilP.PVInit := X[i];

    // Recalculer les poids initiaux de prot?ines et lipides

    PProfilP.ProtInit := CalcProt(PProfilP.PVInit);

    PProfilP.LipInit := CalcLipProt(PProfilP.PVInit, PProfilP.ProtInit);

  end;

  if FLudo.CheckBox6.Checked then

  begin

    Inc(i);

    Y50 := X[i];

    Inc(i);

    Y100 := X[i];

    try

      CalcCoef(PProfilP.Equation, PProfilP.Unite, Y50, Y100, PProfilP.a, PProfilP.b);

    except

      PProfilP.a := 0;

      PProfilP.b := 0;

    end;

  end;

  if FLudo.CheckBox7.Checked then

  begin

    Inc(i);

    if X[i] <= 0 then

      PProfilP.PDMoy := MILLI

    else

      PProfilP.PDMoy := X[i];

  end;

  if FLudo.CheckBox8.Checked then

  begin

    Inc(i);

    if X[i] <= 0 then

      PProfilP.BGompertz := MILLI

    else

      PProfilP.BGompertz := X[i];

  end;

  if FLudo.CheckBox9.Checked then

  begin

    Inc(i);

    if X[i] <= 0 then

      PProfilP.Entretien := MILLI

    else

      PProfilP.Entretien := X[i];

  end;

  // Valeur des param?tres du cas ?valu?

  try

    // Affichage de la simulation

    CalcSimulP(-1, PProfilP.Num, PProfilP.SeqAli, PProfilP.Ration, -1, 1, PResSimulP, FLudo.CBAALimitCalibr.Checked);

  except // La simulation a ?chou?

    for i := 0 to ListRecCalibr.Count - 1 do

    begin

      rec := ListRecCalibr[i];

      rec.Predict := 0;

    end;

  end;

  // Evaluation du cas

  i := 0;

  rec := ListRecCalibr[i];

  cumul := 0;

  for jour := 1 to PResSimulP.NbJSim do

  begin

    while (i < ListRecCalibr.Count) and (PResSimulP.TabResult[1, jour] = rec.Age) do

    begin

      case rec.Id of

        1: // Feed

          rec.Predict := cumul;

        2: // Weight

          rec.Predict := PResSimulP.TabResult[2, jour];

        3: // Backfat (P2)

          rec.Predict := CalcP2(PResSimulP.TabResult[50, jour]);

        4: // Lean (TMP)

          rec.Predict := CalcTMP(PResSimulP.TabResult[48, jour],

            PResSimulP.TabResult[49, jour], PResSimulP.TabResult[50, jour]);

      end;

      Inc(i);

      if i < ListRecCalibr.Count then

        rec := ListRecCalibr[i];

    end;

    cumul := cumul + PResSimulP.TabResult[113, jour];

  end;

  // Ecart par rapport aux valeurs du profil

  Result := 0;

  for i := 0 to ListRecCalibr.Count - 1 do

  begin

    rec := ListRecCalibr[i];

    case rec.Id of

      1: // Feed

        if FLudo.CheckBox1.Checked then

          Result := Result + w[1] * Power(rec.Observ - rec.Predict, 2);

      2: // Weight

        if FLudo.CheckBox2.Checked then

          Result := Result + w[2] * Power(rec.Observ - rec.Predict, 2);

      3: // Backfat

        if FLudo.CheckBox3.Checked then

          Result := Result + w[3] * Power(rec.Observ - rec.Predict, 2);

      4: // Lean

        if FLudo.CheckBox4.Checked then

          Result := Result + w[4] * Power(rec.Observ - rec.Predict, 2);

    end;

  end;

end;

// Newton-Raphson method

// procedure HessGrad to compute the gradient G and the hessian H of the function at point X

{$I numhess.inc}

 // Broyden-Fletcher-Goldfarb-Shanno method

 // procedure Gradient to compute the gradient G of the function at point X

 //{$I numgrad.inc}

procedure TFLudo.FormCreate(Sender: TObject);

begin

  dUnite := cGammaEN;

end;

procedure TFLudo.FormShow(Sender: TObject);

var

  Buffer: Pointer;

  Version: PVSFixedFileInfo;

  BufferSize, VersionSize: DWORD;

  VolumeSerialNumber, MaximumComponentLength, FileSystemFlags: DWORD;

  Personal: array[0..MAX_PATH] of Char;

begin

  NFicAliment := 'Aliment.rec';

  NFicSeqAliP := 'SeqAliP.rec';

  NFicRationP := 'RationP2.rec';

  NFicProfilP := 'ProfilP2.rec';

  ListAliment := TList.Create;

  ListSeqAliP := TList.Create;

  ListRationP := TList.Create;

  ListProfilP := TList.Create;

  ListSimulP := TList.Create;

  // Version du programme

  MajorVersion := 0;

  MinorVersion := 0;

  ReleaseVersion := 0;

  BuildVersion := 0;

  BufferSize := GetFileVersionInfoSize(PChar(Application.ExeName), BufferSize);

  if BufferSize > 0

  then

  begin

    GetMem(Buffer, BufferSize);

    if GetFileVersionInfo(PChar(Application.ExeName), 0, BufferSize, Buffer)

    then

    begin

      VerQueryValue(Buffer, '\', Pointer(Version), VersionSize);

      MajorVersion := Version.dwFileVersionMS shr 16;

      MinorVersion := Version.dwFileVersionMS and $FFFF;

      ReleaseVersion := Version.dwFileVersionLS shr 16;

      BuildVersion := Version.dwFileVersionLS and $FFFF;

    end;

    FreeMem(Buffer, BufferSize);

  end ;

  VersionString := Format('%d.%d.%d.%d', [MajorVersion, MinorVersion, ReleaseVersion, BuildVersion]);

  // Num?ro de s?rie du volume

  Drive := IncludeTrailingPathDelimiter(ExtractFileDrive(Application.ExeName));

  GetVolumeInformation(PChar(Drive), nil, 0, @VolumeSerialNumber, MaximumComponentLength, FileSystemFlags, nil, 0);

  Volume := IntToHex(HiWord(VolumeSerialNumber), 4) + '-' + IntToHex(LoWord(VolumeSerialNumber), 4);

  // LoadLicense

  Reg := TRegistry.Create;

  Reg.RootKey := HKEY_CURRENT_USER;

  LicenseType := BdRReadInteger('\Software\InraPorc\License', 'LicenseType', 0);

  LicenseNumber := BdRReadInteger('\Software\InraPorc\License', 'LicenseNumber', 0);

  FirstName := BdRReadString('\Software\InraPorc\License', 'FirstName', '');

  LastName := BdRReadString('\Software\InraPorc\License', 'LastName', '');

  Company := BdRReadString('\Software\InraPorc\License', 'Company', '');

  Address1 := BdRReadString('\Software\InraPorc\License', 'Address1', '');

  Address2 := BdRReadString('\Software\InraPorc\License', 'Address2', '');

  PostalCode := BdRReadString('\Software\InraPorc\License', 'PostalCode', '');

  City := BdRReadString('\Software\InraPorc\License', 'City', '');

  Country := BdRReadString('\Software\InraPorc\License', 'Country', '');

  Phone := BdRReadString('\Software\InraPorc\License', 'Phone', '');

  Fax := BdRReadString('\Software\InraPorc\License', 'Fax', '');

  Mail := BdRReadString('\Software\InraPorc\License', 'Mail', '');

  Course := BdRReadString('\Software\InraPorc\License', 'Course', '');

  FinalDate := BdRReadString('\Software\InraPorc\License', 'FinalDate', '31/12/2099');

  SoftwareEnableKey := BdRReadString('\Software\InraPorc\License', 'SoftwareEnableKey', '');

  // LoadConfig

  SHGetFolderPath(0, CSIDL_PERSONAL, 0, SHGFP_TYPE_CURRENT, Personal);

  Folder := BdRReadString('\Software\InraPorc\Config\Data', 'Folder', IncludeTrailingPathDelimiter(Personal) + 'InraPorc');

  JvDEFolder.Text := Reg.ReadString('Folder');

  Reg.Free;

  // V?rification de la licence

  if not IsComplete then

  begin

    MessageDlg('Licence non valide !',

      mtError, [mbOK], 0);

    Close;

    Exit;

  end;

  // Liste des num?ros autoris?s

  if (LicenseNumber <> 1)      //   1 = Alain Valancogne

    and (LicenseNumber <> 2)   //   2 = Jaap van Milgen

    and (LicenseNumber <> 20)  //  20 = Ludovic Brossard

    and (LicenseNumber <> 352) // 352 = Ludovic Brossard (portable)

    and (LicenseNumber <> 301) // 301 = Ludovic Brossard (Alice Cadero)

    and (LicenseNumber <> 372) // 372 = Florence Garcia-Launay

    and (LicenseNumber <> 347) // 347 = Florence Garcia-Launay

    and (LicenseNumber <> 16)  //  16 = Nathalie Quiniou

    and (LicenseNumber <> 412) // 412 = Lisanne Verschuren (Topigs)

    and (LicenseNumber <> 418) // 418 = Faezeh Soleimani-Jevinani (th?se H?l?ne Gilbert)

  then

  begin

    MessageDlg('Num?ro de licence non autoris? !',

      mtError, [mbOK], 0);

    Close;

    Exit;

  end;

  PC.ActivePageIndex := 0;

end;

procedure TFLudo.FormClose(Sender: TObject; var Action: TCloseAction);

begin

  FreeAliment;

  ListAliment.Free;

  FreeSeqAliP;

  ListSeqAliP.Free;

  FreeRationP;

  ListRationP.Free;

  FreeProfilP;

  ListProfilP.Free;

  ListSimulP.Free;

end;

procedure TFLudo.JvDEFolderChange(Sender: TObject);

begin

  FreeAliment;

  FreeSeqAliP;

  FreeRationP;

  FreeProfilP;

  FreeSimulP;

  MImport.Lines.Clear;

  MSimul.Lines.Clear;

  if not DirectoryExists(JvDEFolder.LongName) then

    Exit;

  SetCurrentDir(JvDEFolder.LongName);

  JvFEImport.InitialDir := GetCurrentDir;

  ASQLite3DBInraPorc.DefaultDir := GetCurrentDir;

  JvFEObserv.InitialDir := GetCurrentDir;

  JvFEResult.InitialDir := GetCurrentDir;

  JvFEBilan.InitialDir  := GetCurrentDir;

  if FileExists(NFicAliment) then

    LoadAliment;

  if FileExists(NFicSeqAliP) then

    LoadSeqAliP;

  StringsSeqAliP(CBSeqAli1.Items);

  StringsSeqAliP(CBSeqAli2.Items);

  if FileExists(NFicRationP) then

    LoadRationP;

  StringsRationP(CBRation1.Items);

  StringsRationP(CBRation2.Items);

  if FileExists(NFicProfilP) then

  begin

    LoadProfilP;

    StringsProfilP(CBProfil.Items);

    CBProfilChange(nil);

  end;

end;

// Onglet Importation

procedure TFLudo.SBImportClick(Sender: TObject);

begin

  if not FileExists(JvFEImport.Text) then

  begin

    MessageDlg('Indiquer le fichier ? importer !', mtWarning, [mbOK], 0);

    ActiveControl := JvFEImport;

    Exit;

  end;

  if ListProfilP.Count > 0 then

  begin

    MessageDlg('Il existe d?j? un (ou plusieurs) profil(s) !', mtError, [mbOK], 0);

    Exit;

  end;

  // Importation

  Screen.Cursor := crHourGlass;

  MImport.Lines.Clear;

  Application.ProcessMessages;

  JvCsvDSImport.FileName := JvFEImport.Text;

  JvCsvDSImport.Active := True;

  JvCsvDSImport.First;

  while not JvCsvDSImport.EOF do

  begin

    New(PProfilP);

    with PProfilP^ do

    begin

      Num := JvCsvDSImport.RecNo + 1;

      Nom := ansistring(JvCsvDSImport.Fields[0].AsString);

      Memo := '';

      Sexe := JvCsvDSImport.Fields[1].AsInteger;

      SeqAli := -1;

      Ration := -1;

      AgeInit := JvCsvDSImport.Fields[2].AsInteger;

      PVInit := JvCsvDSImport.Fields[3].AsFloat;

      ProtInit := CalcProt(PVInit);

      LipInit := CalcLipProt(PVInit, ProtInit);

      ModeFin := JvCsvDSImport.Fields[4].AsInteger;

      Duree := JvCsvDSImport.Fields[5].AsInteger;

      PVFin := JvCsvDSImport.Fields[6].AsFloat;

      Carcasse := JvCsvDSImport.Fields[7].AsFloat;

      Unite := JvCsvDSImport.Fields[8].AsInteger;

      Equation := JvCsvDSImport.Fields[9].AsInteger;

      a := JvCsvDSImport.Fields[10].AsFloat;

      b := JvCsvDSImport.Fields[11].AsFloat;

      PDMoy := JvCsvDSImport.Fields[12].AsFloat;

      BGompertz := JvCsvDSImport.Fields[13].AsFloat;

      Entretien := JvCsvDSImport.Fields[14].AsFloat;

      PVmr2 := JvCsvDSImport.Fields[15].AsFloat;

    end;

    ListProfilP.Add(PProfilP);

    MImport.Lines.Add(Format('%s (%d/%d)', [PProfilP.Nom, PProfilP.Num,

      JvCsvDSImport.RecordCount]));

    Application.ProcessMessages;

    JvCsvDSImport.Next;

  end;

  JvCsvDSImport.Active := False;

  SaveProfilP;

  Screen.Cursor := crDefault;

  StringsProfilP(CBProfil.Items);

  CBProfilChange(nil);

end;

// Onglet Observations

procedure TFLudo.CBUniteChange(Sender: TObject);

begin

  if (CBUnite.ItemIndex = 0) or (CBUnite.ItemIndex = 4) then // kg (QI ou MS)

    JvVEY50.DecimalPlaces := 3

  else // MJ (ED, EM ou EN)

    JvVEY50.DecimalPlaces := 2;

  JvVEY100.DecimalPlaces := JvVEY50.DecimalPlaces;

  case CBUnite.ItemIndex of

    0: // Quantit? (kg/j)

      mUnite := cGammaFrais;

    1: // ED (MJ/j)

      mUnite := cGammaED;

    2: // EM (MJ/j)

      mUnite := cGammaEM;

    3: // EN (MJ/j)

      mUnite := cGammaEN;

    4: // MS (kg/j)

      mUnite := cGammaMS;

    else

      mUnite := 1;

  end;

  if dUnite <> mUnite then

  begin

    JvVEY50.AsFloat := mUnite * JvVEY50.AsFloat / dUnite;

    JvVEY50.AsFloat := mUnite * JvVEY50.AsFloat / dUnite;

    dUnite := mUnite;

  end;

end;

procedure TFLudo.SBObservClick(Sender: TObject);

var

  ligne: integer;

  cumul: double;

begin

  if not FileExists(JvFEObserv.Text) then

  begin

    MessageDlg('Indiquer le fichier ? importer !', mtWarning, [mbOK], 0);

    ActiveControl := JvFEObserv;

    Exit;

  end;

  if ListProfilP.Count > 0 then

  begin

    MessageDlg('Il existe d?j? un (ou plusieurs) profil(s) !', mtError, [mbOK], 0);

    Exit;

  end;

  if not FileExists(ASQLite3DBInraPorc.Database) then

  begin

    MessageDlg('Le dossier ne contient pas de base SQLite pour stocker les observations  !', mtError, [mbOK], 0);

    Exit;

  end;

  ASQLite3TableObserv.Open;

  if not ASQLite3TableObserv.IsEmpty then

  begin

    MessageDlg('Il existe d?j? une (ou plusieurs) observation(s) !',

      mtError, [mbOK], 0);

    Exit;

  end;

  // Observations

  Screen.Cursor := crHourGlass;

  MObserv.Lines.Clear;

  Application.ProcessMessages;

  ASQLite3TableObserv.DisableControls;

  ASQLite3TableObserv.StartTransaction;

  JvCsvDSObserv.FileName := JvFEObserv.Text;

  JvCsvDSObserv.DisableControls;

  JvCsvDSObserv.Active := True;

  JvCsvDSObserv.First;

  ligne := 0;

  cumul := 0;

  while not JvCsvDSObserv.EOF do

  begin

    if (ligne > 0) and (ansistring(JvCsvDSObserv.Fields[0].AsString) <> PProfilP.Nom)

    then // Rupture profil

    begin

      PProfilP.Duree := ASQLite3TableObserv.FieldByName('Age').AsInteger -

        PProfilP.AgeInit + 1;

      ListProfilP.Add(PProfilP);

      MObserv.Lines.Add(Format('%s : %d observations', [PProfilP.Nom, ligne]));

      Application.ProcessMessages;

      ligne := 0;

      cumul := 0;

    end;

    if (ligne = 0) and not JvCsvDSObserv.Fields[4].IsNull then

      // Initialisation profil

    begin

      New(PProfilP);

      with PProfilP^ do

      begin

        Num  := ListProfilP.Count + 1;

        Nom  := ansistring(JvCsvDSObserv.Fields[0].AsString);

        Memo := '';

        if JvCsvDSObserv.Fields[1].IsNull then

          Sexe := -1

        else

          Sexe := JvCsvDSObserv.Fields[1].AsInteger;

        SeqAli := -1;

        Ration := -1;

        AgeInit := JvCsvDSObserv.Fields[2].AsInteger;

        PVInit := JvCsvDSObserv.Fields[4].AsFloat;

        ProtInit := CalcProt(PVInit);

        LipInit := CalcLipProt(PVInit, ProtInit);

        ModeFin := 0; // Dur?e

        PVFin := 0;

        Carcasse := JvVECarcasse.AsFloat / 100;

        Unite := CBUnite.ItemIndex;

        Equation := CBEquation.ItemIndex;

        CalcCoef(Equation, Unite, JvVEY50.AsFloat, JvVEY100.AsFloat, a, b);

        PDMoy := JvVEPDMoy.AsFloat;

        BGompertz := JvVEPrecocite.AsFloat;

        Entretien := JvVEEntretien.AsFloat;

        PVmr2 := JvVEPVmr2.AsFloat;

      end;

    end;

    if (ligne > 0) or not JvCsvDSObserv.Fields[4].IsNull then

      // Prise en compte de l'enregistrement

    begin

      ligne := ligne + 1;

      with ASQLite3TableObserv do

      begin

        Append;

        FieldByName('Profile').AsInteger := PProfilP.Num;

        FieldByName('Line').AsInteger := ligne;

        FieldByName('Age').AsInteger := JvCsvDSObserv.Fields[2].AsInteger;

        FieldByName('Feed').AsFloat := cumul;

        if not JvCsvDSObserv.Fields[4].IsNull then

          FieldByName('Weight').AsFloat := JvCsvDSObserv.Fields[4].AsFloat;

        if not JvCsvDSObserv.Fields[5].IsNull then

          FieldByName('Backfat').AsFloat := JvCsvDSObserv.Fields[5].AsFloat;

        if not JvCsvDSObserv.Fields[6].IsNull then

          FieldByName('Lean').AsFloat := JvCsvDSObserv.Fields[6].AsFloat;

        Post;

      end;

      cumul := cumul + JvCsvDSObserv.Fields[3].AsFloat;

    end;

    JvCsvDSObserv.Next;

  end;

  if ligne > 0 then // Enregistrement du dernier profil

  begin

    PProfilP.Duree := ASQLite3TableObserv.FieldByName('Age').AsInteger -

      PProfilP.AgeInit + 1;

    ListProfilP.Add(PProfilP);

    MObserv.Lines.Add(Format('%s : %d observations', [PProfilP.Nom, ligne]));

    Application.ProcessMessages;

  end;

  JvCsvDSObserv.Active := False;

  JvCsvDSObserv.EnableControls;

  try

    ASQLite3TableObserv.Commit;

  except

    ASQLite3TableObserv.RollBack;

  end;

  ASQLite3TableObserv.EnableControls;

  ASQLite3DBInraPorc.Close;

  SaveProfilP;

  Screen.Cursor := crDefault;

  StringsProfilP(CBProfil.Items);

  CBProfilChange(nil);

end;

// Onglet Calibrage

procedure TFLudo.SBCalibrClick(Sender: TObject);

var

  i, profil: integer;

  wTot: double;

  rec:  PRecCalibr;

  SSt, SSr: array[1..4] of double;

  Log:  TextFile;

  procedure Uncheck;

  begin

    CheckBox1.Checked := False; // Feed

    CheckBox2.Checked := False; // Weight

    CheckBox3.Checked := False; // Backfat

    CheckBox4.Checked := False; // Lean

    CheckBox5.Checked := False; // PVInit

    CheckBox6.Checked := False; // Y50 & Y100

    CheckBox7.Checked := False; // PDMean

    CheckBox8.Checked := False; // Precocity

    CheckBox9.Checked := False; // Maintenance

  end;

  procedure Calibration;

  var

    n: integer;

  begin

    // Initialisation des structures

    NVarDep := 0;

    if CheckBox1.Checked then

      Inc(NVarDep);

    if CheckBox2.Checked then

      Inc(NVarDep);

    if CheckBox3.Checked then

      Inc(NVarDep);

    if CheckBox4.Checked then

      Inc(NVarDep);

    NData := 0;

    if CheckBox1.Checked then

      NData := NData + Nb[1];

    if CheckBox2.Checked then

      NData := NData + Nb[2];

    if CheckBox3.Checked then

      NData := NData + Nb[3];

    if CheckBox4.Checked then

      NData := NData + Nb[4];

    NVar := 0;

    if CheckBox5.Checked then

      Inc(NVar);

    if CheckBox6.Checked then

      Inc(NVar, 2);

    if CheckBox7.Checked then

      Inc(NVar);

    if CheckBox8.Checked then

      Inc(NVar);

    if CheckBox9.Checked then

      Inc(NVar);

    DimVector(X, NVar);

    DimVector(G, NVar);

    DimMatrix(H_inv, NVar, NVar);

    n := 0;

    if CheckBox5.Checked then

    begin

      Inc(n);

      X[n] := PProfilP.PVInit;

    end;

    if CheckBox6.Checked then

    begin

      Inc(n);

      X[n] := CalcIngere(PProfilP.Equation, PProfilP.Unite, PProfilP.a, PProfilP.b, 50);

      Inc(n);

      X[n] := CalcIngere(PProfilP.Equation, PProfilP.Unite, PProfilP.a, PProfilP.b, 100);

    end;

    if CheckBox7.Checked then

    begin

      Inc(n);

      X[n] := PProfilP.PDMoy;

    end;

    if CheckBox8.Checked then

    begin

      Inc(n);

      X[n] := PProfilP.BGompertz;

    end;

    if CheckBox9.Checked then

    begin

      Inc(n);

      X[n] := PProfilP.Entretien;

    end;

    Marquardt(Func, HessGrad, X, 1, NVar, MaxIter, Tol, F_min, G, H_inv, Det);

    for n := 1 to NVar do

      Inv[n] := H_inv[n, n];

  end;

  // SBCalibrClick

begin

  if (ListAliment.Count = 0) or (ListSeqAliP.Count = 0) or

    (ListRationP.Count = 0) or (ListProfilP.Count = 0) then

  begin

    MessageDlg(

      'Choisir un dossier contenant au moins les aliments, s?quences alimentaires, plans de rationnement et profils !',

      mtWarning, [mbOK], 0);

    ActiveControl := JvDEFolder;

    Exit;

  end;

  if CBSeqAli1.ItemIndex = -1 then

  begin

    MessageDlg('S?lectionner une s?quence alimentaire !', mtWarning, [mbOK], 0);

    ActiveControl := CBSeqAli1;

    Exit;

  end;

  if CBRation1.ItemIndex = -1 then

  begin

    MessageDlg('S?lectionner un plan de rationnement !', mtWarning, [mbOK], 0);

    ActiveControl := CBRation1;

    Exit;

  end;

  // Calibrage

  Screen.Cursor := crHourGlass;

  MCalibr.Lines.Clear;

  AssignFile(Log, 'Calibr.log');

  Rewrite(Log);

  WriteLn(Log, 'Profil' + AnsiChar(#9) + 'R?(Feed)' + AnsiChar(#9) +

    'R?(Weight)' + AnsiChar(#9) + 'R?(Backfat)' + AnsiChar(#9) + 'R?(Lean)');

  Application.ProcessMessages;

  ASQLite3TableObserv.DisableControls;

  for profil := 0 to ListProfilP.Count - 1 do

  begin

    PProfilP := ListProfilP[profil];

    PSeqAliP := ListSeqAliP[FindIdxSeqAliP(CBSeqAli1.Text)];

    PProfilP.SeqAli := PSeqAliP.Num;

    PRationP := ListRationP[FindIdxRationP(CBRation1.Text)];

    PProfilP.Ration := PRationP.Num;

    ListRecCalibr := TList.Create;

    with ASQLite3TableObserv do

    begin

      Filter := Format('Profile = %d', [PProfilP.Num]);

      Filtered := True;

      Open;

      MCalibr.Lines.Add(Format('%s (%d/%d) : %d observations',

        [PProfilP.Nom, profil + 1, ListProfilP.Count, RecordCount]));

      Application.ProcessMessages;

      First;

      while not EOF do

      begin

        if (FieldByName('Line').AsInteger > 1) and not FieldByName('Feed').IsNull then

        begin

          Inc(Nb[1]);

          Tot[1] := Tot[1] + FieldByName('Feed').AsFloat;

          New(rec);

          rec.Age := FieldByName('Age').AsInteger;

          rec.Id  := 1;

          rec.Observ := FieldByName('Feed').AsFloat;

          ListRecCalibr.Add(rec);

        end;

        if not FieldByName('Weight').IsNull then

        begin

          Inc(Nb[2]);

          Tot[2] := Tot[2] + FieldByName('Weight').AsFloat;

          New(rec);

          rec.Age := FieldByName('Age').AsInteger;

          rec.Id  := 2;

          rec.Observ := FieldByName('Weight').AsFloat;

          ListRecCalibr.Add(rec);

        end;

        if not FieldByName('Backfat').IsNull then

        begin

          Inc(Nb[3]);

          Tot[3] := Tot[3] + FieldByName('Backfat').AsFloat;

          New(rec);

          rec.Age := FieldByName('Age').AsInteger;

          rec.Id  := 3;

          rec.Observ := FieldByName('Backfat').AsFloat;

          ListRecCalibr.Add(rec);

        end;

        if not FieldByName('Lean').IsNull then

        begin

          Inc(Nb[4]);

          Tot[4] := Tot[4] + FieldByName('Lean').AsFloat;

          New(rec);

          rec.Age := FieldByName('Age').AsInteger;

          rec.Id  := 4;

          rec.Observ := FieldByName('Lean').AsFloat;

          ListRecCalibr.Add(rec);

        end;

        Next;

      end;

      Close;

    end;

    // Moyennes observations

    for i := 1 to 4 do

      if Nb[i] <> 0 then

        M[i] := Tot[i] / Nb[i];

    // Pond?rations observations

    for i := 1 to 4 do

      if M[i] <> 0 then

        w[i] := 1 / (Nb[i] * Power(M[i], 2));

    // R?ajustement des pond?rations en fonction de la pond?ration totale

    wTot := 0;

    for i := 1 to 4 do

      wTot := wTot + w[i];

    for i := 1 to 4 do

      w[i] := w[i] / wTot;

    New(PResSimulP);

    // Cycle 1 : Feed -> Y50 + Y100

    Uncheck;

    CheckBox1.Checked := True; // Feed

    CheckBox6.Checked := True; // Y50 & Y100

    Calibration;

    // Cycle 2 : Weight -> PVInit + PDMean

    Uncheck;

    CheckBox2.Checked := True; // Weight

    CheckBox5.Checked := True; // PVInit

    CheckBox7.Checked := True; // PDMean

    // Cycle 3 : Feed + Weight -> PVInit + Y50 + Y100 + PDMean

    CheckBox1.Checked := True; // Feed

    CheckBox6.Checked := True; // Y50 & Y100

    Calibration;

    // Cycle 4 : Weight -> PVInit + PDMean + Precocity

    Uncheck;

    CheckBox2.Checked := True; // Weight

    CheckBox5.Checked := True; // PVInit

    CheckBox7.Checked := True; // PDMean

    CheckBox8.Checked := True; // Precocity

    Calibration;

    // Cycle 5 : Feed + Weight -> PVInit + Y50 + Y100 + PDMean + Precocity

    CheckBox1.Checked := True; // Feed

    CheckBox6.Checked := True; // Y50 & Y100

    Calibration;

    if PProfilP.ModeFin = 0 then // Dur?e

      PProfilP.PVFin := PResSimulP.TabResult[2, PResSimulP.NbJSim] +

        PResSimulP.TabResult[84, PResSimulP.NbJSim];

    Dispose(PResSimulP);

    // Calcul des statistiques

    for i := 1 to 4 do

    begin

      SSt[i] := 0;

      SSr[i] := 0;

    end;

    for i := 0 to ListRecCalibr.Count - 1 do

    begin

      rec := ListRecCalibr[i];

      case rec.Id of

        1: // Feed

          if CheckBox1.Checked then

          begin

            SSt[1] := SSt[1] + Power(rec.Observ - M[1], 2);

            SSr[1] := SSr[1] + Power(rec.Observ - rec.Predict, 2);

          end;

        2: // Weight

          if CheckBox2.Checked then

          begin

            SSt[2] := SSt[2] + Power(rec.Observ - M[2], 2);

            SSr[2] := SSr[2] + Power(rec.Observ - rec.Predict, 2);

          end;

        3: // Backfat

          if CheckBox3.Checked then

          begin

            SSt[3] := SSt[3] + Power(rec.Observ - M[3], 2);

            SSr[3] := SSr[3] + Power(rec.Observ - rec.Predict, 2);

          end;

        4: // Lean

          if CheckBox4.Checked then

          begin

            SSt[4] := SSt[4] + Power(rec.Observ - M[4], 2);

            SSr[4] := SSr[4] + Power(rec.Observ - rec.Predict, 2);

          end;

      end;

    end;

    // Enregistrement des statistiques

    Write(Log, PProfilP.Nom + AnsiChar(#9));

    if SSt[1] <> 0 then

      Write(Log, Format('%1.2f %%', [100 - SSr[1] / SSt[1] * 100]));

    Write(Log, AnsiChar(#9));

    if SSt[2] <> 0 then

      Write(Log, Format('%1.2f %%', [100 - SSr[2] / SSt[2] * 100]));

    Write(Log, AnsiChar(#9));

    if SSt[3] <> 0 then

      Write(Log, Format('%1.2f %%', [100 - SSr[3] / SSt[3] * 100]));

    Write(Log, AnsiChar(#9));

    if SSt[4] <> 0 then

      Write(Log, Format('%1.2f %%', [100 - SSr[4] / SSt[4] * 100]));

    WriteLn(Log);

    if ListRecCalibr.Count > 0 then

      for i := 0 to ListRecCalibr.Count - 1 do

      begin

        rec := ListRecCalibr[i];

        Dispose(rec);

      end;

    ListRecCalibr.Free;

  end;

  ASQLite3TableObserv.EnableControls;

  ASQLite3DBInraPorc.Close;

  CloseFile(Log);

  SaveProfilP;

  Screen.Cursor := crDefault;

end;

// Onglet Graphique

procedure TFLudo.CBProfilChange(Sender: TObject);

var

  jour: integer;

  cumul, x, y: double;

begin

  LineFeed.Clear;

  LineWeight.Clear;

  PointFeed.Clear;

  PointWeight.Clear;

  if CBProfil.ItemIndex = -1 then

    Exit;

  PProfilP := ListProfilP[FindIdxProfilP(CBProfil.Text)];

  EPVInit.Text := FloatToStrF(PProfilP.PVInit, ffFixed, 15, 1);

  if (PProfilP.Unite = 0) or (PProfilP.Unite = 4) then // kg (QI ou MS)

  begin

    EY50.Text  := FloatToStrF(CalcIngere(PProfilP.Equation, PProfilP.Unite,

      PProfilP.a, PProfilP.b, 50), ffFixed, 15, 3);

    EY100.Text := FloatToStrF(CalcIngere(PProfilP.Equation, PProfilP.Unite,

      PProfilP.a, PProfilP.b, 100), ffFixed, 15, 3);

  end

  else // MJ (ED, EM ou EN)

  begin

    EY50.Text  := FloatToStrF(CalcIngere(PProfilP.Equation, PProfilP.Unite,

      PProfilP.a, PProfilP.b, 50), ffFixed, 15, 2);

    EY100.Text := FloatToStrF(CalcIngere(PProfilP.Equation, PProfilP.Unite,

      PProfilP.a, PProfilP.b, 100), ffFixed, 15, 2);

  end;

  EPDMoy.Text := FloatToStrF(PProfilP.PDMoy, ffFixed, 15, 2);

  EPrecocite.Text := FloatToStrF(PProfilP.BGompertz, ffFixed, 15, 5);

  EEntretien.Text := FloatToStrF(PProfilP.Entretien, ffFixed, 15, 3);

  with ASQLite3TableObserv do

  begin

    Filter := Format('Profile = %d', [PProfilP.Num]);

    Filtered := True;

    Open;

    DisableControls;

    First;

    while not EOF do

    begin

      x := FieldByName('Age').AsInteger;

      if (FieldByName('Line').AsInteger > 1) and not FieldByName('Feed').IsNull then

      begin

        y := FieldByName('Feed').AsFloat;

        PointFeed.AddXY(x, y, '', clTeeColor);

      end;

      if not FieldByName('Weight').IsNull then

      begin

        y := FieldByName('Weight').AsFloat;

        PointWeight.AddXY(x, y, '', clTeeColor);

      end;

      Next;

    end;

    EnableControls;

  end;

  ASQLite3DBInraPorc.Close;

  if (PProfilP.SeqAli = -1) or (PProfilP.Ration = -1) then

    Exit;

  New(PResSimulP);

  CalcSimulP(-1, PProfilP.Num, PProfilP.SeqAli, PProfilP.Ration, -1, 1, PResSimulP, FLudo.CBAALimitGraph.Checked);

  cumul := 0;

  for jour := 1 to PResSimulP.NbJSim do

  begin

    x := PResSimulP.TabResult[1, jour];

    y := PResSimulP.TabResult[2, jour];

    LineFeed.AddXY(x, cumul, '', clTeeColor);

    LineWeight.AddXY(x, y, '', clTeeColor);

    cumul := cumul + PResSimulP.TabResult[113, jour];

  end;

  Dispose(PResSimulP);

end;

// Onglet Simulation

procedure TFLudo.CheckBoxProfilClick(Sender: TObject);

begin

  RadioButtonDuree.Enabled := not CheckBoxProfil.Checked;

  JvValidateEditDuree.Enabled  := not CheckBoxProfil.Checked;

  RadioButtonPVFin.Enabled := not CheckBoxProfil.Checked;

  JvValidateEditPVFin.Enabled  := not CheckBoxProfil.Checked;

end;

procedure TFLudo.SBSimulClick(Sender: TObject);

var

  i, j, k:  integer;

  Aliment1, Aliment2: integer;

  CC1, CC2: CompositionChimique;

  IngereFrais, Distrib, Gaspillage: double;

  IngereSec1, IngereSec2, Taux1, Taux2: double;

  Ptot, Ptot1, Ptot2, Pdig, Pdig1, Pdig2: double;

  Ingere, Digestible, Depose: double;

  PV, PVV, PVfin, PVVfin, GMQ, PD, LD, p, l: double;

  CumulIngere, CumulDistrib, Cout: double;

begin

  if (ListAliment.Count = 0) or (ListSeqAliP.Count = 0) or

    (ListRationP.Count = 0) or (ListProfilP.Count = 0) then

  begin

    MessageDlg(

      'Choisir un dossier contenant au moins les aliments, s?quences alimentaires, plans de rationnement et profils !',

      mtWarning, [mbOK], 0);

    ActiveControl := JvDEFolder;

    Exit;

  end;

  if CBSeqAli2.ItemIndex = -1 then

  begin

    MessageDlg('S?lectionner une s?quence alimentaire !', mtWarning, [mbOK], 0);

    ActiveControl := CBSeqAli2;

    Exit;

  end;

  if CBRation2.ItemIndex = -1 then

  begin

    MessageDlg('S?lectionner un plan de rationnement !', mtWarning, [mbOK], 0);

    ActiveControl := CBRation2;

    Exit;

  end;

  if JvFEResult.Text = '' then

  begin

    MessageDlg('Indiquer un nom de fichier pour les r?sultats d?taill?s !',

      mtError, [mbOK], 0);

    ActiveControl := JvFEResult;

    Exit;

  end;

  if JvFEBilan.Text = '' then

  begin

    MessageDlg('Indiquer un nom de fichier pour le bilan !', mtError, [mbOK], 0);

    ActiveControl := JvFEBilan;

    Exit;

  end;

  if FileExists(JvFEResult.Text) then

    if MessageDlg(Format('Le fichier %s existe d?j? !' + sLineBreak +

      'Faut-il l''?craser ?', [JvFEResult.Text]), mtConfirmation, [mbYes, mbNo], 0) =

      mrYes then

      DeleteFile(JvFEResult.Text)

    else

      Exit;

  if FileExists(JvFEBilan.Text) then

    if MessageDlg(Format('Le fichier %s existe d?j? !' + sLineBreak +

      'Faut-il l''?craser ?', [JvFEBilan.Text]), mtConfirmation, [mbYes, mbNo], 0) =

      mrYes then

      DeleteFile(JvFEBilan.Text)

    else

      Exit;

  // Simulation

  Screen.Cursor := crHourGlass;

  MSimul.Lines.Clear;

  Application.ProcessMessages;

  JvCsvDSResult.FileName := JvFEResult.Text;

  JvCsvDSResult.Active := True;

  JvCsvDSBilan.FileName := JvFEBilan.Text;

  JvCsvDSBilan.Active := True;

  for i := 0 to ListProfilP.Count - 1 do

  begin

    PProfilP := ListProfilP[i];

    PSeqAliP := ListSeqAliP[FindIdxSeqAliP(CBSeqAli2.Text)];

    PRationP := ListRationP[FindIdxRationP(CBRation2.Text)];

    New(PSimulP);

    with PSimulP^ do

    begin

      Num := PProfilP.Num;

      Nom := PProfilP.Nom;

      Application.ProcessMessages;

      Memo := '';

      Profil := PProfilP.Num;

      SeqAli := PSeqAliP.Num;

      Ration := PRationP.Num;

      AgeInitProfil := True;

      PVInitProfil := True;

      ProtLipInitProfil := True;

      AgeInit := 0;

      PVInit := 0;

      ProtInit := 0;

      LipInit := 0;

      FinProfil := CheckBoxProfil.Checked;

      if RadioButtonDuree.Checked then

        ModeFin := 0

      else

        ModeFin := 1;

      Duree := JvValidateEditDuree.AsInteger;

      PVFin := JvValidateEditPVFin.AsFloat;

    end;

    ListSimulP.Add(PSimulP);

    New(PResSimulP);

    try

      CalcSimulP(PSimulP.Num, PSimulP.Profil, PSimulP.SeqAli, PSimulP.Ration, -1, 1, PResSimulP, FLudo.CBAALimitSimul.Checked);

    finally

      MSimul.Lines.Add(Format('%s (%d/%d) : %d jours',

        [PSimulP.Nom, i + 1, ListProfilP.Count, PResSimulP.NbJSim]));

      Application.ProcessMessages;

    end;

    CumulIngere := 0;

    CumulDistrib := 0;

    Cout := 0;

    for j := 1 to PResSimulP.NbJSim do

      with JvCsvDSResult do

      begin

        PV := PResSimulP.TabResult[2, j];

        PVV := CalcPVV(PV);

        PVfin := PResSimulP.TabResult[83, j];

        PVVfin := CalcPVV(PVfin);

        GMQ := PResSimulP.TabResult[84, j];

        PD := PResSimulP.TabResult[79, j];

        LD := PResSimulP.TabResult[80, j];

        p := PResSimulP.TabResult[49, j];

        l := PResSimulP.TabResult[50, j];

        // Composition des aliments

        IngereFrais := PresSimulP.TabResult[11, j];

        Distrib := PresSimulP.TabResult[113, j];

        Gaspillage := PResSimulP.TabResult[112, j];

        // Aliment 1

        Aliment1 := Trunc(PresSimulP.TabResult[7, j]);

        if Aliment1 = -1 then

          CC1 := CCVide

        else

        begin

          PAliment := ListAliment[FindIdxAliment(FindNomAliment(Aliment1))];

          CC1 := PAliment.CC;

        end;

        Taux1 := PresSimulP.TabResult[9, j] / 100;

        IngereSec1 := IngereFrais * Taux1 * CC1.MS / 1000;

        Ptot1 := IngereSec1 * CC1.P;

        if Aliment1 = -1 then

          Pdig1 := 0

        else

        if PAliment.Presentation = 0 then // Granul?s

          Pdig1 := IngereSec1 * PAliment.CC.PdigG

        else // Farine

          Pdig1 := IngereSec1 * PAliment.CC.PdigF;

        // Aliment 2

        Aliment2 := Trunc(PresSimulP.TabResult[8, j]);

        if Aliment2 = -1 then

          CC2 := CCVide

        else

        begin

          PAliment := ListAliment[FindIdxAliment(FindNomAliment(Aliment2))];

          CC2 := PAliment.CC;

        end;

        Taux2 := PresSimulP.TabResult[10, j] / 100;

        IngereSec2 := IngereFrais * Taux2 * CC2.MS / 1000;

        Ptot2 := IngereSec2 * CC2.P;

        if Aliment2 = -1 then

          Pdig2 := 0

        else

        if PAliment.Presentation = 0 then // Granul?s

          Pdig2 := IngereSec2 * PAliment.CC.PdigG

        else // Farine

          Pdig2 := IngereSec2 * PAliment.CC.PdigF;

        // Cumul

        Ptot := Ptot1 + Ptot2;

        Pdig := Pdig1 + Pdig2;

        // R?sultats d?taill?s

        Append;

        Fields[0].AsAnsiString := PProfilP.Nom;

        Fields[1].AsInteger := Trunc(PResSimulP.TabResult[1, j]);

        Fields[2].AsFloat  := PV;

        Fields[3].AsAnsiString := PSeqAliP.Nom;

        Fields[4].AsAnsiString := PRationP.Nom;

        Fields[5].AsInteger := Aliment1;

        Fields[6].AsInteger := Aliment2;

        Fields[7].AsFloat  := Taux1 * 100;

        Fields[8].AsFloat  := Taux2 * 100;

        Fields[9].AsFloat  := Distrib;

        Fields[10].AsFloat := IngereFrais;

        Fields[11].AsFloat := PResSimulP.TabResult[78, j];

        Fields[12].AsFloat := PResSimulP.TabResult[106, j];

        Fields[13].AsFloat := p;

        Fields[14].AsFloat := l;

        Fields[15].AsFloat := PD;

        Fields[16].AsFloat := LD;

        Fields[17].AsFloat := GMQ;

        if PResSimulP.TabResult[84, j] <> 0 then

          Fields[18].AsFloat := Distrib / GMQ;

        Fields[19].AsFloat := CalcP2(l);

        Fields[20].AsFloat := CalcTMP(PVV, p, l);

        Fields[21].AsFloat := CalcRC(PResSimulP.TabResult[2, PResSimulP.NbJSim],

          CalcRCStd(PProfilP.PVFin, PProfilP.Carcasse), PV) * 100;

        Fields[22].AsFloat := PResSimulP.TabResult[90, j] * IngereFrais;

        // Apport total AA

        for k := 0 to 12 do

          Fields[23 + k].AsFloat := PResSimulP.TabResult[93 + k, j];

        // Apport digestible AA

        for k := 0 to 12 do

          Fields[36 + k].AsFloat := PResSimulP.TabResult[19 + k, j];

        // Besoin AA

        for k := 0 to 12 do