InraPorc

unit UFInvoice;

interface

uses

  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,

    Dialogs, StdCtrls, PBNumEdit, Buttons, ComCtrls, IniFiles, IdMessage,

    IdBaseComponent, IdComponent, IdTCPConnection, IdTCPClient,

    IdMessageClient, IdAttachmentFile, IdSMTP, DateUtils,

    IdExplicitTLSClientServerBase, IdSMTPBase, IdIMAP4, IdIOHandler,

  IdIOHandlerSocket, IdIOHandlerStack, IdSSL, IdSSLOpenSSL;

type

  TFInvoice = class(TForm)

    CBOrder: TComboBox;

    LOrder: TLabel;

    LPayment: TLabel;

    DTPPayment: TDateTimePicker;

    BBNext: TBitBtn;

    LLicenses: TLabel;

    PBLicenses: TPBNumEdit;

    MObservations: TMemo;

    SMTP: TIdSMTP;

    MKey: TIdMessage;

    IMAP4: TIdIMAP4;

    OpenSSL_IMAP4: TIdSSLIOHandlerSocketOpenSSL;

    OpenSSL_SMTP: TIdSSLIOHandlerSocketOpenSSL;

    procedure CBOrderChange(Sender: TObject);

    procedure BBNextClick(Sender: TObject);

    procedure FormShow(Sender: TObject);

    procedure FormCreate(Sender: TObject);

  private

    { D?clarations priv?es }

    procedure ClearInvoice;

  public

    { D?clarations publiques }

  end;

var

  FInvoice: TFInvoice;

implementation

uses

  UFMenu;

{$R *.dfm}

procedure TFInvoice.FormCreate(Sender: TObject);

begin

  Top := 0;

  Left := 0;

  DTPPayment.DateTime := Now;

  with IMAP4 do

  begin

    Host := IMAP_SERVER;

//    Username := EXCHANGE_USERNAME + '\' + EXCHANGE_SHARED_MAILBOX;

    Username := 'INRA\' + FMenu.EUsername.Text + '\' + EXCHANGE_SHARED_MAILBOX;

//    Password := EXCHANGE_PASSWORD;

    Password := FMenu.EPassword.Text;

  end;

  with SMTP do

  begin

    Host := SMTP_SERVER;

//    Username := EXCHANGE_USERNAME;

    Username := 'INRA\' + FMenu.EUsername.Text;

//    Password := EXCHANGE_PASSWORD;

    Password := FMenu.EPassword.Text;

  end;

end;

procedure TFInvoice.FormShow(Sender: TObject);

begin

  CBOrder.Clear;

  with FMenu.TOrder do

  begin

    First;

    while not Eof do

    begin

      if FieldByName('Payment').IsNull

      then

        CBOrder.Items.Add(FieldByName('Key').AsString);

      Next;

    end;

  end;

  ClearInvoice;

end;

procedure TFInvoice.CBOrderChange(Sender: TObject);

begin

  if CBOrder.ItemIndex = -1 then Exit;

  with FMenu.TOrder do

    if FindKey([CBOrder.Text])

    then

    begin

      PBLicenses.AsInteger := FieldByName('Licenses').AsInteger;

      BBNext.Enabled := PBLicenses.AsInteger > 0;

      ActiveControl := DTPPayment;

    end;

end;

procedure TFInvoice.BBNextClick(Sender: TObject);

var

  n: Integer;

  f: TIniFile;

  StrMessage: TStrings;

begin

  FMenu.MLog.Lines.Add('Updating order...');

  with FMenu.TOrder do

  begin

    Edit;

    FieldByName('Payment').AsDateTime := DTPPayment.Date;

    Post;

  end;

  FMenu.MLog.Lines.Add('Updating licenses...');

  n := 0;

  with FMenu.TLicense do

    if Locate('Type;Source', VarArrayOf([0, CBOrder.Text]), [])

    then

      repeat

        Inc(n);

        Edit;

        FieldByName('Validity').AsBoolean := True;

        if not FieldByName('Mail').IsNull

        and (FieldByName('FinalDate').AsDateTime < FMenu.DateLimite)

        then // Envoyer une cl? de licence

        begin

          FieldByName('FinalDate').AsDateTime := FMenu.DateLimite;

          FieldByName('SoftwareEnableKey').AsString := FMenu.CompleteKey(FieldByName('LicenseNumber').AsInteger, FieldByName('Version').AsString, FieldByName('FirstName').AsString, FieldByName('LastName').AsString, FieldByName('Company').AsString, FieldByName('VolumeSerialNumber').AsString, DateToStr(FMenu.DateLimite));

          try

            f := TIniFile.Create(TempFolder + '\InraPorc.lic');

            f.WriteInteger ('License', 'LicenseType', 2);

            f.WriteInteger ('License', 'LicenseNumber', FieldByName('LicenseNumber').AsInteger) ;

            f.WriteString ('License', 'Version', FieldByName('Version').AsString);

            f.WriteString ('License', 'FirstName', FieldByName('FirstName').AsString);

            f.WriteString ('License', 'LastName', FieldByName('LastName').AsString);

            f.WriteString ('License', 'Company', FieldByName('Company').AsString);

            f.WriteString ('License', 'Address1', FieldByName('Address1').AsString);

            f.WriteString ('License', 'Address2', FieldByName('Address2').AsString);

            f.WriteString ('License', 'PostalCode', FieldByName('PostalCode').AsString);

            f.WriteString ('License', 'City', FieldByName('City').AsString);

            f.WriteString ('License', 'Country', FieldByName('Country').AsString);

            f.WriteString ('License', 'Phone', FieldByName('Phone').AsString);

            f.WriteString ('License', 'Fax', FieldByName('Fax').AsString);

            f.WriteString ('License', 'Mail', FieldByName('Mail').AsString);

            f.WriteString ('License', 'VolumeSerialNumber', FieldByName('VolumeSerialNumber').AsString);

            f.WriteString ('License', 'FinalDate', DateToStr(FieldByName('FinalDate').AsDateTime));

            f.WriteString ('License', 'SoftwareEnableKey', FieldByName('SoftwareEnableKey').AsString);

            f.Free;

            FMenu.MLog.Lines.Add('Mailing to ' + FieldByName('Mail').AsString + '...');

            with MKey do

            begin

              Body.Clear;

              MessageParts.Clear;

              From.Name := 'InraPorc';

              From.Address := MAIL_INRAPORC;

              Recipients.EMailAddresses := FieldByName('Mail').AsString;

              StrMessage := TStringList.Create;

              if FieldByName('Language').AsString = 'FR'

              then // R?ponse (fran?ais)

              begin

                Subject := Format('[InraPorc] Cl? d''activation pour licence num?ro %d', [FieldByName('LicenseNumber').AsInteger]);

                StrMessage.LoadFromFile(SHARED_DRIVE + SHARED_FOLDER + 'Messages\Facture_FR.txt');

                Body.AddStrings(StrMessage);

                Body.Add(Format('La cl? d''activation est valable jusqu''au %s.', [DateToStr(FieldByName('FinalDate').AsDateTime)]));

                Body.Add('Un nouveau fichier de licence vous sera automatiquement envoy? avant la date d''expiration.');

                Body.Add('');

                StrMessage.LoadFromFile(SHARED_DRIVE + SHARED_FOLDER + 'Messages\Signature_FR.txt');

                Body.AddStrings(StrMessage);

              end

              else // Reply (english)

              begin

                Subject := Format('[InraPorc] Software enable key for license number %d', [FieldByName('LicenseNumber').AsInteger]);

                StrMessage.LoadFromFile(SHARED_DRIVE + SHARED_FOLDER + 'Messages\Facture_EN.txt');

                Body.AddStrings(StrMessage);

                Body.Add(Format('The license activation key is valid until %s.', [DateToStr(FieldByName('FinalDate').AsDateTime)]));

                Body.Add('You will automatically receive a new license file before the expiration date.');

                Body.Add('');

                StrMessage.LoadFromFile(SHARED_DRIVE + SHARED_FOLDER + 'Messages\Signature_EN.txt');

                Body.AddStrings(StrMessage);

              end;

              StrMessage.Free;

              if FileExists(TempFolder + '\InraPorc.lic')

              then

                TIdAttachmentFile.Create(MessageParts, TempFolder + '\InraPorc.lic')

              else

                FMenu.MLog.Lines.Add('File InraPorc.lic could not be attached !');

            end;

            FMenu.MLog.Lines.Add('SMTP...');

            try

              SMTP.Connect;

              try

                SMTP.Send(MKey);

              finally

                SMTP.Disconnect;

                if IMAP4.Connect

                then

                  try

                    if not IMAP4.AppendMsg('?l?ments envoy?s', MKey, MKey.LastGeneratedHeaders)

                    then

                      FMenu.MLog.Lines.Add('Message could not be copied in IMAP server !');

                  finally

                    IMAP4.Disconnect;

                  end

                else

                  FMenu.MLog.Lines.Add('IMAP server could not be connected !');

              end;

            except

              FMenu.MLog.Lines.Add('Message could not be sent !');

            end;

            if not DeleteFile(TempFolder + '\InraPorc.lic')

            then

              FMenu.MLog.Lines.Add('File InraPorc.lic could not be deleted !');

          except

            FMenu.MLog.Lines.Add('File InraPorc.lic could not be created !');

          end;

        end;

        Post;

        Next;

      until Eof or (FieldByName('Type').AsInteger <> 0) or (FieldByName('Source').AsString <> CBOrder.Text);

  if n <> PBLicenses.AsInteger

  then

    FMenu.MLog.Lines.Add(Format('%d licenses updated / %d expected !', [n, PBLicenses.AsInteger]));

  FMenu.MLog.Lines.Add('Logging record...');

  with FMenu.TInvoices do

  begin

    Append;

    FieldByName('Date').AsDateTime := Now;

    FieldByName('Admin').AsString := FMenu.EAdmin.Text;

    FieldByName('Order').AsString := CBOrder.Text;

    FieldByName('Payment').AsDateTime := DTPPayment.Date;

    FieldByName('Observations').AsString := MObservations.Text;

    Post;

  end;

  CBOrder.DeleteSelected;

  ClearInvoice;

end;

procedure TFInvoice.ClearInvoice;

begin

  BBNext.Enabled := False;

  CBOrder.Hint := Format('%d factures en attente / %d commandes', [CBOrder.Items.Count, FMenu.TOrder.RecordCount]);

  PBLicenses.Text := '';

  MObservations.Clear;

  ActiveControl := CBOrder;

end;

end.