InraPorc

unit UFSeqAliP ;

interface

uses

  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,

  Dialogs, StdCtrls, ExtCtrls, Buttons, PBNumEdit, JvExControls, JvComponent, 

  JvEnterTab, UVariables, gnugettext;

type

  TFSeqAliP = class(TForm)

    GBAli: TGroupBox;

    CBSeqAli: TComboBox;

    LBRule: TListBox;

    LNo: TLabel;

    LModeFin: TLabel;

    CBTwoAli: TCheckBox;

    CBTransit: TCheckBox;

    CBAli1: TComboBox;

    LInit: TLabel;

    LFin: TLabel;

    PBAli1Init: TPBNumEdit;

    PBAli1Fin: TPBNumEdit;

    PBAli2Init: TPBNumEdit;

    PBAli2Fin: TPBNumEdit;

    GBSeqAli: TGroupBox;

    CBAli2: TComboBox;

    GBRule: TGroupBox;

    SBAddRule: TSpeedButton;

    SBDelRule: TSpeedButton;

    SBAddSeqAli: TSpeedButton;

    SBDelSeqAli: TSpeedButton;

    LAli: TLabel;

    LAli1: TLabel;

    LAli2: TLabel;

    LAli1Init: TLabel;

    LAli1Fin: TLabel;

    LAli2Init: TLabel;

    LAli2Fin: TLabel;

    PInit: TPanel;

    PFin: TPanel;

    SBRename: TSpeedButton;

    SBComment: TSpeedButton;

    GBEnd: TGroupBox;

    LUnitFin: TLabel;

    PBValFin: TPBNumEdit;

    CBModeFin: TComboBox;

    PSeqAli: TPanel;

    GBParam: TGroupBox;

    SBSave: TSpeedButton;

    SBPrint: TSpeedButton;

    JvEnterAsTab: TJvEnterAsTab;

    procedure FormShow(Sender: TObject);

    procedure FormClose(Sender: TObject; var Action: TCloseAction);

    procedure LBRuleDrawItem(Control: TWinControl; Index: Integer;

      Rect: TRect; State: TOwnerDrawState);

    procedure CBSeqAliChange(Sender: TObject);

    procedure SBAddSeqAliClick(Sender: TObject);

    procedure SBDelSeqAliClick(Sender: TObject);

    procedure SBAddRuleClick(Sender: TObject);

    procedure SBDelRuleClick(Sender: TObject);

    procedure LBRuleClick(Sender: TObject);

    procedure CBTwoAliClick(Sender: TObject);

    procedure CBTransitClick(Sender: TObject);

    procedure PBAli1InitChange(Sender: TObject);

    procedure PBAli1FinChange(Sender: TObject);

    procedure CBAli1Change(Sender: TObject);

    procedure CBAli2Change(Sender: TObject);

    procedure FormActivate(Sender: TObject);

    procedure FormDeactivate(Sender: TObject);

    procedure SBRenameClick(Sender: TObject);

    procedure SBCommentClick(Sender: TObject);

    procedure CBModeFinChange(Sender: TObject);

    procedure PBValFinChange(Sender: TObject);

    procedure SBSaveClick(Sender: TObject);

    procedure SBPrintClick(Sender: TObject);

    procedure FormCreate(Sender: TObject);

  private

    { D?clarations priv?es }

    Update, Modified : boolean ;

    IdxSeqAliP, NumRule : integer ;

    procedure Save ;

  public

    { D?clarations publiques }

    function StrModeFin (n : integer) : string ;

    function StrAliment (n : integer) : string ;

  end;

var

  FSeqAliP: TFSeqAliP;

implementation

uses

  UStrings, UInit, UUtil, UFindRec, UEchelle, UFComment, UFRapSeqAliP ;

{$R *.dfm}

{ TFSeqAliP }

procedure TFSeqAliP.FormCreate(Sender: TObject);

begin

  if Screen.Fonts.IndexOf('Arial Unicode MS') <> -1

  then

    Font.Name := 'Arial Unicode MS';

  TranslateComponent(Self);

  Constraints.MinWidth := 616 + (Width - ClientWidth);

  Width := Constraints.MinWidth;

  Constraints.MinHeight := 432 + (Height - ClientHeight);

  Height := Constraints.MinHeight;

end;

procedure TFSeqAliP.FormShow (Sender : TObject) ;

begin

  Modified := FALSE ;

  StringsSeqAliP (CBSeqAli.Items, TRUE) ;

  SBAddSeqAli.Enabled := IsComplete or (ListSeqAliP.Count < 5) ;

  SBSave.Enabled := IsComplete or IsEducation ;

  IdxSeqAliP := -1 ;

//  CBSeqAliChange (nil) ;

end ;

procedure TFSeqAliP.FormClose (Sender : TObject ; var Action : TCloseAction) ;

begin

  if Modified then Save ;

  Action := caFree ;

  NumWinSeqAliP := -1 ;

end ;

procedure TFSeqAliP.FormActivate (Sender : TObject) ;

var

  i : integer ;

begin

  CBAli1.Clear ;

  CBAli2.Clear ;

  if ListAliment.Count > 0

  then

    for i := 0 to ListAliment.Count - 1 do

    begin

      PAliment := ListAliment[i] ;

      if AlimentValid (PAliment) and (PAliment.Typ <> 2)

      then

      begin

        CBAli1.Items.Add (PAliment.Nom) ;

        CBAli2.Items.Add (PAliment.Nom) ;

      end ;

    end ;

//  if IdxSeqAliP <> -1

//  then

//  begin

//    PSeqAliP := ListSeqAliP[IdxSeqAliP] ;

//    with PSeqAliP.Rule[NumRule] do

//    begin

//      if NumAli1 <> -1

//      then

//        CBAli1.ItemIndex := CBAli1.Items.IndexOf (FindNomAliment (NumAli1)) ;

//      if NumAli2 <> -1

//      then

//        CBAli2.ItemIndex := CBAli2.Items.IndexOf (FindNomAliment (NumAli2)) ;

//    end ;

//  end ;

  CBSeqAliChange (nil) ;

  PSeqAli.Enabled := IsComplete or IsEducation or IsEvaluation ;

  SBAddRule.Visible := PSeqAli.Enabled ;

  SBDelRule.Visible := PSeqAli.Enabled ;

end ;

procedure TFSeqAliP.FormDeactivate (Sender : TObject) ;

begin

  if Modified then Save ;

end ;

procedure TFSeqAliP.Save ;

var

  s : string ;

begin

  Modified := FALSE ;

  if IsComplete or IsEducation

  then

    if MessageDlg (Caption + sLineBreak + MsgSave, mtConfirmation, [mbYes, mbNo], 0) = mrYes

    then

    begin

      SaveSeqAliP ;

      if not SeqAliPValid (PSeqAliP)

      then

        MessageDlg(Format (MsgInvalidData, [Caption, PSeqAliP.Nom]), mtWarning, [mbOK], 0) ;

    end

    else

    begin

      LoadSeqAliP ;

      s := CBSeqAli.Text ;

      StringsSeqAliP (CBSeqAli.Items, TRUE) ;

      if FindIdxSeqAliP (s) = -1

      then

      begin

        IdxSeqAliP := -1 ;

        CBSeqAliChange (nil) ;

      end

      else

        CBSeqAli.ItemIndex := CBSeqAli.Items.IndexOf (s) ;

    end ;

end ;

procedure TFSeqAliP.CBSeqAliChange (Sender : TObject) ;

var

  i : integer ;

begin

  if (IdxSeqAliP <> -1) and (CBSeqAli.Text <> PSeqAliP.Nom)

  then

    if Modified then Save ;

  IdxSeqAliP := FindIdxSeqAliP (CBSeqAli.Text) ;

  LBRule.Clear ;

  if IdxSeqAliP = -1

  then

  begin

    CBSeqAli.Repaint ;

    SBDelSeqAli.Enabled := FALSE ;

    SBRename.Enabled := FALSE ;

    SBComment.Enabled := FALSE ;

    SBSave.Enabled := FALSE ;

    SBPrint.Enabled := FALSE ;

    PSeqAli.Visible := FALSE ;

  end

  else // Affichage de l'enregistrement

  begin

    SBDelSeqAli.Enabled := TRUE ;

    SBRename.Enabled := TRUE ;

    SBComment.Enabled := TRUE ;

    SBSave.Enabled := TRUE ;

    SBPrint.Enabled := TRUE ;

    PSeqAli.Visible := TRUE ;

    PSeqAliP := ListSeqAliP[IdxSeqAliP] ;

    with PSeqAliP^ do

      CBSeqAli.Hint := Memo ;

    with PSeqAliP^ do

      for i := 1 to NbRule do

        LBRule.Items.Add ('') ;

    LBRule.ItemIndex := 0 ;

    LBRuleClick (nil) ;

  end ;

end ;

procedure TFSeqAliP.SBAddSeqAliClick (Sender : TObject) ;

var

  i, n, q : integer ;

  s : string ;

  ok : boolean ;

  PBackup : PRecSeqAliP ;

begin

  if Modified then Save ;

  if IdxSeqAliP = -1

  then

    q := mrNo

  else

    q := MessageDlg (MsgCopy, mtConfirmation, [mbYes, mbNo], 0) ;

  // Saisie du nouveau nom

  s := '' ;

  repeat

    if InputQuery (FSeqAliP.Caption, MsgName, s)

    then // V?rification du nom

    begin

      s := Trim (s) ; // Suppression des espaces au d?but et ? la fin

      if s = ''

      then // Pas de nom

      begin

        ok := FALSE ;

        MessageDlg (MsgNameEmpty, mtWarning, [mbOk], 0) ;

      end

      else

        if Length (s) > 25

        then // Nom trop long

        begin

          ok := FALSE ;

          MessageDlg (Format (MsgNameTooLarge, [25]), mtWarning, [mbOk], 0) ;

          s := Copy (s, 1, 25) ;

        end

        else

        begin

          ok := TRUE ;

          i := 0 ;

          while ok and (i < ListSeqAliP.Count) do

          begin

            PSeqAliP := ListSeqAliP[i] ;

            if PSeqAliP.Nom = s

            then // Nom d?j? utilis?

            begin

              ok := FALSE ;

              MessageDlg (MsgNameExists, mtWarning, [mbOk], 0) ;

            end

            else

              Inc (i) ;

          end ;

        end ;

    end

    else // Annulation

    begin

      s := '' ;

      if (IdxSeqAliP <> -1)

      then

        PSeqAliP := ListSeqAliP[IdxSeqAliP] ;

      ok := TRUE ;

    end ;

  until ok ;

  if s <> ''

  then // Cr?ation du nouvel enregistrement

  begin

    // Recherche du premier num?ro libre

    n := 0 ;

    repeat

      Inc (n) ;

      ok := TRUE ;

      i := 0 ;

      while ok and (i < ListSeqAliP.Count) do

      begin

        PSeqAliP := ListSeqAliP[i] ;

        if PSeqAliP.Num = n

        then

          ok := FALSE

        else

          Inc (i) ;

      end ;

    until ok ;

    New (PSeqAliP) ;

    with PSeqAliP^ do

    begin

      Nom := s ;

      Num := n ;

      if q = mrYes

      then

      begin

        PBackup := ListSeqAliP[IdxSeqAliP] ;

        Memo := PBackup.Memo ;

        NbRule := PBackup.NbRule ;

        Rule := PBackup.Rule ;

      end

      else

      begin

        Memo := '' ;

        NbRule := 1 ;

        for i := 1 to MAX_RULE do

          with Rule[i] do

          begin

            ModeFin := -1 ;

            ValFin := 0 ;

            NumAli1 := -1 ;

            NumAli2 := -1 ;

            PctAli1Init := 100 ;

            PctAli1Fin := 100 ;

          end ;

      end ;

    end ;

    ListSeqAliP.Add (PSeqAliP) ;

    CBSeqAli.Items.Add (PSeqAliP.Nom) ;

    CBSeqAli.ItemIndex := CBSeqAli.Items.IndexOf (PSeqAliP.Nom) ;

    CBSeqAliChange (nil) ;

    Modified := TRUE ;

    SBAddSeqAli.Enabled := IsComplete or (ListSeqAliP.Count < 5) ;

    SBCommentClick (nil) ;

  end ;

end ;

procedure TFSeqAliP.SBDelSeqAliClick (Sender : TObject) ;

begin

  if SeqAliPUsed (PSeqAliP.Num)

  then // Enregistrement utilis?

    MessageDlg (MsgDelErr, mtWarning, [mbOk], 0)

  else // Suppression de l'enregistrement

    if MessageDlg (MsgDel, mtConfirmation, [mbYes, mbNo], 0) = mrYes

    then

    begin

      Dispose (PSeqAliP) ;

      ListSeqAliP.Delete (IdxSeqAliP) ;

      SaveSeqAliP ; // Sauvegarde !

      Modified := FALSE ;

      CBSeqAli.DeleteSelected ;

      IdxSeqAliP := -1 ;

      CBSeqAli.ItemIndex := -1 ;

      CBSeqAliChange (nil) ;

      SBAddSeqAli.Enabled := IsComplete or (ListSeqAliP.Count < 5) ;

    end ;

end ;

procedure TFSeqAliP.SBRenameClick (Sender : TObject) ;

var

  i : integer ;

  s : string ;

  ok : boolean ;

begin

  // Saisie du nouveau nom

  s := CBSeqAli.Text ;

  repeat

    if InputQuery (FSeqAliP.Caption, MsgRename, s) and (s <> CBSeqAli.Text)

    then // V?rification du nom

    begin

      s := Trim (s) ; // Suppression des espaces au d?but et ? la fin

      if s = ''

      then // Pas de nom

      begin

        ok := FALSE ;

        MessageDlg (MsgNameEmpty, mtWarning, [mbOk], 0) ;

      end

      else

        if Length (s) > 25

        then // Nom trop long

        begin

          ok := FALSE ;

          MessageDlg (Format (MsgNameTooLarge, [25]), mtWarning, [mbOk], 0) ;

          s := Copy (s, 1, 25) ;

        end

        else

        begin

          ok := TRUE ;

          i := 0 ;

          while ok and (i < ListSeqAliP.Count) do

          begin

            PSeqAliP := ListSeqAliP[i] ;

            if PSeqAliP.Nom = s

            then // Nom d?j? utilis?

            begin

              ok := FALSE ;

              MessageDlg (MsgNameExists, mtWarning, [mbOk], 0) ;

            end

            else

              Inc (i) ;

          end ;

        end ;

    end

    else // Annulation

    begin

      s := '' ;

      ok := TRUE ;

    end ;

  until ok ;

  PSeqAliP := ListSeqAliP[IdxSeqAliP] ;

  if s <> ''

  then // Renommer l'enregistrement

  begin

    PSeqAliP.Nom := s ;

    Modified := TRUE ;

    StringsSeqAliP (CBSeqAli.Items, TRUE) ;

    CBSeqAli.ItemIndex := CBSeqAli.Items.IndexOf (s) ;

  end ;

end ;

procedure TFSeqAliP.SBCommentClick (Sender : TObject) ;

begin

  // Saisie du commentaire

  FComment := TFComment.Create (Self) ;

  with FComment do

  begin

    Memo.Text := PSeqAliP.Memo ;

    if ShowModal = mrOk

    then // Commenter l'enregistrement

    begin

      PSeqAliP.Memo := Memo.Text ;

      Modified := TRUE ;

      CBSeqAli.Hint := PSeqAliP.Memo ;

    end ;

    Release ;

  end ;

end ;

procedure TFSeqAliP.SBSaveClick(Sender: TObject);

begin

  SaveSeqAliP ;

  if not SeqAliPValid (PSeqAliP)

  then

    MessageDlg(Format (MsgInvalidData, [Caption, PSeqAliP.Nom]), mtWarning, [mbOK], 0) ;

  Modified := FALSE ;

end;

procedure TFSeqAliP.SBPrintClick(Sender: TObject);

begin

  FRapSeqAliP := TFRapSeqAliP.Create (Self) ;

  FRapSeqAliP.QRRapport.PreviewModal ;

  FRapSeqAliP.Release ;

end;

procedure TFSeqAliP.LBRuleClick (Sender : TObject) ;

begin

  NumRule := LBRule.ItemIndex + 1 ;

  if LBRule.Items.Count < MAX_RULE

  then

    SBAddRule.Enabled := TRUE

  else

    SBAddRule.Enabled := FALSE ;

  if NumRule = PSeqAliP.NbRule

  then // Fin de simulation

  begin

    SBDelRule.Enabled := FALSE ;

    GBEnd.Visible := FALSE ;

    CBTwoAli.Enabled := TRUE ;

  end

  else // Mode de fin

  begin

    SBDelRule.Enabled := TRUE ;

    GBEnd.Visible := TRUE ;

  end ;

  with PSeqAliP.Rule[NumRule] do

  begin

    Update := TRUE ;

    CBModeFin.ItemIndex := ModeFin ;

    CBModeFinChange (nil) ;

    PBValFin.AsFloat := ValFin ;

    if NumAli1 = -1

    then

      CBAli1.ItemIndex := -1

    else

      CBAli1.ItemIndex := CBAli1.Items.IndexOf (FindNomAliment (NumAli1)) ;

    if CBAli1.ItemIndex = -1

    then

      CBAli1.Hint := ''

    else

    begin

      PAliment := ListAliment[FindIdxAliment (CBAli1.Text)] ;

      CBAli1.Hint := PAliment.Memo ;

    end ;

    if NumAli2 = -1

    then

    begin

      CBAli2.ItemIndex := -1 ;

      if CBTwoAli.Checked

      then

        CBTwoAli.Checked := FALSE

      else

        CBTwoAliClick (nil) ;

    end

    else // 2 aliments

    begin

      CBAli2.ItemIndex := CBAli2.Items.IndexOf (FindNomAliment (NumAli2)) ;

      PBAli1Init.AsInteger := PctAli1Init ;

      if PctAli1Init = PctAli1Fin

      then

        if CBTransit.Checked

        then

          CBTransit.Checked := FALSE

        else

          CBTransitClick (nil)

      else // transition

      begin

        PBAli1Fin.AsInteger := PctAli1Fin ;

        CBTransit.Checked := TRUE ;

      end ;

      CBTwoAli.Checked := TRUE ;

    end ;

    if CBAli2.ItemIndex = -1

    then

      CBAli2.Hint := ''

    else

    begin

      PAliment := ListAliment[FindIdxAliment (CBAli2.Text)] ;

      CBAli1.Hint := PAliment.Memo ;

    end ;

    Update := FALSE ;

  end ;

end ;

procedure TFSeqAliP.LBRuleDrawItem(Control: TWinControl; Index: Integer;

  Rect: TRect; State: TOwnerDrawState);

begin

  with (Control as TListBox).Canvas do

  begin

    // Cadre principal

    FillRect(Rect);

    // Texte

    SetTextAlign(Handle, TA_LEFT);

    Rect.Left := 22;

    TextRect(Rect, Rect.Left, Rect.Top, StrModeFin(Index + 1));

    Rect.Left := 150 ;

    TextRect(Rect, Rect.Left, Rect.Top, StrAliment(Index + 1));

    Rect.Left := 0;

    // Num?ro

    SetTextAlign(Handle, TA_RIGHT);

    Rect.Right := 14;

    TextRect(Rect, Rect.Right, Rect.Top, Format('%d', [Index + 1]));

  end;

end;

procedure TFSeqAliP.SBAddRuleClick (Sender : TObject) ;

var

  i : integer ;

begin

  for i := PSeqAliP.NbRule downto NumRule do

    PSeqAliP.Rule[i + 1] := PSeqAliP.Rule[i] ;

  with PSeqAliP.Rule[NumRule] do

  begin

    ModeFin := -1 ;

    ValFin := 0 ;

  end ;

  Inc (PSeqAliP.NbRule) ;

  LBRule.Items.Add ('') ;

  LBRule.ItemIndex := NumRule - 1 ;

  LBRuleClick (nil) ;

  Modified := TRUE ;

  ActiveControl := CBModeFin ;

end ;

procedure TFSeqAliP.SBDelRuleClick (Sender : TObject) ;

var

  i : integer ;

begin

  Dec (PSeqAliP.NbRule) ;

  for i := NumRule to PSeqAliP.NbRule do

    PSeqAliP.Rule[i] := PSeqAliP.Rule[i + 1] ;

  i := NumRule ; // Position courante

  LBRule.DeleteSelected ;

  LBRule.ItemIndex := i - 1 ;

  LBRuleClick (nil) ;

  ActiveControl := LBRule ;

  Modified := TRUE ;

end ;

procedure TFSeqAliP.CBModeFinChange (Sender : TObject) ;

begin

  if CBModeFin.ItemIndex = 3

  then

  begin

    CBTwoAli.Enabled := FALSE ;

    if CBTwoAli.Checked

    then

      CBTwoAli.Checked := FALSE

    else

      CBTwoAliClick (nil) ;

  end

  else

    CBTwoAli.Enabled := TRUE ;

  case CBModeFin.ItemIndex of

    0, 1 : // Dur?e ou Age

      LUnitFin.Caption := StrJ ;

    2, 3 : // Poids vif ou Cumul aliment

      LUnitFin.Caption := StrKg ;

    else

      LUnitFin.Caption := '' ;

  end ;

  if CBModeFin.ItemIndex = -1

  then

    PBValFin.Visible := FALSE

  else

    PBValFin.Visible := TRUE ;

  if not Update

  then

  begin

    Modified := TRUE ;

    PSeqAliP.Rule[NumRule].ModeFin := CBModeFin.ItemIndex ;

    LBRule.Repaint ;

  end ;

end ;

procedure TFSeqAliP.PBValFinChange (Sender : TObject) ;

begin

  if not Update

  then

  begin

    Modified := TRUE ;

    PSeqAliP.Rule[NumRule].ValFin := PBValFin.AsFloat ;

    LBRule.Repaint ;

  end ;

end ;

procedure TFSeqAliP.CBTwoAliClick (Sender : TObject) ;

begin

  if CBTwoAli.Checked

  then

  begin

    if CBAli1.ItemIndex = -1

    then

      CBAli2.Enabled := FALSE

    else

      CBAli2.Enabled := TRUE ;

    PInit.Visible := TRUE ;

    CBTransit.Visible := TRUE

  end

  else

  begin

    if CBAli2.Text <> ''

    then

    begin

      Modified := TRUE ;

      CBAli2.ItemIndex := -1 ;

      PSeqAliP.Rule[NumRule].NumAli2 := -1 ;

    end ;

    CBAli2.Enabled := FALSE ;

    PInit.Visible := FALSE ;

    CBTransit.Visible := FALSE ;

    PBAli1Init.AsInteger := 100 ;

    if CBTransit.Checked

    then

      CBTransit.Checked := FALSE

    else

      CBTransitClick (nil) ;

  end ;

end ;

procedure TFSeqAliP.CBTransitClick (Sender : TObject) ;

begin

  if CBTransit.Checked

  then

  begin

    PFin.Visible := TRUE ;

    LInit.Visible := TRUE ;

    PBAli1Init.Hint := HintAli1Init ;

  end

  else

  begin

    PFin.Visible := FALSE ;

    LInit.Visible := FALSE ;

    PBAli1Init.Hint := HintAli1Const ;

    PBAli1Fin.AsInteger := PBAli1Init.AsInteger ;

  end ;

end ;

procedure TFSeqAliP.CBAli1Change (Sender : TObject) ;

begin

  if CBAli1.ItemIndex > -1

  then

    CBAli2.Enabled := CBTwoAli.Checked ;

  if not Update and (CBAli1.Text <> '')

  then

  begin

    Modified := TRUE ;

    PSeqAliP.Rule[NumRule].NumAli1 := FindNumAliment (CBAli1.Text) ;

    LBRule.Repaint ;

  end ;

end ;

procedure TFSeqAliP.CBAli2Change (Sender : TObject) ;

begin

  if not Update and (CBAli2.Text <> '')

  then

  begin

    Modified := TRUE ;

    PSeqAliP.Rule[NumRule].NumAli2 := FindNumAliment (CBAli2.Text) ;

    LBRule.Repaint ;

  end ;

end ;

procedure TFSeqAliP.PBAli1InitChange (Sender : TObject) ;

begin

  PBAli2Init.AsInteger := 100 - PBAli1Init.AsInteger ;

  if not Update

  then

  begin

    Modified := TRUE ;

    PSeqAliP.Rule[NumRule].PctAli1Init := PBAli1Init.AsInteger ;

    if not CBTransit.Checked

    then // Pas de transition

      PBAli1Fin.AsInteger := PBAli1Init.AsInteger ;

    LBRule.Repaint ;

  end ;

end ;

procedure TFSeqAliP.PBAli1FinChange (Sender : TObject) ;

begin

  PBAli2Fin.AsInteger := 100 - PBAli1Fin.AsInteger ;

  if not Update

  then

  begin

    Modified := TRUE ;

    PSeqAliP.Rule[NumRule].PctAli1Fin := PBAli1Fin.AsInteger ;

    LBRule.Repaint ;

  end ;

end ;

function TFSeqAliP.StrModeFin (n : integer) : string ;

begin

  if n = PSeqAliP.NbRule

  then // Fin de simulation

    result := _('End of simulation')

  else

    with PSeqAliP.Rule[n] do

      case ModeFin of

        0, 1 : // Dur?e ou Age

          result := Format ('%s = %1.0f %s', [CBModeFin.Items[ModeFin], ValFin, StrJ]) ;

        2, 3 : // Poids vif ou Cumul aliment

          result := Format ('%s = %1.0f %s', [CBModeFin.Items[ModeFin], ValFin, StrKg]) ;

        else

          result := '' ;

      end ;

end ;

function TFSeqAliP.StrAliment (n : integer) : string ;

begin

  with PSeqAliP.Rule[n] do

    if NumAli1 = -1

    then

      result := ''

    else

      if NumAli2 = -1

      then // 1 aliment

        result := FindNomAliment (NumAli1)

      else // 2 aliments

        if PctAli1Init = PctAli1Fin

        then

          result := Format ('%s (%d %%) - %s (%d %%)', [FindNomAliment (NumAli1), PctAli1Init, FindNomAliment (NumAli2), 100 - PctAli1Init])

        else // Transition

          result := Format ('%s : %s (%d-%d %%) - %s (%d-%d %%)', [_('Transition'), FindNomAliment (NumAli1), PctAli1Init, PctAli1Fin, FindNomAliment (NumAli2), 100 - PctAli1Init, 100 - PctAli1Fin]) ;

end ;

end.