InraPorc

unit UFUSB;

interface

uses

  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,

  Dialogs, StdCtrls, Buttons, JvBaseDlg, JvSelectDirectory, ComCtrls;

type

  TFUSB = class(TForm)

    LAjinomoto: TLabel;

    CBAjinomoto: TComboBox;

    LCourse: TLabel;

    ECourse: TEdit;

    LUser: TLabel;

    CBUser: TComboBox;

    LFormationDate: TLabel;

    LFormationPlace: TLabel;

    EFormationDate: TEdit;

    EFormationPlace: TEdit;

    LFirstName: TLabel;

    LLastName: TLabel;

    LCompany: TLabel;

    EFirstName: TEdit;

    ELastName: TEdit;

    ECompany: TEdit;

    GBAjinomoto: TGroupBox;

    GBUser: TGroupBox;

    JvSelectDirectory: TJvSelectDirectory;

    BBNext: TBitBtn;

    EDirectory: TEdit;

    BBDirectory: TBitBtn;

    LFinalDate: TLabel;

    DTPFinalDate: TDateTimePicker;

    LDirectory: TLabel;

    procedure FormCreate(Sender: TObject);

    procedure FormShow(Sender: TObject);

    procedure CBAjinomotoChange(Sender: TObject);

    procedure CBUserChange(Sender: TObject);

    procedure BBDirectoryClick(Sender: TObject);

    procedure BBNextClick(Sender: TObject);

  private

    { D?clarations priv?es }

  public

    { D?clarations publiques }

  end;

var

  FUSB: TFUSB;

implementation

uses

  IniFiles, UFMenu;

{$R *.dfm}

procedure TFUSB.FormCreate(Sender: TObject);

begin

  Top := 0;

  Left := 0;

  DTPFinalDate.DateTime := Now;

end;

procedure TFUSB.FormShow(Sender: TObject);

begin

  CBAjinomoto.Clear;

  with FMenu.TAjinomoto do

  begin

    First;

    while not Eof do

    begin

      CBAjinomoto.Items.Insert(0, FieldByName('Key').AsString);

      Next;

    end;

  end;

  CBAjinomotoChange(nil);

end;

procedure TFUSB.CBAjinomotoChange(Sender: TObject);

var

  i: Integer;

begin

  EFormationDate.Clear;

  EFormationPlace.Clear;

  ECourse.Clear;

  CBUser.Clear;

  CBUserChange(nil);

  if CBAjinomoto.ItemIndex = -1 then Exit;

  with FMenu.TAjinomoto do

    if Locate('Key', CBAjinomoto.Text, [])

    then

    begin

      EFormationDate.Text := FieldByName('FormationDate').AsString;

      EFormationPlace.Text := FieldByName('FormationPlace').AsString;

      ECourse.Text := Format('Formation du %s ? %s', [EFormationDate.Text, EFormationPlace.Text]);

      for i := 1 to FieldByName('Licenses').AsInteger do

        CBUser.Items.Add(Format('%s %s (%s)', [FieldByName(Format('FirstName%d', [i])).AsString, FieldByName(Format('LastName%d', [i])).AsString, FieldByName(Format('Company%d', [i])).AsString]));

    end;

end;

procedure TFUSB.CBUserChange(Sender: TObject);

begin

  EFirstName.Clear;

  ELastName.Clear;

  ECompany.Clear;

  BBNext.Enabled := (CBUser.ItemIndex <> -1) and (Length(EDirectory.Text) > 0);

  if CBUser.ItemIndex = -1 then Exit;

  with FMenu.TAjinomoto do

  begin

    EFirstName.Text := FieldByName(Format('FirstName%d', [CBUser.ItemIndex + 1])).AsString;

    ELastName.Text := FieldByName(Format('LastName%d', [CBUser.ItemIndex + 1])).AsString;

    ECompany.Text := FieldByName(Format('Company%d', [CBUser.ItemIndex + 1])).AsString;

  end;

end;

procedure TFUSB.BBDirectoryClick(Sender: TObject);

begin

  if JvSelectDirectory.Execute

  then

    EDirectory.Text := JvSelectDirectory.Directory;

  BBNext.Enabled := (CBUser.ItemIndex <> -1) and (Length(EDirectory.Text) > 0);

end;

procedure TFUSB.BBNextClick(Sender: TObject);

var

  Lic : TIniFile;

  MajorVersion, MinorVersion, ReleaseVersion, BuildVersion : integer ;

  FileName, VersionString, Drive, Volume, SoftwareEnableKey : string ;

  Buffer : Pointer ;

  Version : PVSFixedFileInfo ;

  BufferSize, VersionSize : DWORD ;

  VolumeSerialNumber, MaximumComponentLength, FileSystemFlags : DWORD ;

begin

  if not DirectoryExists(EDirectory.Text)

  then

  begin

    MessageDlg('Le dossier d''installation n''existe pas !' + sLineBreak + 'V?rifier que la cl? USB a bien ?t? ins?r?e.', mtError, [mbOK], 0);;

    Exit;

  end;

  FileName := IncludeTrailingPathDelimiter(JvSelectDirectory.Directory) + 'InraPorc.exe';

  if not FileExists(FileName)

  then

  begin

    MessageDlg('Le programme InraPorc.exe ne se trouve pas dans ce dossier !', mtError, [mbOK], 0);

    Exit;

  end;

  // Version du programme

  BufferSize := GetFileVersionInfoSize(PChar(FileName), BufferSize);

  if BufferSize > 0

  then

  begin

    GetMem(Buffer, BufferSize);

    GetFileVersionInfo(PChar(FileName), 0, BufferSize, Buffer);

    VerQueryValue(Buffer, '\', Pointer(Version), VersionSize);

    MajorVersion := Version.dwFileVersionMS shr 16;

    MinorVersion := Version.dwFileVersionMS and $FFFF;

    ReleaseVersion := Version.dwFileVersionLS shr 16;

    BuildVersion := Version.dwFileVersionLS and $FFFF;

    FreeMem(Buffer, BufferSize);

    VersionString := Format ('%d.%d.%d.%d', [MajorVersion, MinorVersion, ReleaseVersion, BuildVersion]);

  end ;

  // Num?ro de s?rie du volume

  Drive := IncludeTrailingPathDelimiter(ExtractFileDrive(FileName));

  GetVolumeInformation(PChar(Drive), nil, 0, @VolumeSerialNumber, MaximumComponentLength, FileSystemFlags, nil, 0);

  Volume := IntToHex(HiWord(VolumeSerialNumber), 4) + '-' + IntToHex(LoWord(VolumeSerialNumber), 4);

  // Cl? d'activation

  SoftwareEnableKey := FMenu.EducationKey(VersionString, EFirstName.Text, ELastName.Text, ECompany.Text, Volume, DateToStr(DTPFinalDate.Date));

  // Enregistrement dans la base

  FMenu.MLog.Lines.Add('Recording education...');

  with FMenu.TEducation do

  begin

    Append;

    FieldByName('Date').AsDateTime := Now;

    FieldByName('Version').AsString := VersionString;

    FieldByName('FirstName').AsString := EFirstName.Text;

    FieldByName('LastName').AsString := ELastName.Text;

    FieldByName('Company').AsString := ECompany.Text;

    FieldByName('Course').AsString := ECourse.Text;

    FieldByName('VolumeSerialNumber').AsString := Volume;

    FieldByName('FinalDate').AsString := DateToStr(DTPFinalDate.Date);

    FieldByName('SoftwareEnableKey').AsString := SoftwareEnableKey;

    Post;

  end;

  // Cr?ation du fichier de licence

  FMenu.MLog.Lines.Add('Writing license file...');

  Lic := TIniFile.Create(ChangeFileExt(FileName, '.lic'));

  Lic.WriteInteger('License', 'LicenseType', 1);

  Lic.WriteString('License', 'Version', VersionString);

  Lic.WriteString('License', 'FirstName', EFirstName.Text);

  Lic.WriteString('License', 'LastName', ELastName.Text);

  Lic.WriteString('License', 'Company', ECompany.Text);

  Lic.WriteString('License', 'Course', ECourse.Text);

  Lic.WriteString('License', 'VolumeSerialNumber', Volume);

  Lic.WriteString('License', 'FinalDate', DateToStr(DTPFinalDate.Date));

  Lic.WriteString('License', 'SoftwareEnableKey', SoftwareEnableKey);

  Lic.Free;

  CBUser.ItemIndex := -1;

  CBUserChange(nil);

end;

end.