InraPorc

unit UFResBesLactT;

interface

uses

  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,

  Dialogs, StdCtrls, Buttons, ExtCtrls, ComCtrls, CheckLst, Menus, Printers, 

  Math, Contnrs, PBNumEdit, PBSuperSpin, Grids, TeEngine, Series, TeeProcs, 

  Chart, TeeEdit, UVariables, gnugettext;

type

  TFResBesLactT = class(TForm)

    PC: TPageControl;

    TabNRJ: TTabSheet;

    TabAA: TTabSheet;

    CBAA1: TComboBox;

    CBAA3: TComboBox;

    CBAA4: TComboBox;

    CBAA2: TComboBox;

    GBAAT: TGroupBox;

    GBAAY: TGroupBox;

    GBAAX: TGroupBox;

    Graph: TChart;

    GBNRJX: TGroupBox;

    GBNRJY: TGroupBox;

    CBNRJ3: TComboBox;

    CBNRJ4: TComboBox;

    GBNRJT: TGroupBox;

    CBNRJ1: TComboBox;

    CBNRJ2: TComboBox;

    LBAA: TListBox;

    LBNRJ: TListBox;

    TSAli: TTabSheet;

    GBAliX: TGroupBox;

    CBAli2: TComboBox;

    PM: TPopupMenu;

    MI3D: TMenuItem;

    MIPreview: TMenuItem;

    MIPrint: TMenuItem;

    PD: TPrintDialog;

    procedure FormClose(Sender: TObject; var Action: TCloseAction);

    procedure FormShow(Sender: TObject);

    procedure PCChange(Sender: TObject);

    procedure CBNRJ1Change(Sender: TObject);

    procedure CBNRJ2Change(Sender: TObject);

    procedure CBNRJ3Change(Sender: TObject);

    procedure CBNRJ4Change(Sender: TObject);

    procedure CBAA1Change(Sender: TObject);

    procedure CBAA2Change(Sender: TObject);

    procedure CBAA3Change(Sender: TObject);

    procedure CBAA4Change(Sender: TObject);

    procedure CBAli2Change(Sender: TObject);

    procedure MI3DClick(Sender: TObject);

    procedure MIPreviewClick(Sender: TObject);

    procedure MIPrintClick(Sender: TObject);

    procedure FormCreate(Sender: TObject);

    procedure WMSysCommand(var Message: TWMSysCommand); message WM_SYSCOMMAND;

  private

    { D?clarations priv?es }

    ListNRJ : TStrings ;

    PieNRJ : TPieSeries ;

    AreaNRJ : array of TAreaSeries ;

    LineNRJ : TLineSeries ;

    ListAA : TStrings ;

    BarAA : THorizBarSeries ;

    AreaAA : array of TAreaSeries ;

    LineAA : TLineSeries ;

    LineAli : array[1..2] of TLineSeries ;

    procedure ResetGraph ;

    procedure InitNRJ ;

    procedure AffGraphNRJ ;

    procedure InitAA ;

    procedure AffGraphAA ;

    procedure InitAli ;

    procedure AffGraphAli ;

  public

    { D?clarations publiques }

  end;

var

  FResBesLactT: TFResBesLactT;

implementation

uses

  UStrings, UFindRec, UUtil, UEchelle, UFBesLactT, UFPrevGraph, UFWarning;

{$R *.dfm}

{ TFResBesLactT }

procedure TFResBesLactT.FormCreate(Sender: TObject);

begin

  if Screen.Fonts.IndexOf('Arial Unicode MS') <> -1

  then

    Font.Name := 'Arial Unicode MS';

  TranslateComponent(Self);

  Constraints.MinWidth := 544 + (Width - ClientWidth);

  Width := 640;

  Constraints.MinHeight := 400 + (Height - ClientHeight);

  Height := 480;

  CBAli2.ItemIndex := 0;

  CBNRJ1.ItemIndex := 0;

  CBNRJ2.ItemIndex := 0;

  CBNRJ3.ItemIndex := 0;

  CBNRJ4.Items.Add(Format('%s/%s', [StrMJ, StrJ]));

  CBNRJ4.Items.Add('%');

  CBNRJ4.ItemIndex := 0;

  CBAA1.ItemIndex := 0;

  CBAA2.ItemIndex := 0;

  CBAA3.ItemIndex := 0;

  CBAA4.Items.Add(Format('%s/%s', [StrG, StrJ]));

  CBAA4.Items.Add(Format('%% %s', [StrBesoin]));

  CBAA4.Items.Add(Format('%s/%s %s', [StrG, StrKg, StrAlimentUnit]));

  CBAA4.Items.Add(Format('%s/%s %s', [StrG, StrMJ, StrED]));

  CBAA4.Items.Add(Format('%s/%s %s', [StrG, StrMJ, StrEM]));

  CBAA4.Items.Add(Format('%s/%s %s', [StrG, StrMJ, StrEN]));

  CBAA4.ItemIndex := 0;

end;

procedure TFResBesLactT.FormShow (Sender : TObject) ;

begin

  MIPrint.Enabled := IsComplete or IsEducation ;

  // Aliment

  InitAli ;

  // Energie

  InitNRJ ;

  // Acides Amin?s

  InitAA ;

  // Affichage principal

  PC.ActivePageIndex := 0 ;

  PCChange (nil) ;

end ;

procedure TFResBesLactT.FormClose (Sender : TObject ; var Action : TCloseAction) ;

var

  i : integer ;

begin

  // Aliment

  for i := 1 to 2 do

    LineAli[i].Free ;

  // Energie

  LineNRJ.Free ;

  for i := 0 to ListNRJ.Count - 1 do

    AreaNRJ[i].Free ;

  SetLength (AreaNRJ, 0) ;

  PieNRJ.Free ;

  ListNRJ.Free ;

  // Acides Amin?s

  LineAA.Free ;

  for i := 0 to ListAA.Count - 1 do

    AreaAA[i].Free ;

  SetLength (AreaAA, 0) ;

  BarAA.Free ;

  ListAA.Free ;

end ;

procedure TFResBesLactT.PCChange (Sender : TObject) ;

begin

  case PC.ActivePageIndex of

    0 : // Aliment

      AffGraphAli ;

    1 : // Energie

      AffGraphNRJ ;

    2 : // Acides Amin?s

      AffGraphAA ;

  end ;

end ;

procedure TFResBesLactT.ResetGraph ;

var

  i : integer ;

begin

  Graph.UndoZoom ;

  Graph.View3D := FALSE ;

  Graph.Legend.Visible := TRUE ;

  Graph.Title.Text.Clear ;

  Graph.SubTitle.Text.Clear ;

  Graph.LeftAxis.Automatic := FALSE ;

  Graph.BottomAxis.MinimumOffset := 0;

  Graph.BottomAxis.MaximumOffset := 0;

  // Aliment

  for i := 1 to 2 do

    LineAli[i].Active := FALSE ;

  // Energie

  PieNRJ.Active := FALSE ;

  for i := 0 to ListNRJ.Count - 1 do

    AreaNRJ[i].Active := FALSE ;

  LineNRJ.Active := FALSE ;

  // Acides Amin?s

  BarAA.Active := FALSE ;

  for i := 0 to ListAA.Count - 1 do

    AreaAA[i].Active := FALSE ;

  LineAA.Active := FALSE ;

end ;

procedure TFResBesLactT.MI3DClick (Sender : TObject) ;

begin

  Graph.View3D := not (Graph.View3D) ;

end ;

procedure TFResBesLactT.MIPreviewClick (Sender : TObject) ;

begin

  FPrevGraph := TFPrevGraph.Create (Self) ;

  with FPrevGraph do

  begin

    TPPGraph.Panels.Add (Graph) ;

    ShowModal ;

    Release ;

  end ;

end ;

procedure TFResBesLactT.MIPrintClick (Sender : TObject) ;

begin

  if PD.Execute

  then

  begin

    Printer.Orientation := poLandscape ;

    Graph.Print ;

  end ;

end ;

/////////////////

//   Aliment   //

/////////////////

procedure TFResBesLactT.InitAli ;

const

  TabColor : array[0..1] of TColor

    = (clBlack, clRed) ;

var

  i : integer ;

begin

  // LineAli : s?ries (lignes) graphiques

  for i := 1 to 2 do

  begin

    LineAli[i] := TLineSeries.Create (Graph) ;

    LineAli[i].ParentChart := Graph ;

    if i = 1

    then // R?f?rence

      LineAli[i].Title := StrReference

    else // Besoin

      LineAli[i].Title := StrBesoin ;

    LineAli[i].SeriesColor := TabColor[i - 1] ;

    LineAli[i].LinePen.Color := LineAli[i].SeriesColor ;

    LineAli[i].LinePen.Width := 2 ;

    Graph.AddSeries (LineAli[i]) ;

  end ;

end ;

procedure TFResBesLactT.AffGraphAli ;

var

  i, j : integer ;

  // Abscisse

  function AliX : double ;

  begin

    case CBAli2.ItemIndex of

      0 : // Dur?e

        result := j - 1 ;

      else

        result := 0 ;

    end ;

  end ;

  // Ordonn?e

  function AliY : double ;

  begin

    case i of

      1 : // R?f?rence

        result := FBesLactT.AppAli[j] ;

      2 : // Besoin

        if (FBesLactT.AppEMTot = 0)

        then

          result := 0

        else

          result := (FBesLactT.BesEMEnt[j] + FBesLactT.BesEMLait[j])

            * FBesLactT.AppAliTot / FBesLactT.AppEMTot ;

      else

        result := 0 ;

    end ;

  end ;

// AffGraphAli

begin

  ResetGraph ;

  Graph.Title.Text.Add (TSAli.Caption) ;

  Graph.LeftAxis.Title.Caption := Format ('%s (%s/%s)', [TSAli.Caption, StrKg, StrJ]) ;

  Graph.BottomAxis.Title.Caption := CBAli2.Text ;

  // Affichage des lignes

  for i := 1 to 2 do

    LineAli[i].Active := TRUE ;

  for i := 1 to 2 do

    LineAli[i].Clear ;

  for i := 1 to 2 do

    for j := 1 to FBesLactT.DureeLact do

      LineAli[i].AddXY (AliX, AliY, '', clTeeColor) ;

  Graph.LeftAxis.Minimum := 0 ;

  Graph.LeftAxis.Increment := 1 ;

  Graph.LeftAxis.MinorTickCount := 9 ;

  Graph.LeftAxis.Maximum := 10 ;

  Graph.LeftAxis.Minimum := 2 ;

  Graph.LeftAxis.AxisValuesFormat := '# ##0' ;

end ;

procedure TFResBesLactT.CBAli2Change(Sender: TObject);

begin

  AffGraphAli ;

end;

/////////////////

//   Energie   //

/////////////////

procedure TFResBesLactT.InitNRJ ;

const

  TabColor : array[0..1] of TColor

    = (clOlive, clWhite) ;

var

  i : integer ;

begin

  // ListNRJ : liste pour l'?nergie

  ListNRJ := TStringList.Create ;

  ListNRJ.Assign (LBNRJ.Items) ;

  // PieNRJ : s?rie (camembert) graphique

  PieNRJ := TPieSeries.Create (Graph) ;

  PieNRJ.ParentChart := Graph ;

  PieNRJ.Marks.ArrowLength := 24 ;

  PieNRJ.Marks.Arrow.Color := clBlack ;

  PieNRJ.Marks.Brush.Style := bsClear ;

  PieNRJ.Marks.Frame.Visible := FALSE ;

  PieNRJ.ValueFormat := Format ('# ##0.0 %s', [StrMJ]) ;

  PieNRJ.PercentFormat := '##0.0 %' ;

  Graph.AddSeries (PieNRJ) ;

  // AreaNRJ : s?ries (aires) graphiques

  SetLength (AreaNRJ, ListNRJ.Count) ;

  for i := 0 to ListNRJ.Count - 1 do

  begin

    AreaNRJ[i] := TAreaSeries.Create (Graph) ;

    AreaNRJ[i].ParentChart := Graph ;

    AreaNRJ[i].Title := ListNRJ[i] ;

    AreaNRJ[i].SeriesColor := TabColor[i] ;

    AreaNRJ[i].AreaLinesPen.Visible := FALSE ;

    Graph.AddSeries (AreaNRJ[i]) ;

  end ;

  // LineNRJ : s?rie (ligne) graphique

  LineNRJ := TLineSeries.Create (Graph) ;

  LineNRJ.ParentChart := Graph ;

  LineNRJ.Title := StrReference ;

  LineNRJ.SeriesColor := clBlack ;

  LineNRJ.LinePen.Color := LineNRJ.SeriesColor ;

  LineNRJ.LinePen.Width := 2 ;

  Graph.AddSeries (LineNRJ) ;

end ;

procedure TFResBesLactT.AffGraphNRJ ;

var

  i, j : integer ;

  y, m, t : double ;

  // Abscisse

  function NRJX : double ;

  begin

    case CBNRJ1.ItemIndex of

      1 : // R?partition dynamique

        case CBNRJ2.ItemIndex of

          0 : // Dur?e

            result := j - 1 ;

          else

            result := 0 ;

        end ;

      else

        result := 0 ;

    end ;

  end ;

  // Ordonn?e

  function NRJY : double ;

  begin

    case CBNRJ1.ItemIndex of

      0 : // R?partition globale

        case i of

          0 : // Entretien

            result := FBesLactT.BesEMEntTot ;

          1 : // Lait

            result := FBesLactT.BesEMLaitTot ;

          else

            result := 0 ;

        end ;

      1 : // R?partition dynamique

        case i of

          -1 : // Apport

            result := FBesLactT.AppEM[j] ;

          0 : // Entretien

            result := FBesLactT.BesEMEnt[j] ;

          1 : // Lait

            result := FBesLactT.BesEMLait[j] ;

          else

            result := 0 ;

        end ;

      else

        result := 0 ;

    end ;

  end ;

// AffGraphNRJ

begin

  ResetGraph ;

  Graph.Title.Text.Add (Format ('%s : %s', [TabNRJ.Caption, CBNRJ1.Text])) ;

  case CBNRJ3.ItemIndex of

    0 : // Energie digestible

      m := FBesLactT.AppEDTot / FBesLactT.AppEMTot ;

    2 : // Energie nette

      m := FBesLactT.AppENTot / FBesLactT.AppEMTot ;

    else

      m := 1 ;

  end ;

  case CBNRJ1.ItemIndex of

    0 : // R?partition globale

    begin

      Graph.View3D := TRUE ;

      Graph.Legend.Visible := FALSE ;

      // Affichage du camembert

      PieNRJ.Active := TRUE ;

      PieNRJ.Clear ;

      if (CBNRJ4.ItemIndex = 1)

      then

        PieNRJ.Marks.Style := smsLabelPercent

      else

        PieNRJ.Marks.Style := smsLabelValue ;

      for i := 0 to ListNRJ.Count - 1 do

      begin

        y := NRJY * m ;

        if (y > PICO)

        then

          PieNRJ.AddPie (y, ListNRJ[i], AreaNRJ[i].SeriesColor) ;

      end ;

      t := FBesLactT.BesEMTot * m ;

      Graph.SubTitle.Text.Add (Format ('%s : %3.1f %s', [StrTotal, t, StrMJ])) ;

    end ;

    1 : // R?partition dynamique

    begin

      Graph.LeftAxis.Title.Caption := Format ('%s (%s)', [CBNRJ3.Text, CBNRJ4.Text]) ;

      Graph.BottomAxis.Title.Caption := CBNRJ2.Text ;

      // Affichage des aires

      for i := 0 to ListNRJ.Count - 1 do

        AreaNRJ[i].Active := TRUE ;

      for i := 0 to ListNRJ.Count - 1 do

        AreaNRJ[i].Clear ;

      if (CBNRJ4.ItemIndex = 1)

      then

        for i := 0 to ListNRJ.Count - 1 do

          AreaNRJ[i].MultiArea := maStacked100

      else

        for i := 0 to ListNRJ.Count - 1 do

          AreaNRJ[i].MultiArea := maStacked ;

      for i := 0 to ListNRJ.Count - 1 do

        for j := 1 to FBesLactT.DureeLact do

          AreaNRJ[i].AddXY (NRJX, NRJY * m, '', clTeeColor) ;

      // Affichage de la ligne

      i := -1 ;

      LineNRJ.Active := TRUE ;

      LineNRJ.Clear ;

      for j := 1 to FBesLactT.DureeLact do

        if (CBNRJ4.ItemIndex = 1)

        then

        begin

          t := FBesLactT.BesEMEnt[j] + FBesLactT.BesEMLait[j] ;

          LineNRJ.AddXY (NRJX, NRJY / t * 100, '', clTeeColor) ;

        end

        else

          LineNRJ.AddXY (NRJX, NRJY * m, '', clTeeColor) ;

    end ;

  end ;

  AjustEchelle (Graph) ;

end ;

procedure TFResBesLactT.CBNRJ1Change (Sender : TObject) ;

begin

  case CBNRJ1.ItemIndex of

    0 : // R?partition globale

      CBNRJ2.Visible := FALSE ;

    1 : // R?partition dynamique

      CBNRJ2.Visible := TRUE ;

  end ;

  AffGraphNRJ ;

end ;

procedure TFResBesLactT.CBNRJ2Change (Sender : TObject) ;

begin

  AffGraphNRJ ;

end ;

procedure TFResBesLactT.CBNRJ3Change (Sender : TObject) ;

begin

  AffGraphNRJ ;

end ;

procedure TFResBesLactT.CBNRJ4Change (Sender : TObject) ;

begin

  AffGraphNRJ ;

end ;

///////////////////////

//   Acides amin?s   //

///////////////////////

procedure TFResBesLactT.InitAA ;

const

  TabColor : array[0..1] of TColor

    = (clOlive, clWhite) ;

var

  i : integer ;

begin

  // ListAA : liste pour les acides amin?s

  ListAA := TStringList.Create ;

  ListAA.Assign (LBAA.Items) ;

  // BarAA : s?rie (barre) graphique

  BarAA := THorizBarSeries.Create (Graph) ;

  BarAA.ParentChart := Graph ;

  BarAA.Title := ' ' ;

  BarAA.SeriesColor := clTeal ;

  BarAA.BarPen.Color := BarAA.SeriesColor ;

  BarAA.Marks.Visible := FALSE ;

  BarAA.MultiBar := mbSide ;

  Graph.AddSeries (BarAA) ;

  // AreaAA : s?ries (aires) graphiques

  SetLength (AreaAA, ListAA.Count) ;

  for i := 0 to ListAA.Count - 1 do

  begin

    AreaAA[i] := TAreaSeries.Create (Graph) ;

    AreaAA[i].ParentChart := Graph ;

    AreaAA[i].Title := ListAA[i] ;

    AreaAA[i].SeriesColor := TabColor[i] ;

    AreaAA[i].AreaLinesPen.Visible := FALSE ;

    Graph.AddSeries (AreaAA[i]) ;

  end ;

  // LineAA : s?rie (ligne) graphique

  LineAA := TLineSeries.Create (Graph) ;

  LineAA.ParentChart := Graph ;

  LineAA.Title := StrReference ;

  LineAA.SeriesColor := clBlack ;

  LineAA.LinePen.Color := LineAA.SeriesColor ;

  LineAA.LinePen.Width := 2 ;

  Graph.AddSeries (LineAA) ;

end ;

procedure TFResBesLactT.AffGraphAA ;

var

  h, i, j : integer ;

  t : double ;

  // Abscisse

  function AAX : double ;

  begin

    case CBAA1.ItemIndex of

      0 : // R?partition dynamique

        case CBAA2.ItemIndex of

          0 : // Dur?e

            result := j - 1 ;

          else

            result := 0 ;

        end ;

      else

        result := 0 ;

    end ;

  end ;

  // Ordonn?e

  function AAY : double ;

  var

    a : integer ;

    d : double ;

  begin

    case h of

      3 : // met+cys

        a := 13 ;

      7 : // phe+tyr

        a := 14 ;

      else

        a := h ;

    end ;

    case CBAA1.ItemIndex of

      0 : // R?partition dynamique

      begin

        // Diviseur

        case CBAA4.ItemIndex of

          2 : // Aliment

            d := FBesLactT.AppAli[j] ;

          3 : // ED

            d := FBesLactT.AppED[j] ;

          4 : // EM

            d := FBesLactT.AppEM[j] ;

          5 : // EN

            d := FBesLactT.AppEN[j] ;

          else

            d := 1 ;

        end ;

        case i of

          -1 : // Apport

            result := FBesLactT.AppAA[a, j] / d ;

          0 : // Entretien

            result := FBesLactT.BesAAEnt[a, j] / d ;

          1 : // Lait

            result := FBesLactT.BesAALait[a, j] / d ;

          else

            result := 0 ;

        end ;

      end ;

      1 : // Besoin

      begin

        // Diviseur

        case CBAA4.ItemIndex of

          1 : // Lysine

            d := Mean (Slice (FBesLactT.BesAA[1], FBesLactT.DureeLact)) / 100 ;

          else

            d := 1 ;

        end ;

        result := Mean (Slice (FBesLactT.BesAA[a], FBesLactT.DureeLact)) / d ;

      end ;

      else

        result := 0 ;

    end ;

  end ;

// AffGraphAA

begin

  ResetGraph ;

  Graph.Title.Text.Add (CBAA1.Text) ;

  Graph.SubTitle.Text.Add(StrDigestStd);

  case CBAA1.ItemIndex of

    0 : // R?partition dynamique

    begin

      Graph.LeftAxis.Title.Caption := Format ('%s (%s)', [CBAA3.Text, CBAA4.Text]) ;

      Graph.BottomAxis.Title.Caption := CBAA2.Text ;

      h := CBAA3.ItemIndex + 1 ;

      // Affichage des aires

      for i := 0 to ListAA.Count - 1 do

        AreaAA[i].Active := TRUE ;

      for i := 0 to ListAA.Count - 1 do

        AreaAA[i].Clear ;

      if (CBAA4.ItemIndex = 1)

      then

        for i := 0 to ListAA.Count - 1 do

          AreaAA[i].MultiArea := maStacked100

      else

        for i := 0 to ListAA.Count - 1 do

          AreaAA[i].MultiArea := maStacked ;

      for i := 0 to ListAA.Count - 1 do

        for j := 1 to FBesLactT.DureeLact do

          AreaAA[i].AddXY (AAX, AAY, '', clTeeColor) ;

      // Affichage de la ligne

      i := -1 ;

      LineAA.Active := TRUE ;

      LineAA.Clear ;

      for j := 1 to FBesLactT.DureeLact do

        if (CBAA4.ItemIndex = 1)

        then

        begin

          case h of

            3 : // met+cys

              t := FBesLactT.BesAA[13, j] ;

            7 : // phe+tyr

              t := FBesLactT.BesAA[14, j] ;

            else

              t := FBesLactT.BesAA[h, j] ;

          end ;

          LineAA.AddXY (AAX, AAY / t * 100, '', clTeeColor) ;

        end

        else

          LineAA.AddXY (AAX, AAY, '', clTeeColor) ;

      AjustEchelle (Graph) ;

    end ;

    1 : // Besoin

    begin

      Graph.Legend.Visible := FALSE ;

      Graph.LeftAxis.Automatic := TRUE ;

      Graph.LeftAxis.Title.Caption := TabAA.Caption ;

      Graph.BottomAxis.Title.Caption :=  Format ('%s (%s)', [StrBesoin, CBAA4.Text]) ;

      // Affichage des barres

      BarAA.Active := TRUE ;

      BarAA.Clear ;

      for h := CBAA3.Items.Count downto 1 do

        BarAA.AddBar (AAY, CBAA3.Items[h - 1], clTeeColor) ;

    end ;

  end ;

end ;

procedure TFResBesLactT.CBAA1Change (Sender : TObject) ;

begin

  CBAA4.Items.Clear ;

  case CBAA1.ItemIndex of

    0 : // R?partition dynamique

    begin

      CBAA2.Visible := TRUE ;

      CBAA3.Visible := TRUE ;

      // Unit?s

      CBAA4.Items.Add (Format ('%s/%s', [StrG, StrJ])) ;

      CBAA4.Items.Add (Format ('%% %s', [StrBesoin])) ;

      CBAA4.Items.Add (Format ('%s/%s %s', [StrG, StrKg, StrAlimentUnit])) ;

      CBAA4.Items.Add (Format ('%s/%s %s', [StrG, StrMJ, StrED])) ;

      CBAA4.Items.Add (Format ('%s/%s %s', [StrG, StrMJ, StrEM])) ;

      CBAA4.Items.Add (Format ('%s/%s %s', [StrG, StrMJ, StrEN])) ;

    end ;

    1 : // Besoin

    begin

      if AffBesoin

      then

      begin

        FWarning := TFWarning.Create (Self) ;

        with FWarning do

        begin

          Msg := 'Besoin';

          ShowModal ;

          Release ;

          AffBesoin := FALSE ;

        end ;

      end ;

      CBAA2.Visible := FALSE ;

      CBAA3.Visible := FALSE ;

      // Unit?s

      CBAA4.Items.Add (Format ('%s/%s', [StrG, StrJ])) ;

      CBAA4.Items.Add (Format ('%% %s', [StrLys])) ;

    end ;

  end ;

  CBAA4.ItemIndex := 0 ;

  AffGraphAA ;

end ;

procedure TFResBesLactT.CBAA2Change (Sender : TObject) ;

begin

  AffGraphAA ;

end ;

procedure TFResBesLactT.CBAA3Change (Sender : TObject) ;

begin

  AffGraphAA ;

end ;

procedure TFResBesLactT.CBAA4Change (Sender : TObject) ;

begin

  AffGraphAA ;

end ;

procedure TFResBesLactT.WMSysCommand(var Message: TWMSysCommand);

begin

  if Message.CmdType = SC_MINIMIZE

  then

    Application.Minimize

  else

    inherited;

end;

end.