InraPorc

unit UFMenu;

{$WARN UNIT_PLATFORM OFF}

interface

uses

  Windows, Forms, Classes, Controls, Dialogs, Graphics, StdCtrls, Buttons,

  ExtCtrls, ComCtrls, Menus, XPMan, IdBaseComponent, IdComponent,

  IdTCPConnection, IdTCPClient, IdHTTP, IdIOHandler, IdIOHandlerSocket,

  IdIOHandlerStack, IdSSL, IdSSLOpenSSL;

type

  TFMenu = class (TForm)

    StatusLine : TStatusBar ;

    IBackground: TImage;

    MainMenu: TMainMenu;

    MFile: TMenuItem;

    MLicense: TMenuItem;

    MConfig: TMenuItem;

    MFolder: TMenuItem;

    N11: TMenuItem;

    MExit: TMenuItem;

    MAliments: TMenuItem;

    MMatiere: TMenuItem;

    N21: TMenuItem;

    MAliment: TMenuItem;

    MTarif: TMenuItem;

    N22: TMenuItem;

    MImpExp: TMenuItem;

    MTruie: TMenuItem;

    MSeqAliT: TMenuItem;

    MRationT: TMenuItem;

    MLogeT: TMenuItem;

    MProfilT: TMenuItem;

    N31: TMenuItem;

    MSimulT: TMenuItem;

    N32: TMenuItem;

    MBesGest: TMenuItem;

    MBesGestT: TMenuItem;

    MBesGestE: TMenuItem;

    MBesLact: TMenuItem;

    MBesLactT: TMenuItem;

    MBesLactE: TMenuItem;

    MPorc: TMenuItem;

    MSeqAliP: TMenuItem;

    MRationP: TMenuItem;

    MProfilP: TMenuItem;

    N41: TMenuItem;

    MSimulP: TMenuItem;

    MWindow: TMenuItem;

    MCascade: TMenuItem;

    MTileHorizontal: TMenuItem;

    MTileVertical: TMenuItem;

    MMinimizeAll: TMenuItem;

    MRetoreAll: TMenuItem;

    MArrange: TMenuItem;

    MHelp: TMenuItem;

    MContents: TMenuItem;

    N61: TMenuItem;

    MIntro: TMenuItem;

    N62: TMenuItem;

    MWeb: TMenuItem;

    MAbout: TMenuItem;

    ILogo: TImage;

    XPManifestStyle: TXPManifest;

    MUpdate: TMenuItem;

    IdHTTPCheckVersion: TIdHTTP;

    MDataset: TMenuItem;

    IdSSL: TIdSSLIOHandlerSocketOpenSSL;

    procedure FormShow(Sender: TObject);

    procedure FormClose(Sender: TObject; var Action: TCloseAction);

    procedure MConfigClick(Sender: TObject);

    procedure MExitClick(Sender: TObject);

    procedure MMatiereClick(Sender: TObject);

    procedure MAlimentClick(Sender: TObject);

    procedure MTarifClick(Sender: TObject);

    procedure MImpExpClick(Sender: TObject);

    procedure MSeqAliTClick(Sender: TObject);

    procedure MRationTClick(Sender: TObject);

    procedure MLogeTClick(Sender: TObject);

    procedure MProfilTClick(Sender: TObject);

    procedure MSimulTClick(Sender: TObject);

    procedure MSeqAliPClick(Sender: TObject);

    procedure MRationPClick(Sender: TObject);

    procedure MProfilPClick(Sender: TObject);

    procedure MSimulPClick(Sender: TObject);

    procedure WindowCascade(Sender: TObject);

    procedure MTileHorizontalClick(Sender: TObject);

    procedure MTileVerticalClick(Sender: TObject);

    procedure MMinimizeAllClick(Sender: TObject);

    procedure MRetoreAllClick(Sender: TObject);

    procedure MArrangeClick(Sender: TObject);

    procedure HelpContentsClick(Sender: TObject);

    procedure HelpIndexClick(Sender: TObject);

    procedure MAboutClick(Sender: TObject);

    procedure MBesGestTClick(Sender: TObject);

    procedure MBesGestEClick(Sender: TObject);

    procedure MBesLactTClick(Sender: TObject);

    procedure MBesLactEClick(Sender: TObject);

    procedure FormResize(Sender: TObject);

    procedure MLicenseClick(Sender: TObject);

    procedure MFolderClick(Sender: TObject);

    procedure MIntroClick(Sender: TObject);

    procedure FormCreate(Sender: TObject);

    procedure MWebClick(Sender: TObject);

    procedure MHelpSearchClick(Sender: TObject);

    procedure FormDestroy(Sender: TObject);

    procedure MUpdateClick(Sender: TObject);

    procedure MDatasetClick(Sender: TObject);

  private

    { Private declarations }

    procedure VerifyData;

  public

    { Public declarations }

  end ;

var

  FMenu : TFMenu ;

implementation

uses

  FileCtrl, Math, Messages, ShellAPI, SysUtils, gnugettext, UVariables,

  UStrings, UInit, UUtil, UFindRec, UFLicense, UFConfig, {UFInraAfz,}

  UFMatiere, UFAliment, UFTarif, UFImpExp, UFSeqAliT, UFRationT, UFLogeT,

  UFProfilT, UFSimulT, UFBesGestT, UFBesGestE, UFBesLactT, UFBesLactE,

  UFSeqAliP, UFRationP, UFProfilP, UFSimulP, UFIntro, UFAbout, UFError,

  UFWarning;

{$r *.dfm}

var

  OldWndProc: Pointer;

  WndMsg: DWORD;

function NewWndProc(WindowHandle: HWND; Msg: UINT; wParam: WPARAM; lParam: LPARAM): LRESULT stdcall;

begin

  if Msg = WndMsg

  then // Appel par une autre instance : restauration

  begin

    Result := SendMessage(Application.Handle, WM_SYSCOMMAND, SC_RESTORE, 0);

    SetForegroundWindow(Application.Handle);

    Exit;

  end;

  if WParam = VK_F1

  then // F1 = Help

    Result := HtmlHelp(Application.Handle, PChar(Application.CurrentHelpFile), HH_HELP_CONTEXT, FMenu.HelpContext)

  else

    Result := CallWindowProc(OldWndProc, WindowHandle, Msg, WParam, LParam);

end;

procedure TFMenu.FormCreate(Sender: TObject);

begin

  WndMsg := RegisterWindowMessage('InraPorc');

  OldWndProc := Pointer(SetWindowLong(Handle, GWL_WNDPROC, Longint(@NewWndProc)));

  if Screen.Fonts.IndexOf('Arial Unicode MS') <> -1

  then

  begin

    Font.Name := 'Arial Unicode MS';

    StatusLine.Font.Name := 'Arial Unicode MS';

  end;

  TranslateComponent(Self);

  Constraints.MinHeight := Min(768, Screen.WorkAreaHeight);

  Constraints.MinWidth := Min(1024, Screen.WorkAreaWidth);

end;

procedure TFMenu.FormDestroy(Sender: TObject);

begin

  SetWindowLong(Handle, GWL_WNDPROC, Longint(OldWndProc));

end;

procedure TFMenu.FormShow(Sender: TObject);

var

  CurrentVersion: string;

begin

  // Recherche automatique de mises-?-jours

  if CheckForUpdates then

  begin

    IdHTTPCheckVersion.ConnectTimeout := 10000;

    try

      CurrentVersion := IdHTTPCheckVersion.Get(URL_HTTPS + 'CheckVersion.php');

      if Length(CurrentVersion) = 7 then

        if CompareString(LOCALE_INVARIANT, NORM_IGNORECASE, PChar(CurrentVersion), Length(CurrentVersion), PChar(VersionString), Length(VersionString)) = CSTR_GREATER_THAN then

        begin

          if Copy(LanguageCode, 1, 2) = 'fr'

          then // Fran?ais

            ShellExecute(Handle, 'open', PChar(URL_HTTPS + 'history_fr.php'), nil, nil, SW_SHOWNORMAL)

          else // Anglais

            ShellExecute(Handle, 'open', PChar(URL_HTTPS + 'history_en.php'), nil, nil, SW_SHOWNORMAL);

          if MessageDlg(Format(MsgUpdateFound, [CurrentVersion]), mtConfirmation, [mbYes, mbNo], 0) = mrYes then

            ShellExecute(Handle, 'open', PChar(URL_HTTPS + Format('Downloads/%s/InraPorcSetup.exe', [CurrentVersion])), nil, nil, SW_SHOWNORMAL);

        end;

    except

    end;

  end;

  // Initialisation du contr?le des fen?tres MDI

  NumWinMatiere := -1;

  NumWinAliment := -1;

  NumWinTarif := -1;

  NumWinImpExp := -1;

  NumWinSeqAliT := -1;

  NumWinRationT := -1;

  NumWinLogeT := -1;

  NumWinProfilT := -1;

  NumWinSimulT := -1;

  NumWinBesGestT := -1;

  NumWinBesGestE := -1;

  NumWinBesLactT := -1;

  NumWinBesLactE := -1;

  NumWinSeqAliP := -1;

  NumWinRationP := -1;

  NumWinProfilP := -1;

  NumWinSimulP := -1;

  // Taille et position de la fen?tre principale

  SetBounds(MainLeft, MainTop, MainWidth, MainHeight);

  FormResize(nil);

  if FileExists(Logo)

  then

    ILogo.Picture.LoadFromFile(Logo);

  if DataFolderExists

  then

    VerifyData

  else

  begin

    MAliments.Enabled := False;

    MTruie.Enabled := False;

    MPorc.Enabled := False;

  end;

end;

procedure TFMenu.FormClose(Sender: TObject; var Action: TCloseAction);

var

  i: Integer;

begin

  if MDIChildCount > 0

  then

    for i := MDIChildCount - 1 downto 0 do

      MDIChildren[i].Close;

  FreeData ;

//  FreeLicense;

//  FreeRegistry;

end;

procedure TFMenu.FormResize(Sender: TObject);

var

  {BorderSize,} TextSize: Integer;

begin

  MImpExp.Enabled := IsComplete ;

  // Licence

  if IsEducation and (Length (Course) > 0)

  then

    StatusLine.Panels[1].Text := Format('%s (%s)', [Course, Company])

  else

  if IsComplete or IsEducation

  then

    StatusLine.Panels[1].Text := Format('%s %s (%s)', [FirstName, LastName, Company])

  else

  if IsEvaluation

  then

    StatusLine.Panels[1].Text := StrEvaluation

  else

    StatusLine.Panels[1].Text := StrReadOnly;

//  BorderSize := Width - ClientWidth;

  TextSize := StatusLine.Canvas.TextWidth(StatusLine.Panels[1].Text);

  with StatusLine do

    Panels[0].Width := ClientWidth - TextSize - 24;

end;

procedure TFMenu.VerifyData;

const

  SEP = '        ';

var

  i, j, ErrorCount: Integer;

  ErrorInraAfz, ok: Boolean;

begin

  if (not FileExists(NFicRationP) and FileExists(NFicRationPold))

  or (not FileExists(NFicProfilP) and FileExists(NFicProfilPold))

  then // L'ancien jeu de donn?es n'a pas ?t? converti

    Exit;

  ErrorCount := 0;

  ErrorInraAfz := FALSE;

  FError := TFError.Create(Self);

  FError.MErrors.Lines.Add(MAliments.Caption);

  // Mati?re premi?re

  FError.MErrors.Lines.Add(SEP + MMatiere.Caption);

  if not FileExists(NFicMatInraAfz)

  then

    FError.MErrors.Lines.Add(SEP + SEP + Format(MsgFileNotFound, [NFicMatInraAfz]));

  if not FileExists(NFicMatiere)

  then

  begin

    Inc(ErrorCount);

    FError.MErrors.Lines.Add(SEP + SEP + Format(MsgFileNotFound, [NFicMatiere]));

  end;

  // Aliment

  FError.MErrors.Lines.Add(SEP + MAliment.Caption);

  if not FileExists(NFicAliment)

  then

  begin

    Inc(ErrorCount);

    FError.MErrors.Lines.Add(SEP + SEP + Format(MsgFileNotFound, [NFicAliment]));

  end;

  if ListAliment.Count > 0

  then

    for i := 0 to ListAliment.Count - 1 do

    begin

      PAliment := ListAliment[i];

      if (PAliment.MP.NbMat < 0) or (PAliment.MP.NbMat > MAX_MP)

      then // Bug lors de l'importation (correction du 1/3/2007)

        PAliment.MP.NbMat := 0;

      if PAliment.MP.NbMat > 0

      then

        for j := 0 to PAliment.MP.NbMat - 1 do

          if (PAliment.MP.NumMat[j] <> 0) and not MatiereFound(PAliment.MP.NumMat[j])

          then

          begin

            Inc(ErrorCount);

            if PAliment.MP.NumMat[j] < 0

            then

              ErrorInraAfz := TRUE;

            FError.MErrors.Lines.Add(SEP + SEP + Format('%s - %s %d', [PAliment.Nom, MMatiere.Caption, PAliment.MP.NumMat[j]]));

            PAliment.MP.NumMat[j] := 0;

          end;

    end;

  FError.MErrors.Lines.Add(MTruie.Caption);

  // S?quence alimentaire truie

  FError.MErrors.Lines.Add(SEP + MSeqAliT.Caption);

  if not FileExists(NFicSeqAliT)

  then

  begin

    Inc(ErrorCount);

    FError.MErrors.Lines.Add(SEP + SEP + Format(MsgFileNotFound, [NFicSeqAliT]));

  end;

  if ListSeqAliT.Count > 0

  then

    for i := 0 to ListSeqAliT.Count - 1 do

    begin

      PSeqAliT := ListSeqAliT[i];

      for j := 1 to PSeqAliT.NbRuleGest do

      begin

        if (PSeqAliT.RuleGest[j].NumAli1 <> -1) and not AlimentFound(PSeqAliT.RuleGest[j].NumAli1)

        then

        begin

          Inc(ErrorCount);

          FError.MErrors.Lines.Add(SEP + SEP + Format('%s - %s %d', [PSeqAliT.Nom, MAliment.Caption, PSeqAliT.RuleGest[j].NumAli1]));

          PSeqAliT.RuleGest[j].NumAli1 := -1;

        end;

        if (PSeqAliT.RuleGest[j].NumAli2 <> -1) and not AlimentFound(PSeqAliT.RuleGest[j].NumAli2)

        then

        begin

          Inc(ErrorCount);

          FError.MErrors.Lines.Add(SEP + SEP + Format('%s - %s %d', [PSeqAliT.Nom, MAliment.Caption, PSeqAliT.RuleGest[j].NumAli2]));

          PSeqAliT.RuleGest[j].NumAli2 := -1;

        end;

      end;

      for j := 1 to PSeqAliT.NbRuleLact do

      begin

        if (PSeqAliT.RuleLact[j].NumAli1 <> -1) and not AlimentFound(PSeqAliT.RuleLact[j].NumAli1)

        then

        begin

          Inc(ErrorCount);

          FError.MErrors.Lines.Add(SEP + SEP + Format('%s - %s %d', [PSeqAliT.Nom, MAliment.Caption, PSeqAliT.RuleLact[j].NumAli1]));

          PSeqAliT.RuleLact[j].NumAli1 := -1;

        end;

        if (PSeqAliT.RuleLact[j].NumAli2 <> -1) and not AlimentFound(PSeqAliT.RuleLact[j].NumAli2)

        then

        begin

          Inc(ErrorCount);

          FError.MErrors.Lines.Add(SEP + SEP + Format('%s - %s %d', [PSeqAliT.Nom, MAliment.Caption, PSeqAliT.RuleLact[j].NumAli2]));

          PSeqAliT.RuleLact[j].NumAli2 := -1;

        end;

      end;

      for j := 1 to PSeqAliT.NbRuleISSF do

      begin

        if (PSeqAliT.RuleISSF[j].NumAli1 <> -1) and not AlimentFound(PSeqAliT.RuleISSF[j].NumAli1)

        then

        begin

          Inc(ErrorCount);

          FError.MErrors.Lines.Add(SEP + SEP + Format('%s - %s %d', [PSeqAliT.Nom, MAliment.Caption, PSeqAliT.RuleISSF[j].NumAli1]));

          PSeqAliT.RuleISSF[j].NumAli1 := -1;

        end;

        if (PSeqAliT.RuleISSF[j].NumAli2 <> -1) and not AlimentFound(PSeqAliT.RuleISSF[j].NumAli2)

        then

        begin

          Inc(ErrorCount);

          FError.MErrors.Lines.Add(SEP + SEP + Format('%s - %s %d', [PSeqAliT.Nom, MAliment.Caption, PSeqAliT.RuleISSF[j].NumAli2]));

          PSeqAliT.RuleISSF[j].NumAli2 := -1;

        end;

      end;

    end;

  // Plan de rationnement truie

  FError.MErrors.Lines.Add(SEP + MRationT.Caption);

  if not FileExists(NFicRationT)

  then

  begin

    Inc(ErrorCount);

    FError.MErrors.Lines.Add(SEP + SEP + Format(MsgFileNotFound, [NFicRationT]));

  end;

  // Logement truie

  FError.MErrors.Lines.Add(SEP + MLogeT.Caption);

  if not FileExists(NFicLogeT)

  then

  begin

    Inc(ErrorCount);

    FError.MErrors.Lines.Add(SEP + SEP + Format(MsgFileNotFound, [NFicLogeT]));

  end;

  // Profil truie

  FError.MErrors.Lines.Add(SEP + MProfilT.Caption);

  if not FileExists(NFicProfilT)

  then

  begin

    Inc(ErrorCount);

    FError.MErrors.Lines.Add(SEP + SEP + Format(MsgFileNotFound, [NFicProfilT]));

  end;

  if ListProfilT.Count > 0

  then

    for i := 0 to ListProfilT.Count - 1 do

    begin

      PProfilT := ListProfilT[i];

      if (PProfilT.SeqAli <> -1) and not SeqAliTFound(PProfilT.SeqAli)

      then

      begin

        Inc(ErrorCount);

        FError.MErrors.Lines.Add(SEP + SEP + Format('%s - %s %d', [PProfilT.Nom, MSeqAliT.Caption, PProfilT.SeqAli]));

        PProfilT.SeqAli := -1;

      end;

      if (PProfilT.Loge <> -1) and not LogeTFound(PProfilT.Loge)

      then

      begin

        Inc(ErrorCount);

        FError.MErrors.Lines.Add(SEP + SEP + Format('%s - %s %d', [PProfilT.Nom, MLogeT.Caption, PProfilT.Loge]));

        PProfilT.Loge := -1;

      end;

    end ;

  // Simulation truie

  FError.MErrors.Lines.Add(SEP + MSimulT.Caption);

  if not FileExists(NFicSimulT)

  then

  begin

    Inc(ErrorCount);

    FError.MErrors.Lines.Add(SEP + SEP + Format(MsgFileNotFound, [NFicSimulT]));

  end;

  if ListSimulT.Count > 0

  then

    for i := 0 to ListSimulT.Count - 1 do

    begin

      PSimulT := ListSimulT[i];

      if (PSimulT.Profil <> -1) and not ProfilTFound(PSimulT.Profil)

      then

      begin

        Inc(ErrorCount);

        FError.MErrors.Lines.Add(SEP + SEP + Format('%s - %s %d', [PSimulT.Nom, MProfilT.Caption, PSimulT.Profil]));

        PSimulT.Profil := -1;

      end;

      if (PSimulT.Logement <> -1) and not LogeTFound(PSimulT.Logement)

      then

      begin

        Inc(ErrorCount);

        FError.MErrors.Lines.Add(SEP + SEP + Format('%s - %s %d', [PSimulT.Nom, MLogeT.Caption, PSimulT.Logement]));

        PSimulT.Logement := -1;

      end;

      for j := 1 to NB_CYCLES do

        if (PSimulT.SeqAli[j] <> -1) and not SeqAliTFound(PSimulT.SeqAli[j])

        then

          if (j < PSimulT.StadeInit div 3) or (j > PSimulT.StadeFin div 3)

          then // Port?e masqu?e => correction silencieuse

            PSimulT.SeqAli[j] := -1

          else

          begin

            Inc(ErrorCount);

            FError.MErrors.Lines.Add(SEP + SEP + Format('%s - %s %d', [PSimulT.Nom, MSeqAliT.Caption, PSimulT.SeqAli[j]]));

            PSimulT.SeqAli[j] := -1;

          end;

      for j := 1 to NB_CYCLES do

        if (PSimulT.Ration[j] <> -1) and not RationTFound(PSimulT.Ration[j])

        then

          if (j < PSimulT.StadeInit div 3) or (j > PSimulT.StadeFin div 3)

          then // Port?e masqu?e => correction silencieuse

            PSimulT.Ration[j] := -1

          else

          begin

            Inc(ErrorCount);

            FError.MErrors.Lines.Add(SEP + SEP + Format('%s - %s %d', [PSimulT.Nom, MRationT.Caption, PSimulT.Ration[j]]));

            PSimulT.Ration[j] := -1;

          end;

    end ;

  FError.MErrors.Lines.Add(MPorc.Caption);

  // S?quence alimentaire porc

  FError.MErrors.Lines.Add(SEP + MSeqAliP.Caption);

  if not FileExists(NFicSeqAliP)

  then

  begin

    Inc(ErrorCount);

    FError.MErrors.Lines.Add(SEP + SEP + Format(MsgFileNotFound, [NFicSeqAliP]));

  end;

  if ListSeqAliP.Count > 0

  then

    for i := 0 to ListSeqAliP.Count - 1 do

    begin

      PSeqAliP := ListSeqAliP[i];

      for j := 1 to PSeqAliP.NbRule do

      begin

        if (PSeqAliP.Rule[j].NumAli1 <> -1) and not AlimentFound(PSeqAliP.Rule[j].NumAli1)

        then

        begin

          Inc(ErrorCount);

          FError.MErrors.Lines.Add(SEP + SEP + Format('%s - %s %d', [PSeqAliP.Nom, MAliment.Caption, PSeqAliP.Rule[j].NumAli1]));

          PSeqAliP.Rule[j].NumAli1 := -1;

        end;

        if (PSeqAliP.Rule[j].NumAli2 <> -1) and not AlimentFound(PSeqAliP.Rule[j].NumAli2)

        then

        begin

          Inc(ErrorCount);

          FError.MErrors.Lines.Add(SEP + SEP + Format('%s - %s %d', [PSeqAliP.Nom, MAliment.Caption, PSeqAliP.Rule[j].NumAli2]));

          PSeqAliP.Rule[j].NumAli2 := -1;

        end;

      end;

    end;

  // Plan de rationnement porc

  FError.MErrors.Lines.Add(SEP + MRationP.Caption);

  if not FileExists(NFicRationP)

  then

  begin

    Inc(ErrorCount);

    FError.MErrors.Lines.Add(SEP + SEP + Format(MsgFileNotFound, [NFicRationP]));

  end;

  // Profil porc

  FError.MErrors.Lines.Add(SEP + MProfilP.Caption);

  if not FileExists(NFicProfilP)

  then

  begin

    Inc(ErrorCount);

    FError.MErrors.Lines.Add(SEP + SEP + Format(MsgFileNotFound, [NFicProfilP]));

  end;

  if ListProfilP.Count > 0

  then

    for i := 0 to ListProfilP.Count - 1 do

    begin

      PProfilP := ListProfilP[i];

      if (PProfilP.SeqAli <> -1) and not SeqAliPFound(PProfilP.SeqAli)

      then

      begin

        Inc(ErrorCount);

        FError.MErrors.Lines.Add(SEP + SEP + Format('%s - %s %d', [PProfilP.Nom, MSeqAliP.Caption, PProfilP.SeqAli]));

        PProfilP.SeqAli := -1;

      end;

    end ;

  // Simulation porc

  FError.MErrors.Lines.Add(SEP + MSimulP.Caption);

  if not FileExists(NFicSimulP)

  then

  begin

    Inc(ErrorCount);

    FError.MErrors.Lines.Add(SEP + SEP + Format(MsgFileNotFound, [NFicSimulP]));

  end;

  if ListSimulP.Count > 0

  then

    for i := 0 to ListSimulP.Count - 1 do

    begin

      PSimulP := ListSimulP[i];

      if (PSimulP.Profil <> -1) and not ProfilPFound(PSimulP.Profil)

      then

      begin

        Inc(ErrorCount);

        FError.MErrors.Lines.Add(SEP + SEP + Format('%s - %s %d', [PSimulP.Nom, MProfilP.Caption, PSimulP.Profil]));

        PSimulP.Profil := -1;

      end;

      if (PSimulP.SeqAli <> -1) and not SeqAliPFound(PSimulP.SeqAli)

      then

      begin

        Inc(ErrorCount);

        FError.MErrors.Lines.Add(SEP + SEP + Format('%s - %s %d', [PSimulP.Nom, MSeqAliP.Caption, PSimulP.SeqAli]));

        PSimulP.SeqAli := -1;

      end;

      if (PSimulP.Ration <> -1) and not RationPFound(PSimulP.Ration)

      then

      begin

        Inc(ErrorCount);

        FError.MErrors.Lines.Add(SEP + SEP + Format('%s - %s %d', [PSimulP.Nom, MRationP.Caption, PSimulP.Ration]));

        PSimulP.Ration := -1;

      end;

    end ;

  // Traitement des erreurs

  ok := ErrorCount = 0;

  if not ok

  then

    if ErrorInraAfz

    then

    begin

      FWarning := TFWarning.Create (Self) ;

      with FWarning do

      begin

        Msg := 'InraAfz';

        CBDisplay.Visible := FALSE;

        ShowModal;

        Release;

      end;

    end

    else

      ok := FError.ShowModal = mrYes;

  MAliments.Enabled := ok;

  MTruie.Enabled := ok;

  MPorc.Enabled := ok;

end;

// "Menu Fichier"

procedure TFMenu.MLicenseClick(Sender: TObject);

begin

  FLicense := TFLicense.Create(Self);

  FLicense.ShowModal;

  FLicense.Release;

  // Adaptation taille StatusLine

  FormResize(nil);

end;

procedure TFMenu.MConfigClick(Sender: TObject);

var

  i, typ, mat, typmat, typali: Integer;

//  rec: PRecMatiere;

  FileName: String;

begin

  FConfig := TFConfig.Create(Self);

  if FConfig.ShowModal <> mrOK

  then // chargement de la configuration

    LoadConfig

  else

    if ConfigChanged

    then

    begin

      if NewFolder <> Folder

      then // Changement du dossier de donn?es par d?faut

      begin

        Folder := NewFolder;

        // Fermeture de toutes les fen?tres enfants

        if MDIChildCount > 0

        then

          for i := MDIChildCount - 1 downto 0 do

            MDIChildren[i].Close;

        // Changement de r?pertoire

        SetCurrentDir(Folder);

        // Rechargement des donn?es

        LoadData;

        VerifyData;

        if ((LicenseType = 0) or (LicenseType = 1)) and TooMuchRecords

        then // Trop d'enregistrements

          MessageDlg(MsgTooMuchRecords, mtWarning, [mbOk], 0);

        // Adaptation taille StatusLine

        FormResize(nil);

      end;

      if NewLogo <> Logo

      then // Changement du logo

      begin

        Logo := NewLogo;

        if FileExists(Logo)

        then

          ILogo.Picture.LoadFromFile(Logo)

        else

          ILogo.Picture.LoadFromFile('');

        InvalidateRect(ClientHandle, nil, TRUE);

      end;

      {

      if NewLanguageExt <> LanguageExt

      then // Changement de la langue

      begin

        LanguageExt := NewLanguageExt;

        MessageDlg(MsgLang, mtWarning, [mbOk], 0);

      end;

      }

      if NewLanguageCode <> LanguageCode

      then // Changement de la langue

      begin

        mat := -1;

        typ := -1;

        typmat := -1;

        typali := -1;

        if NumWinMatiere <> -1

        then // Composition mati?re premi?re

          if FMatiere.CBMatiere.ItemIndex <> -1

          then // Sauvegarder la position courante

            mat := FindNumMatiere(FMatiere.CBMatiere.Text);

        if NumWinAliment <> -1

        then // Composition aliment

          typ := FAliment.CBType.ItemIndex;

        if NumWinImpExp <> -1

        then // Import / export

        begin

          typmat := FImpExp.CBTypeMat.ItemIndex;

          typali := FImpExp.CBTypeAli.ItemIndex;

        end;

        LanguageCode := NewLanguageCode;

        UseLanguage(LanguageCode);

        RetranslateComponent(Self);

        if MDIChildCount > 0

        then // Traduction des fen?tres MDI ouvertes

          for i := MDIChildCount - 1 downto 0 do

            RetranslateComponent(MDIChildren[i]);

        // R?affichage des enregistrements pour prendre en compte la traduction

        if NumWinMatiere <> -1

        then // Composition mati?re premi?re

        begin

          StringsMatiere(FMatiere.CBMatiere.Items, 0, TRUE, TRUE);

          if mat <> -1

          then // Res?lectionner l'enregistrement courant

            FMatiere.CBMatiere.ItemIndex := FMatiere.CBMatiere.Items.IndexOf(FindNomMatiere(mat));

          FMatiere.CBMatiereChange(nil);

        end;

        if NumWinAliment <> -1

        then // Composition aliment

        begin

          FAliment.CBType.ItemIndex := typ;

          FAliment.CBTypeChange(nil);

          FAliment.CBAlimentChange(nil);

        end;

        if NumWinImpExp <> -1

        then // Import / export

        begin

          FImpExp.CBTypeMat.ItemIndex := typmat;

          FImpExp.CBTypeMatChange(nil);

          FImpExp.CBTypeAli.ItemIndex := typali;

          FImpExp.CBTypeAliChange(nil);

        end;

        if NumWinSeqAliT <> -1

        then // S?quence alimentaire truie

          FSeqAliT.CBSeqAliChange(nil);

        if NumWinRationT <> -1

        then // Plan de rationnement truie

          FRationT.CBRationChange(nil);

        if NumWinLogeT <> -1

        then // Logement truie

          FLogeT.CBLogeChange(nil);

        if NumWinProfilT <> -1

        then // Profil truie

          FProfilT.CBProfilChange(nil);

        if NumWinSimulT <> -1

        then // Simulation truie

          FSimulT.CBSimulChange(nil);

        {

        if NumWinBesGestT <> -1

        then // Besoin gestation truie

        begin

          FBesGestT.CBLoge.Clear;

          FBesGestT.CBLoge.Items.Add(StrSaisieManuelle);

          if ListLogeT.Count > 0

          then

            for i := 0 to ListLogeT.Count - 1 do

            begin

              PLogeT := ListLogeT[i];

              if LogeTValid(PLogeT)

              then

                FBesGestT.CBLoge.Items.Add(PLogeT.Nom);

            end;

          FBesGestT.CBLoge.ItemIndex := 0;

          FBesGestT.CBLogeChange(nil);

          FBesGestT.CBProfilChange(nil);

        end;

        if NumWinBesGestE <> -1

        then // Besoin gestation ?levage

          FBesGestE.CBProfilChange(nil);

        if NumWinBesLactT <> -1

        then // Besoin lactation truie

          FBesLactT.CBProfilChange(nil);

        if NumWinBesLactE <> -1

        then // Besoin lactation ?levage

          FBesLactE.CBProfilChange(nil);

        }

        if NumWinSeqAliP <> -1

        then // S?quence alimentaire porc

          FSeqAliP.CBSeqAliChange(nil);

        if NumWinRationP <> -1

        then // Plan de rationnement porc

          FRationP.CBRationChange(nil);

        if NumWinProfilP <> -1

        then // Profil porc

          FProfilP.CBProfilChange(nil);

        if NumWinSimulP <> -1

        then // Simulation porc

          FSimulP.CBSimulChange(nil);

        FormResize(nil);

        // Aide

        if Copy(LanguageCode, 1, 2) = 'fr'

        then // Fran?ais

          FileName := ChangeFileExt(Application.ExeName, '_fr.chm')

        else // Anglais

          FileName := ChangeFileExt(Application.ExeName, '_en.chm');

        if FileExists(FileName)

        then

          Application.HelpFile := FileName;

      end;

      SaveConfig;

      if NumWinMatiere <> -1

      then // Composition mati?re premi?re : Mode d'expression

      begin

        FMatiere.AjustCaption;

        FMatiere.AjustDecimals;

        FMatiere.IdxMatiere := -1; // Eviter la sauvegarde automatique

        FMatiere.CBMatiereChange(nil); // R?afficher l'enregistrement

      end ;

      if NumWinAliment <> -1

      then // Composition aliment : Mode d'expression

      begin

        FAliment.AjustCaption;

        FAliment.AjustDecimals;

        FAliment.IdxAliment := -1; // Eviter la sauvegarde automatique

        FAliment.CBAlimentChange(nil); // R?afficher l'enregistrement

      end ;

      if NumWinProfilP <> -1

      then // ProfilP : Caract?ristiques de la carcasse

        FProfilP.PCChange(nil); // Recalculer les simulations

      if NumWinImpExp <> -1

      then // Import / Export : Mode d'expression

        FImpExp.DisplayConfig;

    end;

  FConfig.Release;

end;

procedure TFMenu.MDatasetClick(Sender: TObject);

var

  FileName: String;

begin

  FileName := ExtractFilePath(Application.ExeName) + 'InstData.exe';

  if FileExists(FileName)

  then

    ShellExecute(Handle, 'open', PChar(FileName), nil, nil, SW_SHOWNORMAL);

end;

procedure TFMenu.MFolderClick(Sender: TObject);

var

  i: Integer;

  NewDir: String;

begin

  // Fermeture de toutes les fen?tres enfants

  if MDIChildCount > 0

  then

    for i := MDIChildCount - 1 downto 0 do

      MDIChildren[i].Close;

  // Changement de r?pertoire

  NewDir := GetCurrentDir;

  if SelectDirectory(StrSelectDir, '', NewDir)

  and DirectoryExists(NewDir)

  and (NewDir <> GetCurrentDir)

  then

  begin

    SetCurrentDir(NewDir);

    // Rechargement des donn?es

    LoadData;

    VerifyData;

  end;

  if ((LicenseType = 0) or (LicenseType = 1)) and TooMuchRecords

  then // Trop d'enregistrements

    MessageDlg(MsgTooMuchRecords, mtWarning, [mbOk], 0);

  FormResize(nil);

end;

procedure TFMenu.MExitClick(Sender: TObject);

begin

  Close;

end;

// Menu "Aliment"

procedure TFMenu.MMatiereClick(Sender: TObject);

begin

  if NumWinMatiere < 0

  then // Cr?ation

  begin

    NumWinMatiere := MDIChildCount;

    FMatiere := TFMatiere.Create(Self);

    FMatiere.Show;

  end

  else // Mise au premier plan

    FMatiere.BringToFront;

end;

procedure TFMenu.MAlimentClick(Sender: TObject);

begin

  if NumWinAliment < 0

  then // Cr?ation

  begin

    NumWinAliment := MDIChildCount;

    FAliment := TFAliment.Create(Self);

    FAliment.Show;

  end

  else // Mise au premier plan

    FAliment.BringToFront;

end;

procedure TFMenu.MTarifClick(Sender: TObject);

begin

  if NumWinTarif < 0

  then // Cr?ation

  begin

    NumWinTarif := MDIChildCount;

    FTarif := TFTarif.Create(Self);

    FTarif.Show;

  end

  else // Mise au premier plan

    FTarif.BringToFront;

end;

procedure TFMenu.MImpExpClick(Sender: TObject);

begin

  if NumWinImpExp < 0

  then // Cr?ation

  begin

    NumWinImpExp := MDIChildCount;

    FImpExp := TFImpExp.Create(Self);

    FImpExp.Show;

  end

  else // Mise au premier plan

    FImpExp.BringToFront;

end;

// Menu "Truie reproductrice"

procedure TFMenu.MSeqAliTClick(Sender: TObject);

begin

  if NumWinSeqAliT < 0

  then // Cr?ation

  begin

    NumWinSeqAliT := MDIChildCount;

    FSeqAliT := TFSeqAliT.Create(Self);

    FSeqAliT.Show;

  end

  else // Mise au premier plan

    FSeqAliT.BringToFront;

end;

procedure TFMenu.MRationTClick(Sender: TObject);

begin

  if NumWinRationT < 0

  then // Cr?ation

  begin

    NumWinRationT := MDIChildCount;

    FRationT := TFRationT.Create(Self);

    FRationT.Show;

  end

  else // Mise au premier plan

    FRationT.BringToFront;

end;

procedure TFMenu.MLogeTClick(Sender: TObject);

begin

  if NumWinLogeT < 0

  then // Cr?ation

  begin

    NumWinLogeT := MDIChildCount;

    FLogeT := TFLogeT.Create(Self);

    FLogeT.Show;

  end

  else // Mise au premier plan

    FLogeT.BringToFront;

end;

procedure TFMenu.MProfilTClick(Sender: TObject);

begin

  if NumWinProfilT < 0

  then // Cr?ation

  begin

    NumWinProfilT := MDIChildCount;

    FProfilT := TFProfilT.Create(Self);

    FProfilT.Show;

  end

  else // Mise au premier plan

    FProfilT.BringToFront;

end;

procedure TFMenu.MSimulTClick(Sender: TObject);

begin

  if NumWinSimulT < 0

  then // Cr?ation

  begin

    NumWinSimulT := MDIChildCount;

    FSimulT := TFSimulT.Create(Self);

    FSimulT.Show;

  end

  else // Mise au premier plan

    FSimulT.BringToFront;

end;

procedure TFMenu.MBesGestTClick(Sender: TObject);

begin

  if NumWinBesGestT < 0

  then // Cr?ation

  begin

    NumWinBesGestT := MDIChildCount;

    FBesGestT := TFBesGestT.Create(Self);

    FBesGestT.Show;

  end

  else // Mise au premier plan

    FBesGestT.BringToFront;

end;

procedure TFMenu.MBesGestEClick(Sender: TObject);

begin

  if NumWinBesGestE < 0

  then // Cr?ation

  begin

    NumWinBesGestE := MDIChildCount;

    FBesGestE := TFBesGestE.Create(Self);

    FBesGestE.Show;

  end

  else // Mise au premier plan

    FBesGestE.BringToFront;

end;

procedure TFMenu.MBesLactTClick(Sender: TObject);

begin

  if NumWinBesLactT < 0

  then // Cr?ation

  begin

    NumWinBesLactT := MDIChildCount;

    FBesLactT := TFBesLactT.Create(Self);

    FBesLactT.Show;

  end

  else // Mise au premier plan

    FBesLactT.BringToFront;

end;

procedure TFMenu.MBesLactEClick(Sender: TObject);

begin

  if NumWinBesLactE < 0

  then // Cr?ation

  begin

    NumWinBesLactE := MDIChildCount;

    FBesLactE := TFBesLactE.Create(Self);

    FBesLactE.Show;

  end

  else // Mise au premier plan

    FBesLactE.BringToFront;

end;

// Menu "Porc croissance"

procedure TFMenu.MSeqAliPClick(Sender: TObject);

begin

  if NumWinSeqAliP < 0

  then // Cr?ation

  begin

    NumWinSeqAliP := MDIChildCount;

    FSeqAliP := TFSeqAliP.Create(Self);

    FSeqAliP.Show;

  end

  else // Mise au premier plan

    FSeqAliP.BringToFront;

end;

procedure TFMenu.MRationPClick(Sender: TObject);

begin

  if NumWinRationP < 0

  then // Cr?ation

  begin

    NumWinRationP := MDIChildCount;

    FRationP := TFRationP.Create(Self);

    FRationP.Show;

  end

  else // Mise au premier plan

    FRationP.BringToFront;

end;

procedure TFMenu.MProfilPClick(Sender: TObject);

begin

  if NumWinProfilP < 0

  then // Cr?ation

  begin

    NumWinProfilP := MDIChildCount;

    FProfilP := TFProfilP.Create(Self);

    FProfilP.Show;

  end

  else // Mise au premier plan

    FProfilP.BringToFront;

end;

procedure TFMenu.MSimulPClick(Sender: TObject);

begin

  if NumWinSimulP < 0

  then // Cr?ation

  begin

    NumWinSimulP := MDIChildCount;

    FSimulP := TFSimulP.Create(Self);

    FSimulP.Show;

  end

  else // Mise au premier plan

    FSimulP.BringToFront;

end;

// Menu "Fen?tre"

procedure TFMenu.WindowCascade(Sender: TObject);

begin

  Cascade;

end;

procedure TFMenu.MTileHorizontalClick(Sender: TObject);

begin

  TileMode := tbHorizontal;

  Tile;

end;

procedure TFMenu.MTileVerticalClick(Sender: TObject);

begin

  TileMode := tbVertical;

  Tile;

end;

procedure TFMenu.MMinimizeAllClick(Sender: TObject);

var

  i: Integer;

begin

  if MDIChildCount > 0

  then

    for i := MDIChildCount - 1 downto 0 do

      MDIChildren[i].WindowState := wsMinimized;

end;

procedure TFMenu.MRetoreAllClick(Sender: TObject);

var

  i: Integer;

begin

  if MDIChildCount > 0

  then

    for i := MDIChildCount - 1 downto 0 do

      MDIChildren[i].WindowState := wsNormal;

end;

procedure TFMenu.MArrangeClick(Sender: TObject);

begin

  ArrangeIcons;

end;

// Menu "Aide"

procedure TFMenu.HelpContentsClick(Sender: TObject);

begin

//  Application.HelpCommand(HELP_CONTENTS, 0);

//  HtmlHelp(Application.Handle, PChar(Application.CurrentHelpFile), HH_DISPLAY_TOC, 0);

  Application.HelpShowTableOfContents;

end;

procedure TFMenu.HelpIndexClick(Sender: TObject);

begin

//  Application.HelpCommand(HELP_INDEX, 0);

  HtmlHelp(Application.Handle, PChar(Application.CurrentHelpFile), HH_DISPLAY_INDEX, 0);

end;

procedure TFMenu.MHelpSearchClick(Sender: TObject);

var

  q: THH_Fts_Query;

begin

//  Application.HelpCommand(HELP_FINDER, 0);

  with q do

  begin //D?finition de la requ?te

    cbStruct := SizeOf(q); // Taille de la requ?te

    fUniCodeStrings := False; // Mettre ? true si toute la cha?ne recherch?e est de type Unicode

    pszSearchQuery := nil; // Cha?ne recherch?e

    iProximity := -1; // Recherche en respectant les mots similaires

    fStemmedSearch := False; // Mettre ? true pour rechercher dans les r?sultats pr?c?dents

    fTitleOnly := False; // Mettre ? true si la recherche se fait uniquement sur les titres de rubriques

    fExecute := True; // Mettre ? true pour ex?cuter la requ?te

    pszWindow := nil; // Type de fen?tre ? afficher, ici c'est celle par d?faut

  end;

  HtmlHelp(Application.Handle, PChar(Application.CurrentHelpFile), HH_DISPLAY_SEARCH, DWORD(@q));

end;

procedure TFMenu.MIntroClick(Sender: TObject);

begin

  FIntro := TFIntro.Create(Self);

  FIntro.BBOk.Visible := False;

  FIntro.BBCancel.Visible := False;

  FIntro.BBClose.Visible := True;

  FIntro.ShowModal;

  FIntro.Release;

end;

procedure TFMenu.MWebClick(Sender: TObject);

begin

  ShellExecute(Handle, 'open', PChar(URL_HTTPS), nil, nil, SW_SHOWNORMAL);

end;

procedure TFMenu.MUpdateClick(Sender: TObject);

var

  UpdateURL: string;

begin

  if Copy(LanguageCode, 1, 2) = 'fr'

  then // Fran?ais

    UpdateURL := URL_HTTPS + 'update_fr.php?version=' + VersionString

  else // Anglais

    UpdateURL := URL_HTTPS + 'update_en.php?version=' + VersionString;

  ShellExecute(Handle, 'open', PChar(UpdateURL), nil, nil, SW_SHOWNORMAL);

end;

procedure TFMenu.MAboutClick(Sender: TObject);

begin

  FAbout := TFAbout.Create(Self);

  FAbout.ShowModal;

  FAbout.Release;

end;

end.