InraPorc

unit UFCalibrProfilP;

interface

uses

  Windows, Forms, Classes, Controls, StdCtrls, Dialogs, Buttons, ExtCtrls,

  Chart, Series, TeEngine, TeeProcs, JvEnterTab, JvExControls, PBNumEdit,

  PBSuperSpin;

type

  TFCalibrProfilP = class(TForm)

    BBOk: TBitBtn;

    BBCancel: TBitBtn;

    SBCalibrage: TSpeedButton;

    CBMethod: TComboBox;

    Graph: TChart;

    GBResults: TGroupBox;

    PGraphTop: TPanel;

    GBGraphRight: TGroupBox;

    CBGraphRight: TComboBox;

    GBGraphLeft: TGroupBox;

    CBGraphLeft: TComboBox;

    LineLeft: TLineSeries;

    LineRight: TLineSeries;

    PointLeft: TLineSeries;

    PointRight: TLineSeries;

    GBParam: TGroupBox;

    LY50: TLabel;

    LY100: TLabel;

    LFinal: TLabel;

    LInitial: TLabel;

    LMeanPD: TLabel;

    LSD: TLabel;

    EY50Final: TEdit;

    ESDY50: TEdit;

    EY100Final: TEdit;

    ESDY100: TEdit;

    EMeanPDFinal: TEdit;

    ESDMeanPD: TEdit;

    GBVariables: TGroupBox;

    LBackfat: TLabel;

    LWeight: TLabel;

    LR2: TLabel;

    LRSD: TLabel;

    LVar: TLabel;

    Lw: TLabel;

    ERSDBackfat: TEdit;

    ERSDWeight: TEdit;

    ER2Weight: TEdit;

    ER2Backfat: TEdit;

    EwRSSWeight: TEdit;

    EwRSSBackfat: TEdit;

    EwBackfat: TEdit;

    EwWeight: TEdit;

    LFeed: TLabel;

    LLean: TLabel;

    ERSDFeed: TEdit;

    ERSDLean: TEdit;

    ER2Lean: TEdit;

    ER2Feed: TEdit;

    EwRSSLean: TEdit;

    EwRSSFeed: TEdit;

    EwFeed: TEdit;

    EwLean: TEdit;

    PButtons: TPanel;

    LMethod: TLabel;

    LPrecocity: TLabel;

    LMaintenance: TLabel;

    EPrecocityFinal: TEdit;

    ESDPrecocity: TEdit;

    EMaintenanceFinal: TEdit;

    ESDMaintenance: TEdit;

    LTime: TLabel;

    ETime: TEdit;

    PBIng50: TPBSuperSpin;

    PBIng100: TPBSuperSpin;

    PBMeanPD: TPBSuperSpin;

    PBPrecocity: TPBSuperSpin;

    PBMaintenance: TPBSuperSpin;

    PLeft: TPanel;

    PSummary: TPanel;

    EY50Initial: TEdit;

    EY100Initial: TEdit;

    EMeanPDInitial: TEdit;

    EPrecocityInitial: TEdit;

    EMaintenanceInitial: TEdit;

    PRight: TPanel;

    GBParameters: TGroupBox;

    LEntretien: TLabel;

    LComport: TLabel;

    LPDMoy: TLabel;

    LIng100: TLabel;

    LIng50: TLabel;

    LInfo: TLabel;

    JvEnterAsTab1: TJvEnterAsTab;

    PBwFeed: TPBNumEdit;

    PBwWeight: TPBNumEdit;

    PBwBackfat: TPBNumEdit;

    PBwLean: TPBNumEdit;

    RBStandard: TRadioButton;

    RBExpert: TRadioButton;

    CheckBox6: TCheckBox;

    CheckBox7: TCheckBox;

    CheckBox8: TCheckBox;

    CheckBox9: TCheckBox;

    CheckBox10: TCheckBox;

    CheckBox1: TCheckBox;

    CheckBox2: TCheckBox;

    CheckBox3: TCheckBox;

    CheckBox4: TCheckBox;

    BBReset: TBitBtn;

    LPVInit: TLabel;

    PBPVInit: TPBSuperSpin;

    LInitBW: TLabel;

    EInitBWFinal: TEdit;

    ESDInitBW: TEdit;

    EInitBWInitial: TEdit;

    CheckBox5: TCheckBox;

    CBAALimit: TCheckBox;

    procedure FormCreate(Sender: TObject);

    procedure FormDestroy(Sender: TObject);

    procedure FormShow(Sender: TObject);

    procedure FormClose(Sender: TObject; var Action: TCloseAction);

    procedure CBGraphLeftChange(Sender: TObject);

    procedure CBGraphRightChange(Sender: TObject);

    procedure SBCalibrageClick(Sender: TObject);

    procedure PBwFeedChange(Sender: TObject);

    procedure PBwWeightChange(Sender: TObject);

    procedure PBwBackfatChange(Sender: TObject);

    procedure PBwLeanChange(Sender: TObject);

    procedure PBIng50Change(Sender: TObject);

    procedure PBIng100Change(Sender: TObject);

    procedure PBMeanPDChange(Sender: TObject);

    procedure PBPrecocityChange(Sender: TObject);

    procedure PBMaintenanceChange(Sender: TObject);

    procedure RBStandardClick(Sender: TObject);

    procedure RBExpertClick(Sender: TObject);

    procedure BBResetClick(Sender: TObject);

    procedure PBPVInitChange(Sender: TObject);

  private

    { D?clarations priv?es }

    procedure Calibration;

    procedure Uncheck;

  public

    { D?clarations publiques }

  end;

var

  FCalibrProfilP: TFCalibrProfilP;

implementation

uses

  SysUtils, gnugettext, dmath, UVariables, UStrings, UInit, UCalcul, UFindRec,

  UEchelle, UFProfilP, UCalcSimulP;

{$R *.dfm}

{ Calibration }

const

  MaxIter = 100;

  Tol = MICRO;

type

  RecCalibr = record

    Age: Integer;

    Id: Integer; // 1=Feed, 2=Weight, 3=Backfat, 4=Lean

    Observ: Extended;

    Predict: Extended;

  end;

  PRecCalibr = ^RecCalibr;

var

  MiseAJour, PDLimit: boolean;

  PProfilTempo: PRecProfilP;

  IdxProfilTempo: Integer;

  PResSimulTempo: PTabResSimulP;

  ListRecCalibr: TList;

  NVar, NVarDep, NData: Integer;

  X, G: TVector;

  H_inv: TMatrix;

  F_min, Det: Float;

  Inv: array[1..6] of Float;

  Freq, Start, Stop: Int64;

  Nb: array[1..4] of Integer;

  Tot, M, w, SSt, SSr, wSSr: array[1..4] of Double;

  wSSrTot: Double;

function Func(X: TVector): Float;

var

  i, jour: Integer;

  Y50, Y100, cumul: Double;

  rec: PRecCalibr;

begin

  i := 0;

  if FCalibrProfilP.CheckBox5.Checked

  then

  begin

    Inc(i);

    if X[i] <= 0

    then // Protection rajout?e le 27/07/2011

      PProfilTempo.PVInit := MILLI

    else

      PProfilTempo.PVInit := X[i];

    // Recalculer les poids initiaux de prot?ines et lipides

    PProfilTempo.ProtInit := CalcProt(PProfilTempo.PVInit);

    PProfilTempo.LipInit := CalcLipProt(PProfilTempo.PVInit, PProfilTempo.ProtInit);

  end;

  if FCalibrProfilP.CheckBox6.Checked

  then

  begin

    Inc(i);

    Y50 := X[i];

  end

  else

    Y50 := FCalibrProfilP.PBIng50.AsFloat;

  if FCalibrProfilP.CheckBox7.Checked

  then

  begin

    Inc(i);

    Y100 := X[i];

  end

  else

    Y100 := FCalibrProfilP.PBIng100.AsFloat;

  if FCalibrProfilP.CheckBox8.Checked

  then

  begin

    Inc(i);

    if X[i] <= 0

    then // Protection rajout?e le 27/07/2011

      PProfilTempo.PDMoy := MILLI

    else

      PProfilTempo.PDMoy := X[i];

  end;

  if FCalibrProfilP.CheckBox9.Checked

  then

  begin

    Inc(i);

    if X[i] <= 0

    then // Protection rajout?e le 27/07/2011

      PProfilTempo.BGompertz := MILLI

    else

      PProfilTempo.BGompertz := X[i];

  end;

  if FCalibrProfilP.CheckBox10.Checked

  then

  begin

    Inc(i);

    if X[i] <= 0

    then // Protection rajout?e le 27/07/2011

      PProfilTempo.Entretien := MILLI

    else

      PProfilTempo.Entretien := X[i];

  end;

  with PProfilTempo^ do

    try

      CalcCoef(Equation, Unite, Y50, Y100, a, b);

    except

      a := 0;

      b := 0;

    end;

  // Valeur des param?tres du cas ?valu?

  MiseAJour := True;

  FCalibrProfilP.PBPVInit.AsFloat := PProfilTempo.PVInit;

  FCalibrProfilP.PBIng50.AsFloat := Y50;

  FCalibrProfilP.PBIng100.AsFloat := Y100;

  FCalibrProfilP.PBMeanPD.AsFloat := PProfilTempo.PDMoy;

  FCalibrProfilP.PBPrecocity.AsFloat := PProfilTempo.BGompertz;

  FCalibrProfilP.PBMaintenance.AsFloat := PProfilTempo.Entretien;

  MiseAJour := False;

  try

    // Affichage de la simulation

    CalcSimulP(-1, PProfilTempo.Num, PProfilTempo.SeqAli, PProfilTempo.Ration, -1, 1, PResSimulTempo, FCalibrProfilP.CBAALimit.Checked);

    {

    // Affichage des graphiques

    FCalibrProfilP.CBGraphLeftChange(nil);

    FCalibrProfilP.CBGraphRightChange(nil);

    Application.ProcessMessages;

    }

  except // La simulation a ?chou?

    for i := 0 to ListRecCalibr.Count - 1 do

    begin

      rec := ListRecCalibr[i];

      rec.Predict := 0;

    end;

  end;

  // Evaluation du cas

  PDLimit := False;

  i := 0;

  rec := ListRecCalibr[i];

  cumul := 0;

  for jour := 1 to PResSimulTempo.NbJSim do

  begin

    while (i < ListRecCalibr.Count) and (PResSimulTempo.TabResult[1, jour] = rec.Age) do

    begin

      case rec.Id of

        1: // Feed

          rec.Predict := cumul;

        2: // Weight

          rec.Predict := PResSimulTempo.TabResult[2, jour];

        3: // Backfat

          if FatInfo = 0

          then // P2

            rec.Predict := CalcP2(PResSimulTempo.TabResult[50, jour])

          else // User defined

            rec.Predict := CalcUserFat(PResSimulTempo.TabResult[48, jour], PResSimulTempo.TabResult[49, jour], PResSimulTempo.TabResult[50, jour]);

        4: // Lean

          if LeanInfo = 0

          then // TMP

            rec.Predict := CalcTMP(PResSimulTempo.TabResult[48, jour], PResSimulTempo.TabResult[49, jour], PResSimulTempo.TabResult[50, jour])

          else // User defined

            rec.Predict := CalcUserLean(PResSimulTempo.TabResult[48, jour], PResSimulTempo.TabResult[49, jour], PResSimulTempo.TabResult[50, jour]);

      end;

      Inc(i);

      if i < ListRecCalibr.Count then rec := ListRecCalibr[i];

    end;

    cumul := cumul + PResSimulTempo.TabResult[113, jour];

    if PResSimulTempo.TabResult[47, jour] < PResSimulTempo.TabResult[77, jour] / GEProtJaap

    then // PDFirstLimit < PD potentiel

      PDLimit := True;

  end;

  // Ecart par rapport aux valeurs du profil

  Result := 0;

  for i := 0 to ListRecCalibr.Count - 1 do

  begin

    rec := ListRecCalibr[i];

    case rec.Id of

      1: // Feed

        if FCalibrProfilP.CheckBox1.Checked

        then

          Result := Result + w[1] * Power(rec.Observ - rec.Predict, 2);

      2: // Weight

        if FCalibrProfilP.CheckBox2.Checked

        then

          Result := Result + w[2] * Power(rec.Observ - rec.Predict, 2);

      3: // Backfat

        if FCalibrProfilP.CheckBox3.Checked

        then

          Result := Result + w[3] * Power(rec.Observ - rec.Predict, 2);

      4: // Lean

        if FCalibrProfilP.CheckBox4.Checked

        then

          Result := Result + w[4] * Power(rec.Observ - rec.Predict, 2);

    end;

  end;

end;

// Newton-Raphson method

// procedure HessGrad to compute the gradient G and the hessian H of the function at point X

{$I numhess.inc}

// Broyden-Fletcher-Goldfarb-Shanno method

// procedure Gradient to compute the gradient G of the function at point X

{$I numgrad.inc}

{ TFCalibrProfilP }

procedure TFCalibrProfilP.BBResetClick(Sender: TObject);

begin

  FormShow(Sender);

  BBOk.Enabled := False;

end;

procedure TFCalibrProfilP.Calibration;

var

  i: Integer;

begin

  // Initialisation des structures

  NVarDep := 0;

  if CheckBox1.Checked then Inc(NVarDep);

  if CheckBox2.Checked then Inc(NVarDep);

  if CheckBox3.Checked then Inc(NVarDep);

  if CheckBox4.Checked then Inc(NVarDep);

  NData := 0;

  if CheckBox1.Checked then NData := NData + Nb[1];

  if CheckBox2.Checked then NData := NData + Nb[2];

  if CheckBox3.Checked then NData := NData + Nb[3];

  if CheckBox4.Checked then NData := NData + Nb[4];

  NVar := 0;

  if CheckBox5.Checked then Inc(NVar);

  if CheckBox6.Checked then Inc(NVar);

  if CheckBox7.Checked then Inc(NVar);

  if CheckBox8.Checked then Inc(NVar);

  if CheckBox9.Checked then Inc(NVar);

  if CheckBox10.Checked then Inc(NVar);

  DimVector(X, NVar);

  DimVector(G, NVar);

  DimMatrix(H_inv, NVar, NVar);

  i := 0;

  if CheckBox5.Checked

  then

  begin

    Inc(i);

    X[i] := PBPVInit.AsFloat;

  end;

  if CheckBox6.Checked

  then

  begin

    Inc(i);

    X[i] := PBIng50.AsFloat;

  end;

  if CheckBox7.Checked

  then

  begin

    Inc(i);

    X[i] := PBIng100.AsFloat;

  end;

  if CheckBox8.Checked

  then

  begin

    Inc(i);

    X[i] := PBMeanPD.AsFloat;

  end;

  if CheckBox9.Checked

  then

  begin

    Inc(i);

    X[i] := PBPrecocity.AsFloat;

  end;

  if CheckBox10.Checked

  then

  begin

    Inc(i);

    X[i] := PBMaintenance.AsFloat;

  end;

  case CBMethod.ItemIndex of

    0: Newton(Func, HessGrad, X, 1, NVar, MaxIter, Tol, F_min, G, H_inv, Det);

    1: Marquardt(Func, HessGrad, X, 1, NVar, MaxIter, Tol, F_min, G, H_inv, Det);

    2: BFGS(Func, Gradient, X, 1, NVar, MaxIter, Tol, F_min, G, H_inv);

  end;

  for i := 1 to NVar do

    Inv[i] := H_inv[i, i];

end;

procedure TFCalibrProfilP.CBGraphLeftChange(Sender: TObject);

var

  jour, i: Integer;

  cumul, x, y: Double;

  rec: PRecCalibr;

begin

  Graph.LeftAxis.Title.Caption := CBGraphLeft.Text;

  // Ligne

  LineLeft.Clear;

  cumul := 0;

  for jour := 1 to PResSimulTempo.NbJSim do

  begin

    x := PResSimulTempo.TabResult[1, jour];

    case CBGraphLeft.ItemIndex of

      0: // Cumulative feed usage

      begin

        y := cumul;

        cumul := cumul + PResSimulTempo.TabResult[113, jour];

      end;

      1: // Body weight

        y := PResSimulTempo.TabResult[2, jour];

      2: // Backfat thickness

        if FatInfo = 0

        then // P2

          y := CalcP2(PResSimulTempo.TabResult[50, jour])

        else // User defined

          y := CalcUserFat(PResSimulTempo.TabResult[48, jour], PResSimulTempo.TabResult[49, jour], PResSimulTempo.TabResult[50, jour]);

      3: // Lean meat percentage

        if LeanInfo = 0

        then // TMP

          y := CalcTMP(PResSimulTempo.TabResult[48, jour], PResSimulTempo.TabResult[49, jour], PResSimulTempo.TabResult[50, jour])

        else // User defined

          y := CalcUserLean(PResSimulTempo.TabResult[48, jour], PResSimulTempo.TabResult[49, jour], PResSimulTempo.TabResult[50, jour]);

      else

        y := 0;

    end;

    LineLeft.AddXY(x, y, '', clTeeColor);

  end;

  // Points

  PointLeft.Clear;

  for i := 0 to ListRecCalibr.Count - 1 do

  begin

    rec := ListRecCalibr[i];

    if rec.Id = CBGraphLeft.ItemIndex + 1

    then

    begin

      x := rec.Age;

      y := rec.Observ;

      PointLeft.AddXY(x, y, '', clTeeColor);

    end;

  end;

  AjustEchelle(Graph);

end;

procedure TFCalibrProfilP.CBGraphRightChange(Sender: TObject);

var

  jour, i: Integer;

  cumul, x, y: Double;

  rec: PRecCalibr;

begin

  Graph.RightAxis.Title.Caption := CBGraphRight.Text;

  // Ligne

  LineRight.Clear;

  cumul := 0;

  for jour := 1 to PResSimulTempo.NbJSim do

  begin

    x := PResSimulTempo.TabResult[1, jour];

    case CBGraphRight.ItemIndex of

      0: // Cumulative feed usage

      begin

        y := cumul;

        cumul := cumul + PResSimulTempo.TabResult[113, jour];

      end;

      1: // Body weight

        y := PResSimulTempo.TabResult[2, jour];

      2: // Backfat thickness

        if FatInfo = 0

        then // P2

          y := CalcP2(PResSimulTempo.TabResult[50, jour])

        else // User defined

          y := CalcUserFat(PResSimulTempo.TabResult[48, jour], PResSimulTempo.TabResult[49, jour], PResSimulTempo.TabResult[50, jour]);

      3: // Lean meat percentage

        if LeanInfo = 0

        then // TMP

          y := CalcTMP(PResSimulTempo.TabResult[48, jour], PResSimulTempo.TabResult[49, jour], PResSimulTempo.TabResult[50, jour])

        else // User defined

          y := CalcUserLean(PResSimulTempo.TabResult[48, jour], PResSimulTempo.TabResult[49, jour], PResSimulTempo.TabResult[50, jour]);

      else

        y := 0;

    end;

    LineRight.AddXY(x, y, '', clTeeColor);

  end;

  // Points

  PointRight.Clear;

  for i := 0 to ListRecCalibr.Count - 1 do

  begin

    rec := ListRecCalibr[i];

    if rec.Id = CBGraphRight.ItemIndex + 1

    then

    begin

      x := rec.Age;

      y := rec.Observ;

      PointRight.AddXY(x, y, '', clTeeColor);

    end;

  end;

  AjustEchelle(Graph);

end;

procedure TFCalibrProfilP.FormClose(Sender: TObject; var Action: TCloseAction);

begin

  PProfilP := ListProfilP[FindIdxProfilP(FProfilP.CBProfil.Text)];

  if ModalResult = mrOk

  then // Conserver les modification

  begin

    PProfilP.AgeInit := PProfilTempo.AgeInit;

    PProfilP.PVInit := PProfilTempo.PVInit;

    PProfilP.ProtInit := PProfilTempo.ProtInit;

    PProfilP.LipInit := PProfilTempo.LipInit;

    PProfilP.ModeFin := 0; // Dur?e

    PProfilP.Duree := PProfilTempo.Duree;

    PProfilP.a := PProfilTempo.a;

    PProfilP.b := PProfilTempo.b;

    PProfilP.PDMoy := PProfilTempo.PDMoy;

    PProfilP.BGompertz := PProfilTempo.BGompertz;

    PProfilP.Entretien := PProfilTempo.Entretien;

  end;

end;

procedure TFCalibrProfilP.FormCreate(Sender: TObject);

begin

  if Screen.Fonts.IndexOf('Arial Unicode MS') <> -1

  then

    Font.Name := 'Arial Unicode MS';

  TranslateComponent(Self);

  CBGraphLeft.ItemIndex := 0; // Cumulative feed usage

  CBGraphRight.ItemIndex := 1; // Body weight

  CBMethod.ItemIndex := 1; // Marquardt

  Graph.BottomAxis.Title.Caption := _('Age (d)');

  MiseAJour := True;

  PBIng50.Decimals := FProfilP.PBIng50.Decimals;

  PBIng50.Increment := FProfilP.PBIng50.Increment;

  PBIng100.Decimals := FProfilP.PBIng100.Decimals;

  PBIng100.Increment := FProfilP.PBIng100.Increment;

  MiseAJour := False;

  New(PProfilTempo);

  IdxProfilTempo := ListProfilP.Add(PProfilTempo);

  New(PResSimulTempo);

  ListRecCalibr := TList.Create;

end;

procedure TFCalibrProfilP.FormDestroy(Sender: TObject);

var

  i: Integer;

  rec: PRecCalibr;

begin

  for i := 0 to ListRecCalibr.Count - 1 do

  begin

    rec := ListRecCalibr[i];

    Dispose(rec);

  end;

  ListRecCalibr.Free;

  ListProfilP.Delete(IdxProfilTempo);

  Dispose(PProfilTempo);

  Dispose(PResSimulTempo);

end;

procedure TFCalibrProfilP.FormShow(Sender: TObject);

var

  i: Integer;

  rec: PRecCalibr;

  wTot: Double;

  AgeInit: Integer;

  PVInit: Double;

begin

  // Lecture des observations

  for i := 1 to 4 do

  begin

    Nb[i] := 0;

    Tot[i] := 0;

    M[i] := 0;

    w[i] := 0;

  end;

  while ListRecCalibr.Count > 0 do

  begin

    rec := ListRecCalibr[0];

    Dispose(rec);

    ListRecCalibr.Delete(0);

  end;

  with FProfilP.ASQLite3TableObservProfilP do

  begin

    First;

    AgeInit := FieldByName('Age').AsInteger;

    PVInit := FieldByName('Weight').AsFloat;

    while not Eof do

    begin

      if (FieldByName('Line').AsInteger > 1) and not FieldByName('Feed').IsNull

      then

      begin

        Inc(Nb[1]);

        Tot[1] := Tot[1] + FieldByName('Feed').AsFloat;

        New(rec);

        rec.Age := FieldByName('Age').AsInteger;

        rec.Id := 1;

        rec.Observ := FieldByName('Feed').AsFloat;

        ListRecCalibr.Add(rec);

      end;

      if not FieldByName('Weight').IsNull

      then

      begin

        Inc(Nb[2]);

        Tot[2] := Tot[2] + FieldByName('Weight').AsFloat;

        New(rec);

        rec.Age := FieldByName('Age').AsInteger;

        rec.Id := 2;

        rec.Observ := FieldByName('Weight').AsFloat;

        ListRecCalibr.Add(rec);

      end;

      if not FieldByName('Backfat').IsNull

      then

      begin

        Inc(Nb[3]);

        Tot[3] := Tot[3] + FieldByName('Backfat').AsFloat;

        New(rec);

        rec.Age := FieldByName('Age').AsInteger;

        rec.Id := 3;

        rec.Observ := FieldByName('Backfat').AsFloat;

        ListRecCalibr.Add(rec);

      end;

      if not FieldByName('Lean').IsNull

      then

      begin

        Inc(Nb[4]);

        Tot[4] := Tot[4] + FieldByName('Lean').AsFloat;

        New(rec);

        rec.Age := FieldByName('Age').AsInteger;

        rec.Id := 4;

        rec.Observ := FieldByName('Lean').AsFloat;

        ListRecCalibr.Add(rec);

      end;

      Next;

    end;

  end;

  // Moyennes observations

  for i := 1 to 4 do

    if Nb[i] <> 0 then M[i] := Tot[i] / Nb[i];

  // Pond?rations observations

  for i := 1 to 4 do

    if M[i] <> 0 then w[i] := 1 / (Nb[i] * Power(M[i], 2));

  // R?ajustement des pond?rations en fonction de la pond?ration totale

  wTot := 0;

  for i := 1 to 4 do

    wTot := wTot + w[i];

  for i := 1 to 4 do

    w[i] := w[i] / wTot;

  // Affichage des variables d?pendantes

  PBwFeed.AsFloat := w[1];

  EwFeed.Text := PBwFeed.Text;

  PBwWeight.AsFloat := w[2];

  EwWeight.Text := PBwWeight.Text;

  if Nb[3] = 0

  then

  begin

    EwBackfat.Enabled := False;

    ERSDBackfat.Enabled := False;

    ER2Backfat.Enabled := False;

    EwRSSBackfat.Enabled := False;

    PBwBackfat.Enabled := False;

    CheckBox3.Enabled := False;

  end

  else

  begin

    PBwBackfat.AsFloat := w[3];

    EwBackfat.Text := PBwBackfat.Text;

  end;

  if Nb[4] = 0

  then

  begin

    EwLean.Enabled := False;

    ERSDLean.Enabled := False;

    ER2Lean.Enabled := False;

    EwRSSLean.Enabled := False;

    PBwLean.Enabled := False;

    CheckBox4.Enabled := False;

  end

  else

  begin

    PBwLean.AsFloat := w[4];

    EwLean.Text := PBwLean.Text;

  end;

  // Initialisation des param?tres avec les valeurs du profil

  MiseAJour := True;

  PBPVInit.AsFloat := PVInit;

  PBIng50.AsFloat := FProfilP.PBIng50.AsFloat;

  PBIng100.AsFloat := FProfilP.PBIng100.AsFloat;

  PBMeanPD.AsFloat := FProfilP.PBPDMoy.AsFloat;

  PBPrecocity.AsFloat := FProfilP.PBComport.AsFloat;

  PBMaintenance.AsFloat := FProfilP.PBEntretien.AsFloat;

  MiseAJour := False;

  PProfilP := ListProfilP[FindIdxProfilP(FProfilP.CBProfil.Text)];

  // Initialisation du profil temporaire

  PProfilTempo.Num := 0;

  PProfilTempo.Nom := '';

  PProfilTempo.Memo := '';

  PProfilTempo.Sexe := PProfilP.Sexe;

  PProfilTempo.SeqAli := PProfilP.SeqAli;

  PProfilTempo.Ration := PProfilP.Ration;

  PProfilTempo.AgeInit := AgeInit;

  PProfilTempo.PVInit := PVInit;

  if PVInit <> PProfilP.PVInit

  then // Recalculer les poids initiaux de prot?ines et lipides

  begin

    PProfilTempo.ProtInit := CalcProt(PVInit);

    PProfilTempo.LipInit := CalcLipProt(PVInit, PProfilTempo.ProtInit);

  end

  else // Utiliser les poids initiaux de prot?ines et lipides du profil

  begin

    PProfilTempo.ProtInit := PProfilP.ProtInit;

    PProfilTempo.LipInit := PProfilP.LipInit;

  end;

  PProfilTempo.ModeFin := 0; // Dur?e

  rec := ListRecCalibr[ListRecCalibr.Count - 1];

  PProfilTempo.Duree := rec.Age - AgeInit + 1;

  PProfilTempo.PVFin := 0;

  PProfilTempo.Carcasse := PProfilP.Carcasse;

  PProfilTempo.Unite := PProfilP.Unite;

  PProfilTempo.Equation := PProfilP.Equation;

  PProfilTempo.a := PProfilP.a;

  PProfilTempo.b := PProfilP.b;

  PProfilTempo.PDMoy := PProfilP.PDMoy;

  PProfilTempo.BGompertz := PProfilP.BGompertz;

  PProfilTempo.Entretien := PProfilP.Entretien;

  PProfilTempo.PVmr2 := PProfilP.PVmr2;

  if ProfilPValid(PProfilTempo)

  then // Affichage de la simulation

  begin

    CalcSimulP(-1, PProfilTempo.Num, PProfilTempo.SeqAli, PProfilTempo.Ration, -1, 1, PResSimulTempo, CBAALimit.Checked);

    CBGraphLeftChange(nil);

    CBGraphRightChange(nil);

  end;

end;

procedure TFCalibrProfilP.SBCalibrageClick(Sender: TObject);

var

  i: Integer;

  rec: PRecCalibr;

begin

  // Effacement des statistiques

  ERSDFeed.Clear;

  ERSDWeight.Clear;

  ERSDBackfat.Clear;

  ERSDLean.Clear;

  ER2Feed.Clear;

  ER2Weight.Clear;

  ER2Backfat.Clear;

  ER2Lean.Clear;

  EwRSSFeed.Clear;

  EwRSSWeight.Clear;

  EwRSSBackfat.Clear;

  EwRSSLean.Clear;

  EInitBWInitial.Clear;

  EY50Initial.Clear;

  EY100Initial.Clear;

  EMeanPDInitial.Clear;

  EPrecocityInitial.Clear;

  EMaintenanceInitial.Clear;

  EInitBWFinal.Clear;

  EY50Final.Clear;

  EY100Final.Clear;

  EMeanPDFinal.Clear;

  EPrecocityFinal.Clear;

  EMaintenanceFinal.Clear;

  ESDInitBW.Clear;

  ESDY50.Clear;

  ESDY100.Clear;

  ESDMeanPD.Clear;

  ESDPrecocity.Clear;

  ESDMaintenance.Clear;

  // Valeurs initiales des param?tres

  EInitBWInitial.Text := PBPVInit.Text;

  EY50Initial.Text := PBIng50.Text;

  EY100Initial.Text := PBIng100.Text;

  EMeanPDInitial.Text := PBMeanPD.Text;

  EPrecocityInitial.Text := PBPrecocity.Text;

  EMaintenanceInitial.Text := PBMaintenance.Text;

  // Calibration

  Screen.Cursor := crHourGlass;

  if not QueryPerformanceFrequency(Freq) then Freq := 1;

  QueryPerformanceCounter(Start);

  if RBStandard.Checked

  then // Mode standard (automatique)

  begin

    // Cycle 1 : Feed -> Y50 + Y100

    Uncheck;

    CheckBox1.Checked := True; // Feed

    CheckBox6.Checked := True; // Y50

    CheckBox7.Checked := True; // Y100

    Calibration;

    // Cycle 2 : Weight -> PVInit + PDMean

    Uncheck;

    CheckBox2.Checked := True; // Weight

    CheckBox5.Checked := True; // PVInit

    CheckBox8.Checked := True; // PDMean

    // Cycle 3 : Feed + Weight -> PVInit + Y50 + Y100 + PDMean

    CheckBox1.Checked := True; // Feed

    CheckBox6.Checked := True; // Y50

    CheckBox7.Checked := True; // Y100

    Calibration;

    // Cycle 4 : Weight -> PVInit + PDMean + Precocity

    Uncheck;

    CheckBox2.Checked := True; // Weight

    CheckBox5.Checked := True; // PVInit

    CheckBox8.Checked := True; // PDMean

    CheckBox9.Checked := True; // Precocity

    Calibration;

    // Cycle 5 : Feed + Weight -> PVInit + Y50 + Y100 + PDMean + Precocity

    CheckBox1.Checked := True; // Feed

    CheckBox6.Checked := True; // Y50

    CheckBox7.Checked := True; // Y100

    Calibration;

  end

  else // Mode expert (mannuel)

    Calibration;

  Screen.Cursor:= crDefault;

  QueryPerformanceCounter(Stop);

  ETime.Text := FloatToStrF((Stop - Start) / Freq, ffFixed, 15, 3);

  // Valeurs finales des param?tres

  EInitBWFinal.Text := PBPVInit.Text;

  EY50Final.Text := PBIng50.Text;

  EY100Final.Text := PBIng100.Text;

  EMeanPDFinal.Text := PBMeanPD.Text;

  EPrecocityFinal.Text := PBPrecocity.Text;

  EMaintenanceFinal.Text := PBMaintenance.Text;

  // Affichage des graphiques

  FCalibrProfilP.CBGraphLeftChange(nil);

  FCalibrProfilP.CBGraphRightChange(nil);

  // Calcul des statistiques

  for i := 1 to 4 do

  begin

    SSt[i] := 0;

    SSr[i] := 0;

    wSSr[i] := 0;

  end;

  for i := 0 to ListRecCalibr.Count - 1 do

  begin

    rec := ListRecCalibr[i];

    case rec.Id of

      1: // Feed

        if FCalibrProfilP.CheckBox1.Checked

        then

        begin

          SSt[1] := SSt[1] + Power(rec.Observ - M[1], 2);

          SSr[1] := SSr[1] + Power(rec.Observ - rec.Predict, 2);

          wSSr[1] := wSSr[1] + Power(rec.Observ - rec.Predict, 2) * w[1];

        end;

      2: // Weight

        if FCalibrProfilP.CheckBox2.Checked

        then

        begin

          SSt[2] := SSt[2] + Power(rec.Observ - M[2], 2);

          SSr[2] := SSr[2] + Power(rec.Observ - rec.Predict, 2);

          wSSr[2] := wSSr[2] + Power(rec.Observ - rec.Predict, 2) * w[2];

        end;

      3: // Backfat

        if FCalibrProfilP.CheckBox3.Checked

        then

        begin

          SSt[3] := SSt[3] + Power(rec.Observ - M[3], 2);

          SSr[3] := SSr[3] + Power(rec.Observ - rec.Predict, 2);

          wSSr[3] := wSSr[3] + Power(rec.Observ - rec.Predict, 2) * w[3];

        end;

      4: // Lean

        if FCalibrProfilP.CheckBox4.Checked

        then

        begin

          SSt[4] := SSt[4] + Power(rec.Observ - M[4], 2);

          SSr[4] := SSr[4] + Power(rec.Observ - rec.Predict, 2);

          wSSr[4] := wSSr[4] + Power(rec.Observ - rec.Predict, 2) * w[4];

        end;

    end;

  end;

  wSSrTot := 0;

  for i := 1 to 4 do

    wSSrTot := wSSrTot + wSSr[i];

  // Affichage des statistiques

  if CheckBox1.Checked

  then

  begin

    if Nb[1] > NVar / NVarDep then ERSDFeed.Text := Format('%1.1f %s', [Sqrt(SSr[1] / (Nb[1] - NVar / NVarDep)), StrKg]);

    if SSt[1] <> 0 then ER2Feed.Text := Format('%1.2f %%', [100 - SSr[1] / SSt[1] * 100]);

    if wSSrTot <> 0 then EwRSSFeed.Text := Format('%1.2f %%', [wSSr[1] / wSSrTot * 100]);

  end;

  if CheckBox2.Checked

  then

  begin

    if Nb[2] > NVar / NVarDep then ERSDWeight.Text := Format('%1.1f %s', [Sqrt(SSr[2] / (Nb[2] - NVar / NVarDep)), StrKg]);

    if SSt[2] <> 0 then ER2Weight.Text := Format('%1.2f %%', [100 - SSr[2] / SSt[2] * 100]);

    if wSSrTot <> 0 then EwRSSWeight.Text := Format('%1.2f %%', [wSSr[2] / wSSrTot * 100]);

  end;

  if CheckBox3.Checked

  then

  begin

    if Nb[3] > NVar / NVarDep then ERSDBackfat.Text := Format('%1.1f %s', [Sqrt(SSr[3] / (Nb[3] - NVar / NVarDep)), StrMM]);

    if SSt[3] <> 0 then ER2Backfat.Text := Format('%1.2f %%', [100 - SSr[3] / SSt[3] * 100]);

    if wSSrTot <> 0 then EwRSSBackfat.Text := Format('%1.2f %%', [wSSr[3] / wSSrTot * 100]);

  end;

  if CheckBox4.Checked

  then

  begin

    if Nb[4] > NVar / NVarDep then ERSDLean.Text := Format('%1.1f %%', [Sqrt(SSr[4] / (Nb[4] - NVar / NVarDep))]);

    if SSt[4] <> 0 then ER2Lean.Text := Format('%1.2f %%', [100 - SSr[4] / SSt[4] * 100]);

    if wSSrTot <> 0 then EwRSSLean.Text := Format('%1.2f %%', [wSSr[4] / wSSrTot * 100]);

  end;

  i := 0;

  if CheckBox5.Checked

  then

  begin

    Inc(i);

    if NData > NVar then ESDInitBW.Text := FloatToStrF(Sqrt(wSSrTot / (NData - NVar) * Inv[i]), ffFixed, 15, PBPVInit.Decimals);

  end;

  if CheckBox6.Checked

  then

  begin

    Inc(i);

    if NData > NVar then ESDY50.Text := FloatToStrF(Sqrt(wSSrTot / (NData - NVar) * Inv[i]), ffFixed, 15, PBIng50.Decimals);

  end;

  if CheckBox7.Checked

  then

  begin

    Inc(i);

    if NData > NVar then ESDY100.Text := FloatToStrF(Sqrt(wSSrTot / (NData - NVar) * Inv[i]), ffFixed, 15, PBIng100.Decimals);

  end;

  if CheckBox8.Checked

  then

  begin

    Inc(i);

    if NData > NVar then ESDMeanPD.Text := FloatToStrF(Sqrt(wSSrTot / (NData - NVar) * Inv[i]), ffFixed, 15, PBMeanPD.Decimals);

  end;

  if CheckBox9.Checked

  then

  begin

    Inc(i);

    if NData > NVar then ESDPrecocity.Text := FloatToStrF(Sqrt(wSSrTot / (NData - NVar) * Inv[i]), ffFixed, 15, PBPrecocity.Decimals);

  end;

  if CheckBox10.Checked

  then

  begin

    Inc(i);

    if NData > NVar then ESDMaintenance.Text := FloatToStrF(Sqrt(wSSrTot / (NData - NVar) * Inv[i]), ffFixed, 15, PBMaintenance.Decimals);

  end;

  // Erreurs

  LInfo.Visible := True;

  case MathErr of

    OptNonConv: LInfo.Caption := _('Non-convergence');

    OptSing: LInfo.Caption := _('Singular Hessian matrix');

    OptBigLambda: LInfo.Caption := _('Marquardt parameter too high');

    else LInfo.Visible := False;

  end;

  if CBAALimit.Checked and PDLimit

  then

    MessageDlg(MsgPDLimit, mtWarning, [mbOK], 0);

  BBOk.Enabled := ProfilPValid(PProfilTempo);

end;

procedure TFCalibrProfilP.PBPVInitChange(Sender: TObject);

begin

  if not MiseAJour

  then

  begin

    PProfilTempo.PVInit := PBPVInit.AsFloat;

    // Recalculer les poids initiaux de prot?ines et lipides

    PProfilTempo.ProtInit := CalcProt(PProfilTempo.PVInit);

    PProfilTempo.LipInit := CalcLipProt(PProfilTempo.PVInit, PProfilTempo.ProtInit);

    if ProfilPValid(PProfilTempo)

    then // Affichage de la simulation

    begin

      CalcSimulP(-1, PProfilTempo.Num, PProfilTempo.SeqAli, PProfilTempo.Ration, -1, 1, PResSimulTempo, CBAALimit.Checked);

      CBGraphLeftChange(nil);

      CBGraphRightChange(nil);

    end;

  end;

end;

procedure TFCalibrProfilP.PBIng50Change(Sender: TObject);

begin

  if not MiseAJour

  then

  begin

    with PProfilTempo^ do

      CalcCoef(Equation, Unite, PBIng50.AsFloat, PBIng100.AsFloat, a, b);

    if ProfilPValid(PProfilTempo)

    then // Affichage de la simulation

    begin

      CalcSimulP(-1, PProfilTempo.Num, PProfilTempo.SeqAli, PProfilTempo.Ration, -1, 1, PResSimulTempo, CBAALimit.Checked);

      CBGraphLeftChange(nil);

      CBGraphRightChange(nil);

    end;

  end;

end;

procedure TFCalibrProfilP.PBIng100Change(Sender: TObject);

begin

  if not MiseAJour

  then

  begin

    with PProfilTempo^ do

      CalcCoef(Equation, Unite, PBIng50.AsFloat, PBIng100.AsFloat, a, b);

    if ProfilPValid(PProfilTempo)

    then // Affichage de la simulation

    begin

      CalcSimulP(-1, PProfilTempo.Num, PProfilTempo.SeqAli, PProfilTempo.Ration, -1, 1, PResSimulTempo, CBAALimit.Checked);

      CBGraphLeftChange(nil);

      CBGraphRightChange(nil);

    end;

  end;

end;

procedure TFCalibrProfilP.PBMeanPDChange(Sender: TObject);

begin

  if not MiseAJour

  then

  begin

    PProfilTempo.PDMoy := PBMeanPD.AsFloat;

    if ProfilPValid(PProfilTempo)

    then // Affichage de la simulation

    begin

      CalcSimulP(-1, PProfilTempo.Num, PProfilTempo.SeqAli, PProfilTempo.Ration, -1, 1, PResSimulTempo, CBAALimit.Checked);

      CBGraphLeftChange(nil);

      CBGraphRightChange(nil);

    end;

  end;

end;

procedure TFCalibrProfilP.PBPrecocityChange(Sender: TObject);

begin

  if not MiseAJour

  then

  begin

    PProfilTempo.BGompertz := PBPrecocity.AsFloat;

    if ProfilPValid(PProfilTempo)

    then // Affichage de la simulation

    begin

      CalcSimulP(-1, PProfilTempo.Num, PProfilTempo.SeqAli, PProfilTempo.Ration, -1, 1, PResSimulTempo, CBAALimit.Checked);

      CBGraphLeftChange(nil);

      CBGraphRightChange(nil);

    end;

  end;

end;

procedure TFCalibrProfilP.PBMaintenanceChange(Sender: TObject);

begin

  if not MiseAJour

  then

  begin

    PProfilTempo.Entretien := PBMaintenance.AsFloat;

    if ProfilPValid(PProfilTempo)

    then // Affichage de la simulation

    begin

      CalcSimulP(-1, PProfilTempo.Num, PProfilTempo.SeqAli, PProfilTempo.Ration, -1, 1, PResSimulTempo, CBAALimit.Checked);

      CBGraphLeftChange(nil);

      CBGraphRightChange(nil);

    end;

  end;

end;

procedure TFCalibrProfilP.PBwFeedChange(Sender: TObject);

begin

  w[1] := PBwFeed.AsFloat;

  EwFeed.Text := PBwFeed.Text;

end;

procedure TFCalibrProfilP.PBwWeightChange(Sender: TObject);

begin

  w[2] := PBwWeight.AsFloat;

  EwWeight.Text := PBwWeight.Text;

end;

procedure TFCalibrProfilP.PBwBackfatChange(Sender: TObject);

begin

  w[3] := PBwBackfat.AsFloat;

  EwBackfat.Text := PBwBackfat.Text;

end;

procedure TFCalibrProfilP.PBwLeanChange(Sender: TObject);

begin

  w[4] := PBwLean.AsFloat;

  EwLean.Text := PBwLean.Text;

end;

procedure TFCalibrProfilP.RBExpertClick(Sender: TObject);

begin

  CBMethod.Enabled := True;

  CBAALimit.Enabled := True;

  PBwFeed.Visible := True;

  PBwWeight.Visible := True;

  PBwBackfat.Visible := True;

  PBwLean.Visible := True;

  EwBackfat.Enabled := True;

  EwLean.Enabled := True;

  ERSDBackfat.Enabled := True;

  ERSDLean.Enabled := True;

  ER2Backfat.Enabled := True;

  ER2Lean.Enabled := True;

  EwRSSBackfat.Enabled := True;

  EwRSSLean.Enabled := True;

  EMaintenanceInitial.Enabled := True;

  EMaintenanceFinal.Enabled := True;

  ESDMaintenance.Enabled := True;

  CheckBox1.Visible := True;

  CheckBox2.Visible := True;

  CheckBox3.Visible := True;

  CheckBox4.Visible := True;

  CheckBox5.Visible := True;

  CheckBox6.Visible := True;

  CheckBox7.Visible := True;

  CheckBox8.Visible := True;

  CheckBox9.Visible := True;

  CheckBox10.Visible := True;

end;

procedure TFCalibrProfilP.RBStandardClick(Sender: TObject);

begin

  CBMethod.Enabled := False;

  CBAALimit.Enabled := False;

  PBwFeed.Visible := False;

  PBwWeight.Visible := False;

  PBwBackfat.Visible := False;

  PBwLean.Visible := False;

  ERSDBackfat.Enabled := False;

  ERSDLean.Enabled := False;

  ER2Backfat.Enabled := False;

  ER2Lean.Enabled := False;

  EwRSSBackfat.Enabled := False;

  EwRSSLean.Enabled := False;

  EMaintenanceInitial.Enabled := False;

  EMaintenanceFinal.Enabled := False;

  ESDMaintenance.Enabled := False;

  CheckBox1.Visible := False;

  CheckBox2.Visible := False;

  CheckBox3.Visible := False;

  CheckBox4.Visible := False;

  CheckBox5.Visible := False;

  CheckBox6.Visible := False;

  CheckBox7.Visible := False;

  CheckBox8.Visible := False;

  CheckBox9.Visible := False;

  CheckBox10.Visible := False;

end;

procedure TFCalibrProfilP.Uncheck;

begin

  CheckBox1.Checked := False; // Feed

  CheckBox2.Checked := False; // Weight

  CheckBox3.Checked := False; // Backfat

  CheckBox4.Checked := False; // Lean

  CheckBox5.Checked := False; // InitBW

  CheckBox6.Checked := False; // Y50

  CheckBox7.Checked := False; // Y100

  CheckBox8.Checked := False; // PDMean

  CheckBox9.Checked := False; // Precocity

  CheckBox10.Checked := False; // Maintenance

end;

end.