InraPorc

unit UFPrevRap;

interface

uses

  Windows, Forms, Classes, Controls, Messages, Dialogs, StdCtrls, Buttons,

  ExtCtrls, QuickRpt, QRPrntr;

type

  TQRPrevRapInterface = class(TQRPreviewInterface)

  public

    function Show(AQRPrinter: TQRPrinter): TWinControl; override;

    function ShowModal(AQRPrinter: TQRPrinter): TWinControl; override;

  end;

  TFPrevRap = class(TForm)

    QRPRapport: TQRPreview;

    LBas: TPanel;

    BBPrint: TBitBtn;

    LPrinter: TLabel;

    CBPrinter: TComboBox;

    LPage: TLabel;

    SBPrev: TSpeedButton;

    SBNext: TSpeedButton;

    PPage: TPanel;

    procedure FormShow(Sender: TObject);

    procedure FormClose(Sender: TObject; var Action: TCloseAction);

    procedure BBPrintClick(Sender: TObject);

    procedure CBPrinterChange(Sender: TObject);

    procedure SBPrevClick(Sender: TObject);

    procedure SBNextClick(Sender: TObject);

    procedure QRPRapportPageAvailable(Sender: TObject; PageNum: Integer);

    procedure FormCreate(Sender: TObject);

    procedure WMSysCommand(var Mess: TWMSysCommand); message WM_SYSCOMMAND;

  private

    { D?clarations priv?es }

  public

    { D?clarations publiques }

    constructor CreatePreview(AOwner: TComponent; AQRPrinter: TQRPrinter); virtual;

  end;

var

  FPrevRap: TFPrevRap;

implementation

uses

  Printers, SysUtils, gnugettext, UStrings, UUtil;

{$R *.dfm}

{TQRPrevRapInterface}

function TQRPrevRapInterface.Show(AQRPrinter: TQRPrinter): TWinControl;

begin

  Result := TFPrevRap.CreatePreview(Self, AQRPrinter);

  TFPrevRap(Result).Show;

end;

function TQRPrevRapInterface.ShowModal(AQRPrinter: TQRPrinter): TWinControl;

begin

  Result := TFPrevRap.CreatePreview(Self, AQRPrinter);

  TFPrevRap(Result).ShowModal;

end;

{TFPrevRap}

constructor TFPrevRap.CreatePreview(AOwner: TComponent; AQRPrinter: TQRPrinter);

begin

  inherited Create(AOwner);

  QRPRapport.QRPrinter := AQRPrinter;

end;

procedure TFPrevRap.FormCreate(Sender: TObject);

begin

  if Screen.Fonts.IndexOf('Arial Unicode MS') <> -1

  then

    Font.Name := 'Arial Unicode MS';

  TranslateComponent(Self);

end;

procedure TFPrevRap.FormClose(Sender: TObject; var Action: TCloseAction);

begin

  QRPRapport.QRPrinter.ClosePreview(Self);

  Application.ProcessMessages;

  Action := caFree;

end;

procedure TFPrevRap.FormShow(Sender: TObject);

begin

  BBPrint.Enabled := IsComplete or IsEducation ;

  CBPrinter.Items.Assign(Printer.Printers);

  CBPrinter.ItemIndex := Printer.PrinterIndex;

end;

procedure TFPrevRap.QRPRapportPageAvailable(Sender: TObject;

  PageNum: Integer);

begin

  with QRPRapport do

    LPage.Caption := Format(StrPage, [PageNumber, PageNum]);

end;

procedure TFPrevRap.BBPrintClick(Sender: TObject);

var

  oldQRPrinter: TQRPrinter;

begin

  oldQRPrinter := QRPRapport.QRPrinter;

  TQuickRep(QRPRapport.QRPrinter.ParentReport).Print;

  QRPRapport.QRPrinter := oldQRPrinter;

end;

procedure TFPrevRap.CBPrinterChange(Sender: TObject);

begin

  Printer.PrinterIndex := CBPrinter.ItemIndex;

  TCustomQuickRep(QRPRapport.QRPrinter.ParentReport).PrinterSettings.PrinterIndex := Printer.PrinterIndex;

end;

procedure TFPrevRap.SBPrevClick(Sender: TObject);

begin

  with QRPRapport do

    if PageNumber > 1

    then

      PageNumber := PageNumber - 1

    else

      Beep;

  with QRPRapport do

    LPage.Caption := Format('Page %d / %d', [PageNumber, QRPrinter.PageCount]);

end;

procedure TFPrevRap.SBNextClick(Sender: TObject);

begin

  with QRPRapport do

    if PageNumber < QRPrinter.PageCount

    then

      PageNumber := PageNumber + 1

    else

      Beep;

  with QRPRapport do

    LPage.Caption := Format('Page %d / %d', [PageNumber, QRPrinter.PageCount]);

end;

procedure TFPrevRap.WMSysCommand(var Mess: TWMSysCommand);

begin

  if Mess.CmdType = SC_MINIMIZE

  then

    Application.Minimize

  else

    inherited;

end;

end.