InraPorc

unit UFLoader;

interface

uses

  Windows, Forms, Classes, Controls, ComCtrls;

type

  TFLoader = class(TForm)

    PBLoader: TProgressBar;

  private

    { D?clarations priv?es }

  public

    { D?clarations publiques }

    procedure Init;

  end;

var

  FLoader: TFLoader;

implementation

uses

  Dialogs, SysUtils, gnugettext, UVariables, UStrings, UInit, UUtil, UFIntro,

  UFLicense;

{$R *.dfm}

procedure TFLoader.Init;

var

  FileName: String;

  VolumeSerialNumber: String;

  Ok: Boolean;

  s: String;

begin

  if Screen.Fonts.IndexOf('Arial Unicode MS') <> -1

  then

    Font.Name := 'Arial Unicode MS';

  // Langue

  UseLanguage(LanguageCode);

  TranslateComponent(Self);

  if ParamCount > 1

  then // Nombre de param?tres incorrect

    MessageDlg(Format(MsgParamCount, [ParamCount, ParamStr(0), ExtractFileName(Application.ExeName)]), mtError, [mbOk], 0);

  PBLoader.StepIt;

  // Licence

  InitLicense;

  LoadLicense;

  if (MajorVersion > 9)

  or (MinorVersion > 9)

  or (ReleaseVersion > 9)

  or (BuildVersion > 9)

  then // Num?ro de version incorrect

  begin

    MessageDlg(Format(StrVersion, [MajorVersion, MinorVersion, ReleaseVersion, BuildVersion]), mtError, [mbOk], 0);

    Application.Terminate;

    Exit;

  end;

  if ((LicenseType = 1) or (LicenseType = 2)) and (StrToInt(FormatDateTime('yyyymmdd', Date)) > StrToInt(Copy(FinalDate, 7, 4) + Copy(FinalDate, 4, 2) + Copy(FinalDate, 1, 2)))

  then // Date limite d?pass?e

    MessageDlg(MsgFinalDate, mtWarning, [mbOk], 0);

  if (LicenseType = 2) and (DriveType(Drive) <> DRIVE_FIXED)

  then // La version compl?te doit ?tre install?e sur un disque fixe

    MessageDlg(MsgFixedDrive, mtWarning, [mbOk], 0);

  VolumeSerialNumber := BdRReadString('\Software\InraPorc\License', 'VolumeSerialNumber', Volume);

  if ((LicenseType = 1) or (LicenseType = 2)) and (Volume <> VolumeSerialNumber)

  then // Changement de disque

    MessageDlg(MsgDiskChanged, mtWarning, [mbOk], 0);

  // Aide

  if Copy(LanguageCode, 1, 2) = 'fr'

  then // Fran?ais

    FileName := ChangeFileExt(Application.ExeName, '_fr.chm')

  else // Anglais

    FileName := ChangeFileExt(Application.ExeName, '_en.chm');

  if FileExists(FileName)

  then

    Application.HelpFile := FileName;

  // Contrat de licence

  case LicenseType of

    1: s := 'AcceptEducation';

    2: s := 'AcceptComplete';

    else s := 'AcceptEvaluation';

  end;

  if not BdRReadBoolean('\Software\InraPorc', s, False)

  then

  begin

    FIntro := TFIntro.Create(Self);

    Ok := FIntro.ShowModal = mrOk;

    FIntro.Release;

    if Ok

    then // Accepter

      BdRWriteBoolean('\Software\InraPorc', s, True)

    else // Refuser

    begin

      Application.Terminate;

      Exit;

    end;

  end;

  PBLoader.StepIt;

  // Configuration

  LoadConfig;

  // Donn?es

  if ParamCount = 1

  then // R?pertoire pass? en param?tre

    if DirectoryExists(ParamStr(1))

    then // R?pertoire enregistr? dans la configuration

      DataFolderExists := SetCurrentDir(ParamStr(1))

    else

    begin

      MessageDlg(Format(MsgDataDirectory, [ParamStr(1)]), mtError, [mbOk], 0);

      DataFolderExists := False;

    end

  else // R?pertoire par d?faut (Configuration)

    if DirectoryExists(Folder)

    then // R?pertoire enregistr? dans la configuration

      DataFolderExists := SetCurrentDir(Folder)

    else

    begin

      MessageDlg(Format(MsgDataDirectory, [Folder]), mtError, [mbOk], 0);

      DataFolderExists := False;

    end;

  PBLoader.StepIt;

  InitData;

  PBLoader.StepIt;

  LoadData;

  PBLoader.StepIt;

  if ((LicenseType = 0) or (LicenseType = 1)) and TooMuchRecords

  then // Trop d'enregistrements

    MessageDlg(MsgTooMuchRecords, mtWarning, [mbOk], 0);

  if not IsComplete and not IsEducation

  then

  begin

    FLicense := TFLicense.Create(Self);

    FLicense.ShowModal;

    FLicense.Release;

  end;

end;

end.