InraPorc

[ISPP]

#define Project "InraPorc"

#define Publisher "INRAE"

#define URL "https://inraporc.inra.fr/inraporc/"

; Version

#define Major

#define Minor

#define Release

#define Build

#expr ParseVersion(SourcePath + '\..\' + Project + '.exe',Major,Minor,Release,Build)

[Setup]

; Compiller

PrivilegesRequired=none

OutputBaseFilename={#Project}Setup

OutputDir=.

VersionInfoCompany={#Publisher}

VersionInfoDescription={#Project} Setup

VersionInfoVersion={#Major}.{#Minor}.{#Release}.{#Build}

; Installer

AppMutex={#Project}

AppName={#Project}

AppVerName={cm:NameAndVersion,{#Project},{#Major}.{#Minor}.{#Release}.{#Build}}

AppVersion={#Major}.{#Minor}.{#Release}.{#Build}

AppPublisher={#Publisher}

AppPublisherURL={#URL}

DefaultDirName={code:DefDirRoot}\{#Project}

DefaultGroupName={#Project}

AllowNoIcons=true

[Languages]

Name: en; MessagesFile: compiler:Default.isl

Name: fr; MessagesFile: compiler:Languages\French.isl

[CustomMessages]

en.LangPath=EN

fr.LangPath=FR

en.InstData=Install a new dataset

en.LaunchInstData=Install a dataset right now

fr.InstData=Installer un nouveau jeu de donn?es

fr.LaunchInstData=Installer un jeu de donn?es d?s maintenant

[Tasks]

Name: desktopicon; Description: {cm:CreateDesktopIcon}; GroupDescription: {cm:AdditionalIcons}

Name: quicklaunchicon; Description: {cm:CreateQuickLaunchIcon}; GroupDescription: {cm:AdditionalIcons}; Flags: unchecked

[Files]

Source: ..\{#Project}.exe; DestDir: {app}; Flags: ignoreversion

Source: ..\dmath.dll; DestDir: {app}; Flags: promptifolder

Source: ..\sqlite3.dll; DestDir: {app}; Flags: promptifolder

Source: ..\libeay32.dll; DestDir: {app}; Flags: promptifolder

Source: ..\ssleay32.dll; DestDir: {app}; Flags: promptifolder

Source: S:\SG-prj-Inraporc\INRA-AFZ\InraAfz.rec; DestDir: {app}; Flags: promptifolder

Source: S:\SG-prj-Inraporc\Help\HTML Help\{#Project}_fr.chm; DestDir: {app}; Flags: promptifolder

Source: S:\SG-prj-Inraporc\Help\HTML Help\{#Project}_en.chm; DestDir: {app}; Flags: promptifolder

Source: InstData.exe; DestDir: {app}; Flags: ignoreversion

[INI]

Filename: {app}\{#Project}.url; Section: InternetShortcut; Key: URL; String: {#URL}

[Icons]

Name: {group}\{#Project}; Filename: {app}\{#Project}.exe; WorkingDir: {app}

Name: {group}\{cm:ProgramOnTheWeb,{#Project}}; Filename: {app}\{#Project}.url; WorkingDir: {app}

Name: {group}\{cm:UninstallProgram,{#Project}}; Filename: {uninstallexe}; WorkingDir: {app}

Name: {group}\{cm:InstData}; Filename: {app}\InstData.exe; WorkingDir: {app}

Name: {userdesktop}\{#Project}; Filename: {app}\{#Project}.exe; WorkingDir: {app}; Tasks: desktopicon

Name: {userappdata}\Microsoft\Internet Explorer\Quick Launch\{#Project}; Filename: {app}\{#Project}.exe; WorkingDir: {app}; Tasks: quicklaunchicon

[Run]

Filename: {app}\InstData.exe; Description: {cm:LaunchInstData}; Flags: nowait postinstall skipifsilent

[Registry]

Root: HKU; Subkey: Software\Borland\Locale; ValueName: {app}\{#Project}.exe; Flags: deletevalue

[InstallDelete]

Type: files; Name: {app}\{#Project}\{#Project}.DEU

Type: files; Name: {app}\{#Project}\{#Project}.ENG

Type: files; Name: {app}\{#Project}\{#Project}.ENU

Type: files; Name: {app}\{#Project}\{#Project}.ESP

Type: files; Name: {app}\{#Project}\{#Project}.ITA

Type: files; Name: {app}\{#Project}\{#Project}.NLD

Type: files; Name: {app}\{#Project}\{#Project}.PLK

Type: files; Name: {app}\{#Project}\{#Project}.PTB

Type: files; Name: {app}\{#Project}\{#Project}_ENG.chm

Type: files; Name: {app}\{#Project}\{#Project}_ENU.chm

Type: files; Name: {app}\{#Project}\{#Project}_FRA.chm

[UninstallDelete]

Type: files; Name: {app}\{#Project}.url

[Code]

function IsRegularUser(): Boolean;

begin

  Result := not (IsAdminLoggedOn or IsPowerUserLoggedOn);

end;

function DefDirRoot(Param: String): String;

begin

  if IsRegularUser then

    Result := ExpandConstant('{localappdata}')

  else

    Result := ExpandConstant('{pf}')

end;